clacon()

subroutine clacon	(	integer	n,
		complex, dimension( n )	v,
		complex, dimension( n )	x,
		real	est,
		integer	kase )

CLACON estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vector products.

Download CLACON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLACON estimates the 1-norm of a square, complex matrix A.
!> Reverse communication is used for evaluating matrix-vector products.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix. N >= 1. !>
[out]	V	!> V is COMPLEX array, dimension (N) !> On the final return, V = A*W, where EST = norm(V)/norm(W) !> (W is not returned). !>
[in,out]	X	!> X is COMPLEX array, dimension (N) !> On an intermediate return, X should be overwritten by !> A * X, if KASE=1, !> A**H * X, if KASE=2, !> where A**H is the conjugate transpose of A, and CLACON must be !> re-called with all the other parameters unchanged. !>
[in,out]	EST	!> EST is REAL !> On entry with KASE = 1 or 2 and JUMP = 3, EST should be !> unchanged from the previous call to CLACON. !> On exit, EST is an estimate (a lower bound) for norm(A). !>
[in,out]	KASE	!> KASE is INTEGER !> On the initial call to CLACON, KASE should be 0. !> On an intermediate return, KASE will be 1 or 2, indicating !> whether X should be overwritten by A * X or A**H * X. !> On the final return from CLACON, KASE will again be 0. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

Originally named CONEST, dated March 16, 1988.
Last modified: April, 1999

Contributors:

Nick Higham, University of Manchester

References:

N.J. Higham, "FORTRAN codes for estimating the one-norm of a real or complex matrix, with applications to condition estimation", ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.

Definition at line 111 of file clacon.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KASE, N
      REAL               EST
*     ..
*     .. Array Arguments ..
      COMPLEX            V( N ), X( N )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ITMAX
      parameter( itmax = 5 )
      REAL               ONE, TWO
      parameter( one = 1.0e0, two = 2.0e0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e0, 0.0e0 ),
     $                   cone = ( 1.0e0, 0.0e0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ITER, J, JLAST, JUMP
      REAL               ABSXI, ALTSGN, ESTOLD, SAFMIN, TEMP
*     ..
*     .. External Functions ..
      INTEGER            ICMAX1
      REAL               SCSUM1, SLAMCH
      EXTERNAL           icmax1, scsum1, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, real
*     ..
*     .. Save statement ..
      SAVE
*     ..
*     .. Executable Statements ..
*
      safmin = slamch( 'Safe minimum' )
      IF( kase.EQ.0 ) THEN
         DO 10 i = 1, n
            x( i ) = cmplx( one / real( n ) )
   10    CONTINUE
         kase = 1
         jump = 1
         RETURN
      END IF
*
      GO TO ( 20, 40, 70, 90, 120 )jump
*
*     ................ ENTRY   (JUMP = 1)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X.
*
   20 CONTINUE
      IF( n.EQ.1 ) THEN
         v( 1 ) = x( 1 )
         est = abs( v( 1 ) )
*        ... QUIT
         GO TO 130
      END IF
      est = scsum1( n, x, 1 )
*
      DO 30 i = 1, n
         absxi = abs( x( i ) )
         IF( absxi.GT.safmin ) THEN
            x( i ) = cmplx( real( x( i ) ) / absxi,
     $               aimag( x( i ) ) / absxi )
         ELSE
            x( i ) = cone
         END IF
   30 CONTINUE
      kase = 2
      jump = 2
      RETURN
*
*     ................ ENTRY   (JUMP = 2)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
*
   40 CONTINUE
      j = icmax1( n, x, 1 )
      iter = 2
*
*     MAIN LOOP - ITERATIONS 2,3,...,ITMAX.
*
   50 CONTINUE
      DO 60 i = 1, n
         x( i ) = czero
   60 CONTINUE
      x( j ) = cone
      kase = 1
      jump = 3
      RETURN
*
*     ................ ENTRY   (JUMP = 3)
*     X HAS BEEN OVERWRITTEN BY A*X.
*
   70 CONTINUE
      CALL ccopy( n, x, 1, v, 1 )
      estold = est
      est = scsum1( n, v, 1 )
*
*     TEST FOR CYCLING.
      IF( est.LE.estold )
     $   GO TO 100
*
      DO 80 i = 1, n
         absxi = abs( x( i ) )
         IF( absxi.GT.safmin ) THEN
            x( i ) = cmplx( real( x( i ) ) / absxi,
     $               aimag( x( i ) ) / absxi )
         ELSE
            x( i ) = cone
         END IF
   80 CONTINUE
      kase = 2
      jump = 4
      RETURN
*
*     ................ ENTRY   (JUMP = 4)
*     X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
*
   90 CONTINUE
      jlast = j
      j = icmax1( n, x, 1 )
      IF( ( abs( x( jlast ) ).NE.abs( x( j ) ) ) .AND.
     $    ( iter.LT.itmax ) ) THEN
         iter = iter + 1
         GO TO 50
      END IF
*
*     ITERATION COMPLETE.  FINAL STAGE.
*
  100 CONTINUE
      altsgn = one
      DO 110 i = 1, n
         x( i ) = cmplx( altsgn*( one+real( i-1 ) / real( n-1 ) ) )
         altsgn = -altsgn
  110 CONTINUE
      kase = 1
      jump = 5
      RETURN
*
*     ................ ENTRY   (JUMP = 5)
*     X HAS BEEN OVERWRITTEN BY A*X.
*
  120 CONTINUE
      temp = two*( scsum1( n, x, 1 ) / real( 3*n ) )
      IF( temp.GT.est ) THEN
         CALL ccopy( n, x, 1, v, 1 )
         est = temp
      END IF
*
  130 CONTINUE
      kase = 0
      RETURN
*
*     End of CLACON
*

Here is the call graph for this function: