dgeqpf()

subroutine dgeqpf	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( * )	jpvt,
		double precision, dimension( * )	tau,
		double precision, dimension( * )	work,
		integer	info
	)

DGEQPF

Download DGEQPF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 This routine is deprecated and has been replaced by routine DGEQP3.

 DGEQPF computes a QR factorization with column pivoting of a
 real M-by-N matrix A: A*P = Q*R.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, the upper triangle of the array contains the min(M,N)-by-N upper triangular matrix R; the elements below the diagonal, together with the array TAU, represent the orthogonal matrix Q as a product of min(m,n) elementary reflectors.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	JPVT	JPVT is INTEGER array, dimension (N) On entry, if JPVT(i) .ne. 0, the i-th column of A is permuted to the front of A*P (a leading column); if JPVT(i) = 0, the i-th column of A is a free column. On exit, if JPVT(i) = k, then the i-th column of A*P was the k-th column of A.
[out]	TAU	TAU is DOUBLE PRECISION array, dimension (min(M,N)) The scalar factors of the elementary reflectors.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (3*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(n)

  Each H(i) has the form

     H = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i).

  The matrix P is represented in jpvt as follows: If
     jpvt(j) = i
  then the jth column of P is the ith canonical unit vector.

  Partial column norm updating strategy modified by
    Z. Drmac and Z. Bujanovic, Dept. of Mathematics,
    University of Zagreb, Croatia.
  -- April 2011                                                      --
  For more details see LAPACK Working Note 176.

Definition at line 141 of file dgeqpf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            JPVT( * )
      DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ITEMP, J, MA, MN, PVT
      DOUBLE PRECISION   AII, TEMP, TEMP2, TOL3Z
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgeqr2, dlarf, dlarfg, dorm2r, dswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH, DNRM2
      EXTERNAL           idamax, dlamch, dnrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEQPF', -info )
         RETURN
      END IF
*
      mn = min( m, n )
      tol3z = sqrt(dlamch('Epsilon'))
*
*     Move initial columns up front
*
      itemp = 1
      DO 10 i = 1, n
         IF( jpvt( i ).NE.0 ) THEN
            IF( i.NE.itemp ) THEN
               CALL dswap( m, a( 1, i ), 1, a( 1, itemp ), 1 )
               jpvt( i ) = jpvt( itemp )
               jpvt( itemp ) = i
            ELSE
               jpvt( i ) = i
            END IF
            itemp = itemp + 1
         ELSE
            jpvt( i ) = i
         END IF
   10 CONTINUE
      itemp = itemp - 1
*
*     Compute the QR factorization and update remaining columns
*
      IF( itemp.GT.0 ) THEN
         ma = min( itemp, m )
         CALL dgeqr2( m, ma, a, lda, tau, work, info )
         IF( ma.LT.n ) THEN
            CALL dorm2r( 'Left', 'Transpose', m, n-ma, ma, a, lda, tau,
     $                   a( 1, ma+1 ), lda, work, info )
         END IF
      END IF
*
      IF( itemp.LT.mn ) THEN
*
*        Initialize partial column norms. The first n elements of
*        work store the exact column norms.
*
         DO 20 i = itemp + 1, n
            work( i ) = dnrm2( m-itemp, a( itemp+1, i ), 1 )
            work( n+i ) = work( i )
   20    CONTINUE
*
*        Compute factorization
*
         DO 40 i = itemp + 1, mn
*
*           Determine ith pivot column and swap if necessary
*
            pvt = ( i-1 ) + idamax( n-i+1, work( i ), 1 )
*
            IF( pvt.NE.i ) THEN
               CALL dswap( m, a( 1, pvt ), 1, a( 1, i ), 1 )
               itemp = jpvt( pvt )
               jpvt( pvt ) = jpvt( i )
               jpvt( i ) = itemp
               work( pvt ) = work( i )
               work( n+pvt ) = work( n+i )
            END IF
*
*           Generate elementary reflector H(i)
*
            IF( i.LT.m ) THEN
               CALL dlarfg( m-i+1, a( i, i ), a( i+1, i ), 1, tau( i ) )
            ELSE
               CALL dlarfg( 1, a( m, m ), a( m, m ), 1, tau( m ) )
            END IF
*
            IF( i.LT.n ) THEN
*
*              Apply H(i) to A(i:m,i+1:n) from the left
*
               aii = a( i, i )
               a( i, i ) = one
               CALL dlarf( 'LEFT', m-i+1, n-i, a( i, i ), 1, tau( i ),
     $                     a( i, i+1 ), lda, work( 2*n+1 ) )
               a( i, i ) = aii
            END IF
*
*           Update partial column norms
*
            DO 30 j = i + 1, n
               IF( work( j ).NE.zero ) THEN
*
*                 NOTE: The following 4 lines follow from the analysis in
*                 Lapack Working Note 176.
*
                  temp = abs( a( i, j ) ) / work( j )
                  temp = max( zero, ( one+temp )*( one-temp ) )
                  temp2 = temp*( work( j ) / work( n+j ) )**2
                  IF( temp2 .LE. tol3z ) THEN
                     IF( m-i.GT.0 ) THEN
                        work( j ) = dnrm2( m-i, a( i+1, j ), 1 )
                        work( n+j ) = work( j )
                     ELSE
                        work( j ) = zero
                        work( n+j ) = zero
                     END IF
                  ELSE
                     work( j ) = work( j )*sqrt( temp )
                  END IF
               END IF
   30       CONTINUE
*
   40    CONTINUE
      END IF
      RETURN
*
*     End of DGEQPF
*

Here is the call graph for this function:

Here is the caller graph for this function: