strt01()

subroutine strt01	(	character	uplo,
		character	diag,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldainv, * )	ainv,
		integer	ldainv,
		real	rcond,
		real, dimension( * )	work,
		real	resid )

STRT01

Purpose:

!>
!> STRT01 computes the residual for a triangular matrix A times its
!> inverse:
!>    RESID = norm( A*AINV - I ) / ( N * norm(A) * norm(AINV) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The triangular matrix A. If UPLO = 'U', the leading n by n !> upper triangular part of the array A contains the upper !> triangular matrix, and the strictly lower triangular part of !> A is not referenced. If UPLO = 'L', the leading n by n lower !> triangular part of the array A contains the lower triangular !> matrix, and the strictly upper triangular part of A is not !> referenced. If DIAG = 'U', the diagonal elements of A are !> also not referenced and are assumed to be 1. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in,out]	AINV	!> AINV is REAL array, dimension (LDAINV,N) !> On entry, the (triangular) inverse of the matrix A, in the !> same storage format as A. !> On exit, the contents of AINV are destroyed. !>
[in]	LDAINV	!> LDAINV is INTEGER !> The leading dimension of the array AINV. LDAINV >= max(1,N). !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal condition number of A, computed as !> 1/(norm(A) * norm(AINV)). !>
[out]	WORK	!> WORK is REAL array, dimension (N) !>
[out]	RESID	!> RESID is REAL !> norm(A*AINV - I) / ( N * norm(A) * norm(AINV) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 122 of file strt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            LDA, LDAINV, N
      REAL               RCOND, RESID
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AINV( LDAINV, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      REAL               AINVNM, ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANTR
      EXTERNAL           lsame, slamch, slantr
*     ..
*     .. External Subroutines ..
      EXTERNAL           strmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slantr( '1', uplo, diag, n, n, a, lda, work )
      ainvnm = slantr( '1', uplo, diag, n, n, ainv, ldainv, work )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Set the diagonal of AINV to 1 if AINV has unit diagonal.
*
      IF( lsame( diag, 'U' ) ) THEN
         DO 10 j = 1, n
            ainv( j, j ) = one
   10    CONTINUE
      END IF
*
*     Compute A * AINV, overwriting AINV.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 j = 1, n
            CALL strmv( 'Upper', 'No transpose', diag, j, a, lda,
     $                  ainv( 1, j ), 1 )
   20    CONTINUE
      ELSE
         DO 30 j = 1, n
            CALL strmv( 'Lower', 'No transpose', diag, n-j+1, a( j, j ),
     $                  lda, ainv( j, j ), 1 )
   30    CONTINUE
      END IF
*
*     Subtract 1 from each diagonal element to form A*AINV - I.
*
      DO 40 j = 1, n
         ainv( j, j ) = ainv( j, j ) - one
   40 CONTINUE
*
*     Compute norm(A*AINV - I) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = slantr( '1', uplo, 'Non-unit', n, n, ainv, ldainv, work )
*
      resid = ( ( resid*rcond ) / real( n ) ) / eps
*
      RETURN
*
*     End of STRT01
*

Here is the call graph for this function:

Here is the caller graph for this function: