dchkq3.f

Go to the documentation of this file.

*> \brief \b DCHKQ3
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKQ3( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
*                          THRESH, A, COPYA, S, TAU, WORK, IWORK,
*                          NOUT )
*
*       .. Scalar Arguments ..
*       INTEGER            NM, NN, NNB, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
*      $                   NXVAL( * )
*       DOUBLE PRECISION   A( * ), COPYA( * ), S( * ),
*      $                   TAU( * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DCHKQ3 tests  DGEQP3.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB and NX contained in the
*>          vectors NBVAL and NXVAL.  The blocking parameters are used
*>          in pairs (NB,NX).
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NXVAL
*> \verbatim
*>          NXVAL is INTEGER array, dimension (NNB)
*>          The values of the crossover point NX.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (MMAX*NMAX)
*>          where MMAX is the maximum value of M in MVAL and NMAX is the
*>          maximum value of N in NVAL.
*> \endverbatim
*>
*> \param[out] COPYA
*> \verbatim
*>          COPYA is DOUBLE PRECISION array, dimension (MMAX*NMAX)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION array, dimension
*>                      (min(MMAX,NMAX))
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (MMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension
*>                      (MMAX*NMAX + 4*NMAX + MMAX)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dchkq3( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
     $                   THRESH, A, COPYA, S, TAU, WORK, IWORK,
     $                   NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NM, NN, NNB, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
     $                   nxval( * )
      DOUBLE PRECISION   A( * ), COPYA( * ), S( * ),
     $                   TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPES
      PARAMETER          ( NTYPES = 6 )
      INTEGER            NTESTS
      parameter( ntests = 3 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d0, zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      CHARACTER*3        PATH
      INTEGER            I, IHIGH, ILOW, IM, IMODE, IN, INB, INFO,
     $                   istep, k, lda, lw, lwork, m, mnmin, mode, n,
     $                   nb, nerrs, nfail, nrun, nx
      DOUBLE PRECISION   EPS
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DQPT01, DQRT11, DQRT12
      EXTERNAL           DLAMCH, DQPT01, DQRT11, DQRT12
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahd, alasum, dgeqp3, dlacpy, dlaord, dlaset,
     $                   dlatms, icopy, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Double precision'
      path( 2: 3 ) = 'Q3'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
      eps = dlamch( 'Epsilon' )
      infot = 0
*
      DO 90 im = 1, nm
*
*        Do for each value of M in MVAL.
*
         m = mval( im )
         lda = max( 1, m )
*
         DO 80 in = 1, nn
*
*           Do for each value of N in NVAL.
*
            n = nval( in )
            mnmin = min( m, n )
            lwork = max( 1, m*max( m, n )+4*mnmin+max( m, n ),
     $                   m*n + 2*mnmin + 4*n )
*
            DO 70 imode = 1, ntypes
               IF( .NOT.dotype( imode ) )
     $            GO TO 70
*
*              Do for each type of matrix
*                 1:  zero matrix
*                 2:  one small singular value
*                 3:  geometric distribution of singular values
*                 4:  first n/2 columns fixed
*                 5:  last n/2 columns fixed
*                 6:  every second column fixed
*
               mode = imode
               IF( imode.GT.3 )
     $            mode = 1
*
*              Generate test matrix of size m by n using
*              singular value distribution indicated by `mode'.
*
               DO 20 i = 1, n
                  iwork( i ) = 0
   20          CONTINUE
               IF( imode.EQ.1 ) THEN
                  CALL dlaset( 'Full', m, n, zero, zero, copya, lda )
                  DO 30 i = 1, mnmin
                     s( i ) = zero
   30             CONTINUE
               ELSE
                  CALL dlatms( m, n, 'Uniform', iseed, 'Nonsymm', s,
     $                         mode, one / eps, one, m, n, 'No packing',
     $                         copya, lda, work, info )
                  IF( imode.GE.4 ) THEN
                     IF( imode.EQ.4 ) THEN
                        ilow = 1
                        istep = 1
                        ihigh = max( 1, n / 2 )
                     ELSE IF( imode.EQ.5 ) THEN
                        ilow = max( 1, n / 2 )
                        istep = 1
                        ihigh = n
                     ELSE IF( imode.EQ.6 ) THEN
                        ilow = 1
                        istep = 2
                        ihigh = n
                     END IF
                     DO 40 i = ilow, ihigh, istep
                        iwork( i ) = 1
   40                CONTINUE
                  END IF
                  CALL dlaord( 'Decreasing', mnmin, s, 1 )
               END IF
*
               DO 60 inb = 1, nnb
*
*                 Do for each pair of values (NB,NX) in NBVAL and NXVAL.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
                  nx = nxval( inb )
                  CALL xlaenv( 3, nx )
*
*                 Get a working copy of COPYA into A and a copy of
*                 vector IWORK.
*
                  CALL dlacpy( 'All', m, n, copya, lda, a, lda )
                  CALL icopy( n, iwork( 1 ), 1, iwork( n+1 ), 1 )
*
*                 Compute the QR factorization with pivoting of A
*
                  lw = max( 1, 2*n+nb*( n+1 ) )
*
*                 Compute the QP3 factorization of A
*
                  srnamt = 'DGEQP3'
                  CALL dgeqp3( m, n, a, lda, iwork( n+1 ), tau, work,
     $                         lw, info )
*
*                 Compute norm(svd(a) - svd(r))
*
                  result( 1 ) = dqrt12( m, n, a, lda, s, work,
     $                          lwork )
*
*                 Compute norm( A*P - Q*R )
*
                  result( 2 ) = dqpt01( m, n, mnmin, copya, a, lda, tau,
     $                          iwork( n+1 ), work, lwork )
*
*                 Compute Q'*Q
*
                  result( 3 ) = dqrt11( m, mnmin, a, lda, tau, work,
     $                          lwork )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 50 k = 1, ntests
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )'DGEQP3', m, n, nb,
     $                     imode, k, result( k )
                        nfail = nfail + 1
                     END IF
   50             CONTINUE
                  nrun = nrun + ntests
*
   60          CONTINUE
   70       CONTINUE
   80    CONTINUE
   90 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ' M =', i5, ', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
*
*     End of DCHKQ3
*
      END