chptrf()

subroutine chptrf	(	character	uplo,
		integer	n,
		complex, dimension( * )	ap,
		integer, dimension( * )	ipiv,
		integer	info
	)

CHPTRF

Download CHPTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CHPTRF computes the factorization of a complex Hermitian packed
 matrix A using the Bunch-Kaufman diagonal pivoting method:

    A = U*D*U**H  or  A = L*D*L**H

 where U (or L) is a product of permutation and unit upper (lower)
 triangular matrices, and D is Hermitian and block diagonal with
 1-by-1 and 2-by-2 diagonal blocks.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	AP	AP is COMPLEX array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the Hermitian matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. On exit, the block diagonal matrix D and the multipliers used to obtain the factor U or L, stored as a packed triangular matrix overwriting A (see below for further details).
[out]	IPIV	IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D. If IPIV(k) > 0, then rows and columns k and IPIV(k) were interchanged and D(k,k) is a 1-by-1 diagonal block. If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k) is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) = IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, D(i,i) is exactly zero. The factorization has been completed, but the block diagonal matrix D is exactly singular, and division by zero will occur if it is used to solve a system of equations.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  If UPLO = 'U', then A = U*D*U**H, where
     U = P(n)*U(n)* ... *P(k)U(k)* ...,
  i.e., U is a product of terms P(k)*U(k), where k decreases from n to
  1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
  that if the diagonal block D(k) is of order s (s = 1 or 2), then

             (   I    v    0   )   k-s
     U(k) =  (   0    I    0   )   s
             (   0    0    I   )   n-k
                k-s   s   n-k

  If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
  If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
  and A(k,k), and v overwrites A(1:k-2,k-1:k).

  If UPLO = 'L', then A = L*D*L**H, where
     L = P(1)*L(1)* ... *P(k)*L(k)* ...,
  i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
  n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
  that if the diagonal block D(k) is of order s (s = 1 or 2), then

             (   I    0     0   )  k-1
     L(k) =  (   0    I     0   )  s
             (   0    v     I   )  n-k-s+1
                k-1   s  n-k-s+1

  If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
  If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
  and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).

Contributors:

J. Lewis, Boeing Computer Services Company

Definition at line 158 of file chptrf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               EIGHT, SEVTEN
      parameter( eight = 8.0e+0, sevten = 17.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IMAX, J, JMAX, K, KC, KK, KNC, KP, KPC,
     $                   KSTEP, KX, NPP
      REAL               ABSAKK, ALPHA, COLMAX, D, D11, D22, R1, ROWMAX,
     $                   TT
      COMPLEX            D12, D21, T, WK, WKM1, WKP1, ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAPY2
      EXTERNAL           lsame, icamax, slapy2
*     ..
*     .. External Subroutines ..
      EXTERNAL           chpr, csscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, conjg, max, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHPTRF', -info )
         RETURN
      END IF
*
*     Initialize ALPHA for use in choosing pivot block size.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
      IF( upper ) THEN
*
*        Factorize A as U*D*U**H using the upper triangle of A
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2
*
         k = n
         kc = ( n-1 )*n / 2 + 1
   10    CONTINUE
         knc = kc
*
*        If K < 1, exit from loop
*
         IF( k.LT.1 )
     $      GO TO 110
         kstep = 1
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( real( ap( kc+k-1 ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value
*
         IF( k.GT.1 ) THEN
            imax = icamax( k-1, ap( kc ), 1 )
            colmax = cabs1( ap( kc+imax-1 ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            ap( kc+k-1 ) = real( ap( kc+k-1 ) )
         ELSE
            IF( absakk.GE.alpha*colmax ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
            ELSE
*
*              JMAX is the column-index of the largest off-diagonal
*              element in row IMAX, and ROWMAX is its absolute value
*
               rowmax = zero
               jmax = imax
               kx = imax*( imax+1 ) / 2 + imax
               DO 20 j = imax + 1, k
                  IF( cabs1( ap( kx ) ).GT.rowmax ) THEN
                     rowmax = cabs1( ap( kx ) )
                     jmax = j
                  END IF
                  kx = kx + j
   20          CONTINUE
               kpc = ( imax-1 )*imax / 2 + 1
               IF( imax.GT.1 ) THEN
                  jmax = icamax( imax-1, ap( kpc ), 1 )
                  rowmax = max( rowmax, cabs1( ap( kpc+jmax-1 ) ) )
               END IF
*
               IF( absakk.GE.alpha*colmax*( colmax / rowmax ) ) THEN
*
*                 no interchange, use 1-by-1 pivot block
*
                  kp = k
               ELSE IF( abs( real( ap( kpc+imax-1 ) ) ).GE.alpha*
     $                  rowmax ) THEN
*
*                 interchange rows and columns K and IMAX, use 1-by-1
*                 pivot block
*
                  kp = imax
               ELSE
*
*                 interchange rows and columns K-1 and IMAX, use 2-by-2
*                 pivot block
*
                  kp = imax
                  kstep = 2
               END IF
            END IF
*
            kk = k - kstep + 1
            IF( kstep.EQ.2 )
     $         knc = knc - k + 1
            IF( kp.NE.kk ) THEN
*
*              Interchange rows and columns KK and KP in the leading
*              submatrix A(1:k,1:k)
*
               CALL cswap( kp-1, ap( knc ), 1, ap( kpc ), 1 )
               kx = kpc + kp - 1
               DO 30 j = kp + 1, kk - 1
                  kx = kx + j - 1
                  t = conjg( ap( knc+j-1 ) )
                  ap( knc+j-1 ) = conjg( ap( kx ) )
                  ap( kx ) = t
   30          CONTINUE
               ap( kx+kk-1 ) = conjg( ap( kx+kk-1 ) )
               r1 = real( ap( knc+kk-1 ) )
               ap( knc+kk-1 ) = real( ap( kpc+kp-1 ) )
               ap( kpc+kp-1 ) = r1
               IF( kstep.EQ.2 ) THEN
                  ap( kc+k-1 ) = real( ap( kc+k-1 ) )
                  t = ap( kc+k-2 )
                  ap( kc+k-2 ) = ap( kc+kp-1 )
                  ap( kc+kp-1 ) = t
               END IF
            ELSE
               ap( kc+k-1 ) = real( ap( kc+k-1 ) )
               IF( kstep.EQ.2 )
     $            ap( kc-1 ) = real( ap( kc-1 ) )
            END IF
*
*           Update the leading submatrix
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k now holds
*
*              W(k) = U(k)*D(k)
*
*              where U(k) is the k-th column of U
*
*              Perform a rank-1 update of A(1:k-1,1:k-1) as
*
*              A := A - U(k)*D(k)*U(k)**H = A - W(k)*1/D(k)*W(k)**H
*
               r1 = one / real( ap( kc+k-1 ) )
               CALL chpr( uplo, k-1, -r1, ap( kc ), 1, ap )
*
*              Store U(k) in column k
*
               CALL csscal( k-1, r1, ap( kc ), 1 )
            ELSE
*
*              2-by-2 pivot block D(k): columns k and k-1 now hold
*
*              ( W(k-1) W(k) ) = ( U(k-1) U(k) )*D(k)
*
*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
*              of U
*
*              Perform a rank-2 update of A(1:k-2,1:k-2) as
*
*              A := A - ( U(k-1) U(k) )*D(k)*( U(k-1) U(k) )**H
*                 = A - ( W(k-1) W(k) )*inv(D(k))*( W(k-1) W(k) )**H
*
               IF( k.GT.2 ) THEN
*
                  d = slapy2( real( ap( k-1+( k-1 )*k / 2 ) ),
     $                aimag( ap( k-1+( k-1 )*k / 2 ) ) )
                  d22 = real( ap( k-1+( k-2 )*( k-1 ) / 2 ) ) / d
                  d11 = real( ap( k+( k-1 )*k / 2 ) ) / d
                  tt = one / ( d11*d22-one )
                  d12 = ap( k-1+( k-1 )*k / 2 ) / d
                  d = tt / d
*
                  DO 50 j = k - 2, 1, -1
                     wkm1 = d*( d11*ap( j+( k-2 )*( k-1 ) / 2 )-
     $                      conjg( d12 )*ap( j+( k-1 )*k / 2 ) )
                     wk = d*( d22*ap( j+( k-1 )*k / 2 )-d12*
     $                    ap( j+( k-2 )*( k-1 ) / 2 ) )
                     DO 40 i = j, 1, -1
                        ap( i+( j-1 )*j / 2 ) = ap( i+( j-1 )*j / 2 ) -
     $                     ap( i+( k-1 )*k / 2 )*conjg( wk ) -
     $                     ap( i+( k-2 )*( k-1 ) / 2 )*conjg( wkm1 )
   40                CONTINUE
                     ap( j+( k-1 )*k / 2 ) = wk
                     ap( j+( k-2 )*( k-1 ) / 2 ) = wkm1
                     ap( j+( j-1 )*j / 2 ) = cmplx( real( ap( j+( j-1 )*
     $                                       j / 2 ) ), 0.0e+0 )
   50             CONTINUE
*
               END IF
*
            END IF
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -kp
            ipiv( k-1 ) = -kp
         END IF
*
*        Decrease K and return to the start of the main loop
*
         k = k - kstep
         kc = knc - k
         GO TO 10
*
      ELSE
*
*        Factorize A as L*D*L**H using the lower triangle of A
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2
*
         k = 1
         kc = 1
         npp = n*( n+1 ) / 2
   60    CONTINUE
         knc = kc
*
*        If K > N, exit from loop
*
         IF( k.GT.n )
     $      GO TO 110
         kstep = 1
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( real( ap( kc ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value
*
         IF( k.LT.n ) THEN
            imax = k + icamax( n-k, ap( kc+1 ), 1 )
            colmax = cabs1( ap( kc+imax-k ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            ap( kc ) = real( ap( kc ) )
         ELSE
            IF( absakk.GE.alpha*colmax ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
            ELSE
*
*              JMAX is the column-index of the largest off-diagonal
*              element in row IMAX, and ROWMAX is its absolute value
*
               rowmax = zero
               kx = kc + imax - k
               DO 70 j = k, imax - 1
                  IF( cabs1( ap( kx ) ).GT.rowmax ) THEN
                     rowmax = cabs1( ap( kx ) )
                     jmax = j
                  END IF
                  kx = kx + n - j
   70          CONTINUE
               kpc = npp - ( n-imax+1 )*( n-imax+2 ) / 2 + 1
               IF( imax.LT.n ) THEN
                  jmax = imax + icamax( n-imax, ap( kpc+1 ), 1 )
                  rowmax = max( rowmax, cabs1( ap( kpc+jmax-imax ) ) )
               END IF
*
               IF( absakk.GE.alpha*colmax*( colmax / rowmax ) ) THEN
*
*                 no interchange, use 1-by-1 pivot block
*
                  kp = k
               ELSE IF( abs( real( ap( kpc ) ) ).GE.alpha*rowmax ) THEN
*
*                 interchange rows and columns K and IMAX, use 1-by-1
*                 pivot block
*
                  kp = imax
               ELSE
*
*                 interchange rows and columns K+1 and IMAX, use 2-by-2
*                 pivot block
*
                  kp = imax
                  kstep = 2
               END IF
            END IF
*
            kk = k + kstep - 1
            IF( kstep.EQ.2 )
     $         knc = knc + n - k + 1
            IF( kp.NE.kk ) THEN
*
*              Interchange rows and columns KK and KP in the trailing
*              submatrix A(k:n,k:n)
*
               IF( kp.LT.n )
     $            CALL cswap( n-kp, ap( knc+kp-kk+1 ), 1, ap( kpc+1 ),
     $                        1 )
               kx = knc + kp - kk
               DO 80 j = kk + 1, kp - 1
                  kx = kx + n - j + 1
                  t = conjg( ap( knc+j-kk ) )
                  ap( knc+j-kk ) = conjg( ap( kx ) )
                  ap( kx ) = t
   80          CONTINUE
               ap( knc+kp-kk ) = conjg( ap( knc+kp-kk ) )
               r1 = real( ap( knc ) )
               ap( knc ) = real( ap( kpc ) )
               ap( kpc ) = r1
               IF( kstep.EQ.2 ) THEN
                  ap( kc ) = real( ap( kc ) )
                  t = ap( kc+1 )
                  ap( kc+1 ) = ap( kc+kp-k )
                  ap( kc+kp-k ) = t
               END IF
            ELSE
               ap( kc ) = real( ap( kc ) )
               IF( kstep.EQ.2 )
     $            ap( knc ) = real( ap( knc ) )
            END IF
*
*           Update the trailing submatrix
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k now holds
*
*              W(k) = L(k)*D(k)
*
*              where L(k) is the k-th column of L
*
               IF( k.LT.n ) THEN
*
*                 Perform a rank-1 update of A(k+1:n,k+1:n) as
*
*                 A := A - L(k)*D(k)*L(k)**H = A - W(k)*(1/D(k))*W(k)**H
*
                  r1 = one / real( ap( kc ) )
                  CALL chpr( uplo, n-k, -r1, ap( kc+1 ), 1,
     $                       ap( kc+n-k+1 ) )
*
*                 Store L(k) in column K
*
                  CALL csscal( n-k, r1, ap( kc+1 ), 1 )
               END IF
            ELSE
*
*              2-by-2 pivot block D(k): columns K and K+1 now hold
*
*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
*
*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
*              of L
*
               IF( k.LT.n-1 ) THEN
*
*                 Perform a rank-2 update of A(k+2:n,k+2:n) as
*
*                 A := A - ( L(k) L(k+1) )*D(k)*( L(k) L(k+1) )**H
*                    = A - ( W(k) W(k+1) )*inv(D(k))*( W(k) W(k+1) )**H
*
*                 where L(k) and L(k+1) are the k-th and (k+1)-th
*                 columns of L
*
                  d = slapy2( real( ap( k+1+( k-1 )*( 2*n-k ) / 2 ) ),
     $                aimag( ap( k+1+( k-1 )*( 2*n-k ) / 2 ) ) )
                  d11 = real( ap( k+1+k*( 2*n-k-1 ) / 2 ) ) / d
                  d22 = real( ap( k+( k-1 )*( 2*n-k ) / 2 ) ) / d
                  tt = one / ( d11*d22-one )
                  d21 = ap( k+1+( k-1 )*( 2*n-k ) / 2 ) / d
                  d = tt / d
*
                  DO 100 j = k + 2, n
                     wk = d*( d11*ap( j+( k-1 )*( 2*n-k ) / 2 )-d21*
     $                    ap( j+k*( 2*n-k-1 ) / 2 ) )
                     wkp1 = d*( d22*ap( j+k*( 2*n-k-1 ) / 2 )-
     $                      conjg( d21 )*ap( j+( k-1 )*( 2*n-k ) / 2 ) )
                     DO 90 i = j, n
                        ap( i+( j-1 )*( 2*n-j ) / 2 ) = ap( i+( j-1 )*
     $                     ( 2*n-j ) / 2 ) - ap( i+( k-1 )*( 2*n-k ) /
     $                     2 )*conjg( wk ) - ap( i+k*( 2*n-k-1 ) / 2 )*
     $                     conjg( wkp1 )
   90                CONTINUE
                     ap( j+( k-1 )*( 2*n-k ) / 2 ) = wk
                     ap( j+k*( 2*n-k-1 ) / 2 ) = wkp1
                     ap( j+( j-1 )*( 2*n-j ) / 2 )
     $                  = cmplx( real( ap( j+( j-1 )*( 2*n-j ) / 2 ) ),
     $                  0.0e+0 )
  100             CONTINUE
               END IF
            END IF
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -kp
            ipiv( k+1 ) = -kp
         END IF
*
*        Increase K and return to the start of the main loop
*
         k = k + kstep
         kc = knc + n - k + 2
         GO TO 60
*
      END IF
*
  110 CONTINUE
      RETURN
*
*     End of CHPTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: