icmax1()

integer function icmax1	(	integer	n,
		complex, dimension(*)	cx,
		integer	incx )

ICMAX1 finds the index of the first vector element of maximum absolute value.

Download ICMAX1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ICMAX1 finds the index of the first vector element of maximum absolute value.
!>
!> Based on ICAMAX from Level 1 BLAS.
!> The change is to use the 'genuine' absolute value.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of elements in the vector CX. !>
[in]	CX	!> CX is COMPLEX array, dimension (N) !> The vector CX. The ICMAX1 function returns the index of its first !> element of maximum absolute value. !>
[in]	INCX	!> INCX is INTEGER !> The spacing between successive values of CX. INCX >= 1. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Nick Higham for use with CLACON.

Definition at line 78 of file icmax1.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
*     ..
*     .. Array Arguments ..
      COMPLEX            CX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL               SMAX
      INTEGER            I, IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
      icmax1 = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      icmax1 = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         smax = abs(cx(1))
         DO i = 2,n
            IF (abs(cx(i)).GT.smax) THEN
               icmax1 = i
               smax = abs(cx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         smax = abs(cx(1))
         ix = ix + incx
         DO i = 2,n
            IF (abs(cx(ix)).GT.smax) THEN
               icmax1 = i
               smax = abs(cx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of ICMAX1
*

Here is the call graph for this function:

Here is the caller graph for this function: