dlarge()

subroutine dlarge	(	integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( 4 )	iseed,
		double precision, dimension( * )	work,
		integer	info
	)

DLARGE

Purpose:

 DLARGE pre- and post-multiplies a real general n by n matrix A
 with a random orthogonal matrix: A = U*D*U'.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the original n by n matrix A. On exit, A is overwritten by U*A*U' for some random orthogonal matrix U.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= N.
[in,out]	ISEED	ISEED is INTEGER array, dimension (4) On entry, the seed of the random number generator; the array elements must be between 0 and 4095, and ISEED(4) must be odd. On exit, the seed is updated.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (2*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 86 of file dlarge.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      DOUBLE PRECISION   A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION   TAU, WA, WB, WN
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv, dger, dlarnv, dscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sign
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DNRM2
      EXTERNAL           dnrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -3
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'DLARGE', -info )
         RETURN
      END IF
*
*     pre- and post-multiply A by random orthogonal matrix
*
      DO 10 i = n, 1, -1
*
*        generate random reflection
*
         CALL dlarnv( 3, iseed, n-i+1, work )
         wn = dnrm2( n-i+1, work, 1 )
         wa = sign( wn, work( 1 ) )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = work( 1 ) + wa
            CALL dscal( n-i, one / wb, work( 2 ), 1 )
            work( 1 ) = one
            tau = wb / wa
         END IF
*
*        multiply A(i:n,1:n) by random reflection from the left
*
         CALL dgemv( 'Transpose', n-i+1, n, one, a( i, 1 ), lda, work,
     $               1, zero, work( n+1 ), 1 )
         CALL dger( n-i+1, n, -tau, work, 1, work( n+1 ), 1, a( i, 1 ),
     $              lda )
*
*        multiply A(1:n,i:n) by random reflection from the right
*
         CALL dgemv( 'No transpose', n, n-i+1, one, a( 1, i ), lda,
     $               work, 1, zero, work( n+1 ), 1 )
         CALL dger( n, n-i+1, -tau, work( n+1 ), 1, work, 1, a( 1, i ),
     $              lda )
   10 CONTINUE
      RETURN
*
*     End of DLARGE
*

Here is the call graph for this function:

Here is the caller graph for this function: