sbdt03()

subroutine sbdt03	(	character	uplo,
		integer	n,
		integer	kd,
		real, dimension( * )	d,
		real, dimension( * )	e,
		real, dimension( ldu, * )	u,
		integer	ldu,
		real, dimension( * )	s,
		real, dimension( ldvt, * )	vt,
		integer	ldvt,
		real, dimension( * )	work,
		real	resid
	)

SBDT03

Purpose:

 SBDT03 reconstructs a bidiagonal matrix B from its SVD:
    S = U' * B * V
 where U and V are orthogonal matrices and S is diagonal.

 The test ratio to test the singular value decomposition is
    RESID = norm( B - U * S * VT ) / ( n * norm(B) * EPS )
 where VT = V' and EPS is the machine precision.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the matrix B is upper or lower bidiagonal. = 'U': Upper bidiagonal = 'L': Lower bidiagonal
[in]	N	N is INTEGER The order of the matrix B.
[in]	KD	KD is INTEGER The bandwidth of the bidiagonal matrix B. If KD = 1, the matrix B is bidiagonal, and if KD = 0, B is diagonal and E is not referenced. If KD is greater than 1, it is assumed to be 1, and if KD is less than 0, it is assumed to be 0.
[in]	D	D is REAL array, dimension (N) The n diagonal elements of the bidiagonal matrix B.
[in]	E	E is REAL array, dimension (N-1) The (n-1) superdiagonal elements of the bidiagonal matrix B if UPLO = 'U', or the (n-1) subdiagonal elements of B if UPLO = 'L'.
[in]	U	U is REAL array, dimension (LDU,N) The n by n orthogonal matrix U in the reduction B = U'*A*P.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,N)
[in]	S	S is REAL array, dimension (N) The singular values from the SVD of B, sorted in decreasing order.
[in]	VT	VT is REAL array, dimension (LDVT,N) The n by n orthogonal matrix V' in the reduction B = U * S * V'.
[in]	LDVT	LDVT is INTEGER The leading dimension of the array VT.
[out]	WORK	WORK is REAL array, dimension (2*N)
[out]	RESID	RESID is REAL The test ratio: norm(B - U * S * V') / ( n * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 133 of file sbdt03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            KD, LDU, LDVT, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * ), S( * ), U( LDU, * ),
     $                   VT( LDVT, * ), WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               BNORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX
      REAL               SASUM, SLAMCH
      EXTERNAL           lsame, isamax, sasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      resid = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Compute B - U * S * V' one column at a time.
*
      bnorm = zero
      IF( kd.GE.1 ) THEN
*
*        B is bidiagonal.
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           B is upper bidiagonal.
*
            DO 20 j = 1, n
               DO 10 i = 1, n
                  work( n+i ) = s( i )*vt( i, j )
   10          CONTINUE
               CALL sgemv( 'No transpose', n, n, -one, u, ldu,
     $                     work( n+1 ), 1, zero, work, 1 )
               work( j ) = work( j ) + d( j )
               IF( j.GT.1 ) THEN
                  work( j-1 ) = work( j-1 ) + e( j-1 )
                  bnorm = max( bnorm, abs( d( j ) )+abs( e( j-1 ) ) )
               ELSE
                  bnorm = max( bnorm, abs( d( j ) ) )
               END IF
               resid = max( resid, sasum( n, work, 1 ) )
   20       CONTINUE
         ELSE
*
*           B is lower bidiagonal.
*
            DO 40 j = 1, n
               DO 30 i = 1, n
                  work( n+i ) = s( i )*vt( i, j )
   30          CONTINUE
               CALL sgemv( 'No transpose', n, n, -one, u, ldu,
     $                     work( n+1 ), 1, zero, work, 1 )
               work( j ) = work( j ) + d( j )
               IF( j.LT.n ) THEN
                  work( j+1 ) = work( j+1 ) + e( j )
                  bnorm = max( bnorm, abs( d( j ) )+abs( e( j ) ) )
               ELSE
                  bnorm = max( bnorm, abs( d( j ) ) )
               END IF
               resid = max( resid, sasum( n, work, 1 ) )
   40       CONTINUE
         END IF
      ELSE
*
*        B is diagonal.
*
         DO 60 j = 1, n
            DO 50 i = 1, n
               work( n+i ) = s( i )*vt( i, j )
   50       CONTINUE
            CALL sgemv( 'No transpose', n, n, -one, u, ldu, work( n+1 ),
     $                  1, zero, work, 1 )
            work( j ) = work( j ) + d( j )
            resid = max( resid, sasum( n, work, 1 ) )
   60    CONTINUE
         j = isamax( n, d, 1 )
         bnorm = abs( d( j ) )
      END IF
*
*     Compute norm(B - U * S * V') / ( n * norm(B) * EPS )
*
      eps = slamch( 'Precision' )
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( real( n )*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, real( n )*bnorm ) / bnorm ) /
     $                 ( real( n )*eps )
            ELSE
               resid = min( resid / bnorm, real( n ) ) /
     $                 ( real( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of SBDT03
*

Here is the call graph for this function:

Here is the caller graph for this function: