LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
dspt21.f
Go to the documentation of this file.
1*> \brief \b DSPT21
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DSPT21( ITYPE, UPLO, N, KBAND, AP, D, E, U, LDU, VP,
12* TAU, WORK, RESULT )
13*
14* .. Scalar Arguments ..
15* CHARACTER UPLO
16* INTEGER ITYPE, KBAND, LDU, N
17* ..
18* .. Array Arguments ..
19* DOUBLE PRECISION AP( * ), D( * ), E( * ), RESULT( 2 ), TAU( * ),
20* \$ U( LDU, * ), VP( * ), WORK( * )
21* ..
22*
23*
24*> \par Purpose:
25* =============
26*>
27*> \verbatim
28*>
29*> DSPT21 generally checks a decomposition of the form
30*>
31*> A = U S U**T
32*>
33*> where **T means transpose, A is symmetric (stored in packed format), U
34*> is orthogonal, and S is diagonal (if KBAND=0) or symmetric
35*> tridiagonal (if KBAND=1). If ITYPE=1, then U is represented as a
36*> dense matrix, otherwise the U is expressed as a product of
37*> Householder transformations, whose vectors are stored in the array
38*> "V" and whose scaling constants are in "TAU"; we shall use the
39*> letter "V" to refer to the product of Householder transformations
40*> (which should be equal to U).
41*>
42*> Specifically, if ITYPE=1, then:
43*>
44*> RESULT(1) = | A - U S U**T | / ( |A| n ulp ) and
45*> RESULT(2) = | I - U U**T | / ( n ulp )
46*>
47*> If ITYPE=2, then:
48*>
49*> RESULT(1) = | A - V S V**T | / ( |A| n ulp )
50*>
51*> If ITYPE=3, then:
52*>
53*> RESULT(1) = | I - V U**T | / ( n ulp )
54*>
55*> Packed storage means that, for example, if UPLO='U', then the columns
56*> of the upper triangle of A are stored one after another, so that
57*> A(1,j+1) immediately follows A(j,j) in the array AP. Similarly, if
58*> UPLO='L', then the columns of the lower triangle of A are stored one
59*> after another in AP, so that A(j+1,j+1) immediately follows A(n,j)
60*> in the array AP. This means that A(i,j) is stored in:
61*>
62*> AP( i + j*(j-1)/2 ) if UPLO='U'
63*>
64*> AP( i + (2*n-j)*(j-1)/2 ) if UPLO='L'
65*>
66*> The array VP bears the same relation to the matrix V that A does to
67*> AP.
68*>
69*> For ITYPE > 1, the transformation U is expressed as a product
70*> of Householder transformations:
71*>
72*> If UPLO='U', then V = H(n-1)...H(1), where
73*>
74*> H(j) = I - tau(j) v(j) v(j)**T
75*>
76*> and the first j-1 elements of v(j) are stored in V(1:j-1,j+1),
77*> (i.e., VP( j*(j+1)/2 + 1 : j*(j+1)/2 + j-1 ) ),
78*> the j-th element is 1, and the last n-j elements are 0.
79*>
80*> If UPLO='L', then V = H(1)...H(n-1), where
81*>
82*> H(j) = I - tau(j) v(j) v(j)**T
83*>
84*> and the first j elements of v(j) are 0, the (j+1)-st is 1, and the
85*> (j+2)-nd through n-th elements are stored in V(j+2:n,j) (i.e.,
86*> in VP( (2*n-j)*(j-1)/2 + j+2 : (2*n-j)*(j-1)/2 + n ) .)
87*> \endverbatim
88*
89* Arguments:
90* ==========
91*
92*> \param[in] ITYPE
93*> \verbatim
94*> ITYPE is INTEGER
95*> Specifies the type of tests to be performed.
96*> 1: U expressed as a dense orthogonal matrix:
97*> RESULT(1) = | A - U S U**T | / ( |A| n ulp ) and
98*> RESULT(2) = | I - U U**T | / ( n ulp )
99*>
100*> 2: U expressed as a product V of Housholder transformations:
101*> RESULT(1) = | A - V S V**T | / ( |A| n ulp )
102*>
103*> 3: U expressed both as a dense orthogonal matrix and
104*> as a product of Housholder transformations:
105*> RESULT(1) = | I - V U**T | / ( n ulp )
106*> \endverbatim
107*>
108*> \param[in] UPLO
109*> \verbatim
110*> UPLO is CHARACTER
111*> If UPLO='U', AP and VP are considered to contain the upper
112*> triangle of A and V.
113*> If UPLO='L', AP and VP are considered to contain the lower
114*> triangle of A and V.
115*> \endverbatim
116*>
117*> \param[in] N
118*> \verbatim
119*> N is INTEGER
120*> The size of the matrix. If it is zero, DSPT21 does nothing.
121*> It must be at least zero.
122*> \endverbatim
123*>
124*> \param[in] KBAND
125*> \verbatim
126*> KBAND is INTEGER
127*> The bandwidth of the matrix. It may only be zero or one.
128*> If zero, then S is diagonal, and E is not referenced. If
129*> one, then S is symmetric tri-diagonal.
130*> \endverbatim
131*>
132*> \param[in] AP
133*> \verbatim
134*> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
135*> The original (unfactored) matrix. It is assumed to be
136*> symmetric, and contains the columns of just the upper
137*> triangle (UPLO='U') or only the lower triangle (UPLO='L'),
138*> packed one after another.
139*> \endverbatim
140*>
141*> \param[in] D
142*> \verbatim
143*> D is DOUBLE PRECISION array, dimension (N)
144*> The diagonal of the (symmetric tri-) diagonal matrix.
145*> \endverbatim
146*>
147*> \param[in] E
148*> \verbatim
149*> E is DOUBLE PRECISION array, dimension (N-1)
150*> The off-diagonal of the (symmetric tri-) diagonal matrix.
151*> E(1) is the (1,2) and (2,1) element, E(2) is the (2,3) and
152*> (3,2) element, etc.
153*> Not referenced if KBAND=0.
154*> \endverbatim
155*>
156*> \param[in] U
157*> \verbatim
158*> U is DOUBLE PRECISION array, dimension (LDU, N)
159*> If ITYPE=1 or 3, this contains the orthogonal matrix in
160*> the decomposition, expressed as a dense matrix. If ITYPE=2,
161*> then it is not referenced.
162*> \endverbatim
163*>
164*> \param[in] LDU
165*> \verbatim
166*> LDU is INTEGER
167*> The leading dimension of U. LDU must be at least N and
168*> at least 1.
169*> \endverbatim
170*>
171*> \param[in] VP
172*> \verbatim
173*> VP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
174*> If ITYPE=2 or 3, the columns of this array contain the
175*> Householder vectors used to describe the orthogonal matrix
176*> in the decomposition, as described in purpose.
177*> *NOTE* If ITYPE=2 or 3, V is modified and restored. The
178*> subdiagonal (if UPLO='L') or the superdiagonal (if UPLO='U')
179*> is set to one, and later reset to its original value, during
180*> the course of the calculation.
181*> If ITYPE=1, then it is neither referenced nor modified.
182*> \endverbatim
183*>
184*> \param[in] TAU
185*> \verbatim
186*> TAU is DOUBLE PRECISION array, dimension (N)
187*> If ITYPE >= 2, then TAU(j) is the scalar factor of
188*> v(j) v(j)**T in the Householder transformation H(j) of
189*> the product U = H(1)...H(n-2)
190*> If ITYPE < 2, then TAU is not referenced.
191*> \endverbatim
192*>
193*> \param[out] WORK
194*> \verbatim
195*> WORK is DOUBLE PRECISION array, dimension (N**2+N)
196*> Workspace.
197*> \endverbatim
198*>
199*> \param[out] RESULT
200*> \verbatim
201*> RESULT is DOUBLE PRECISION array, dimension (2)
202*> The values computed by the two tests described above. The
203*> values are currently limited to 1/ulp, to avoid overflow.
204*> RESULT(1) is always modified. RESULT(2) is modified only
205*> if ITYPE=1.
206*> \endverbatim
207*
208* Authors:
209* ========
210*
211*> \author Univ. of Tennessee
212*> \author Univ. of California Berkeley
213*> \author Univ. of Colorado Denver
214*> \author NAG Ltd.
215*
216*> \ingroup double_eig
217*
218* =====================================================================
219 SUBROUTINE dspt21( ITYPE, UPLO, N, KBAND, AP, D, E, U, LDU, VP,
220 \$ TAU, WORK, RESULT )
221*
222* -- LAPACK test routine --
223* -- LAPACK is a software package provided by Univ. of Tennessee, --
224* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
225*
226* .. Scalar Arguments ..
227 CHARACTER UPLO
228 INTEGER ITYPE, KBAND, LDU, N
229* ..
230* .. Array Arguments ..
231 DOUBLE PRECISION AP( * ), D( * ), E( * ), RESULT( 2 ), TAU( * ),
232 \$ u( ldu, * ), vp( * ), work( * )
233* ..
234*
235* =====================================================================
236*
237* .. Parameters ..
238 DOUBLE PRECISION ZERO, ONE, TEN
239 parameter( zero = 0.0d0, one = 1.0d0, ten = 10.0d0 )
240 DOUBLE PRECISION HALF
241 parameter( half = 1.0d+0 / 2.0d+0 )
242* ..
243* .. Local Scalars ..
244 LOGICAL LOWER
245 CHARACTER CUPLO
246 INTEGER IINFO, J, JP, JP1, JR, LAP
247 DOUBLE PRECISION ANORM, TEMP, ULP, UNFL, VSAVE, WNORM
248* ..
249* .. External Functions ..
250 LOGICAL LSAME
251 DOUBLE PRECISION DDOT, DLAMCH, DLANGE, DLANSP
252 EXTERNAL lsame, ddot, dlamch, dlange, dlansp
253* ..
254* .. External Subroutines ..
255 EXTERNAL daxpy, dcopy, dgemm, dlacpy, dlaset, dopmtr,
256 \$ dspmv, dspr, dspr2
257* ..
258* .. Intrinsic Functions ..
259 INTRINSIC dble, max, min
260* ..
261* .. Executable Statements ..
262*
263* 1) Constants
264*
265 result( 1 ) = zero
266 IF( itype.EQ.1 )
267 \$ result( 2 ) = zero
268 IF( n.LE.0 )
269 \$ RETURN
270*
271 lap = ( n*( n+1 ) ) / 2
272*
273 IF( lsame( uplo, 'U' ) ) THEN
274 lower = .false.
275 cuplo = 'U'
276 ELSE
277 lower = .true.
278 cuplo = 'L'
279 END IF
280*
281 unfl = dlamch( 'Safe minimum' )
282 ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
283*
284* Some Error Checks
285*
286 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
287 result( 1 ) = ten / ulp
288 RETURN
289 END IF
290*
291* Do Test 1
292*
293* Norm of A:
294*
295 IF( itype.EQ.3 ) THEN
296 anorm = one
297 ELSE
298 anorm = max( dlansp( '1', cuplo, n, ap, work ), unfl )
299 END IF
300*
301* Compute error matrix:
302*
303 IF( itype.EQ.1 ) THEN
304*
305* ITYPE=1: error = A - U S U**T
306*
307 CALL dlaset( 'Full', n, n, zero, zero, work, n )
308 CALL dcopy( lap, ap, 1, work, 1 )
309*
310 DO 10 j = 1, n
311 CALL dspr( cuplo, n, -d( j ), u( 1, j ), 1, work )
312 10 CONTINUE
313*
314 IF( n.GT.1 .AND. kband.EQ.1 ) THEN
315 DO 20 j = 1, n - 1
316 CALL dspr2( cuplo, n, -e( j ), u( 1, j ), 1, u( 1, j+1 ),
317 \$ 1, work )
318 20 CONTINUE
319 END IF
320 wnorm = dlansp( '1', cuplo, n, work, work( n**2+1 ) )
321*
322 ELSE IF( itype.EQ.2 ) THEN
323*
324* ITYPE=2: error = V S V**T - A
325*
326 CALL dlaset( 'Full', n, n, zero, zero, work, n )
327*
328 IF( lower ) THEN
329 work( lap ) = d( n )
330 DO 40 j = n - 1, 1, -1
331 jp = ( ( 2*n-j )*( j-1 ) ) / 2
332 jp1 = jp + n - j
333 IF( kband.EQ.1 ) THEN
334 work( jp+j+1 ) = ( one-tau( j ) )*e( j )
335 DO 30 jr = j + 2, n
336 work( jp+jr ) = -tau( j )*e( j )*vp( jp+jr )
337 30 CONTINUE
338 END IF
339*
340 IF( tau( j ).NE.zero ) THEN
341 vsave = vp( jp+j+1 )
342 vp( jp+j+1 ) = one
343 CALL dspmv( 'L', n-j, one, work( jp1+j+1 ),
344 \$ vp( jp+j+1 ), 1, zero, work( lap+1 ), 1 )
345 temp = -half*tau( j )*ddot( n-j, work( lap+1 ), 1,
346 \$ vp( jp+j+1 ), 1 )
347 CALL daxpy( n-j, temp, vp( jp+j+1 ), 1, work( lap+1 ),
348 \$ 1 )
349 CALL dspr2( 'L', n-j, -tau( j ), vp( jp+j+1 ), 1,
350 \$ work( lap+1 ), 1, work( jp1+j+1 ) )
351 vp( jp+j+1 ) = vsave
352 END IF
353 work( jp+j ) = d( j )
354 40 CONTINUE
355 ELSE
356 work( 1 ) = d( 1 )
357 DO 60 j = 1, n - 1
358 jp = ( j*( j-1 ) ) / 2
359 jp1 = jp + j
360 IF( kband.EQ.1 ) THEN
361 work( jp1+j ) = ( one-tau( j ) )*e( j )
362 DO 50 jr = 1, j - 1
363 work( jp1+jr ) = -tau( j )*e( j )*vp( jp1+jr )
364 50 CONTINUE
365 END IF
366*
367 IF( tau( j ).NE.zero ) THEN
368 vsave = vp( jp1+j )
369 vp( jp1+j ) = one
370 CALL dspmv( 'U', j, one, work, vp( jp1+1 ), 1, zero,
371 \$ work( lap+1 ), 1 )
372 temp = -half*tau( j )*ddot( j, work( lap+1 ), 1,
373 \$ vp( jp1+1 ), 1 )
374 CALL daxpy( j, temp, vp( jp1+1 ), 1, work( lap+1 ),
375 \$ 1 )
376 CALL dspr2( 'U', j, -tau( j ), vp( jp1+1 ), 1,
377 \$ work( lap+1 ), 1, work )
378 vp( jp1+j ) = vsave
379 END IF
380 work( jp1+j+1 ) = d( j+1 )
381 60 CONTINUE
382 END IF
383*
384 DO 70 j = 1, lap
385 work( j ) = work( j ) - ap( j )
386 70 CONTINUE
387 wnorm = dlansp( '1', cuplo, n, work, work( lap+1 ) )
388*
389 ELSE IF( itype.EQ.3 ) THEN
390*
391* ITYPE=3: error = U V**T - I
392*
393 IF( n.LT.2 )
394 \$ RETURN
395 CALL dlacpy( ' ', n, n, u, ldu, work, n )
396 CALL dopmtr( 'R', cuplo, 'T', n, n, vp, tau, work, n,
397 \$ work( n**2+1 ), iinfo )
398 IF( iinfo.NE.0 ) THEN
399 result( 1 ) = ten / ulp
400 RETURN
401 END IF
402*
403 DO 80 j = 1, n
404 work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
405 80 CONTINUE
406*
407 wnorm = dlange( '1', n, n, work, n, work( n**2+1 ) )
408 END IF
409*
410 IF( anorm.GT.wnorm ) THEN
411 result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
412 ELSE
413 IF( anorm.LT.one ) THEN
414 result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
415 ELSE
416 result( 1 ) = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
417 END IF
418 END IF
419*
420* Do Test 2
421*
422* Compute U U**T - I
423*
424 IF( itype.EQ.1 ) THEN
425 CALL dgemm( 'N', 'C', n, n, n, one, u, ldu, u, ldu, zero, work,
426 \$ n )
427*
428 DO 90 j = 1, n
429 work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
430 90 CONTINUE
431*
432 result( 2 ) = min( dlange( '1', n, n, work, n,
433 \$ work( n**2+1 ) ), dble( n ) ) / ( n*ulp )
434 END IF
435*
436 RETURN
437*
438* End of DSPT21
439*
440 END
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: dlaset.f:110
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:89
subroutine dspr2(UPLO, N, ALPHA, X, INCX, Y, INCY, AP)
DSPR2
Definition: dspr2.f:142
subroutine dspr(UPLO, N, ALPHA, X, INCX, AP)
DSPR
Definition: dspr.f:127
subroutine dspmv(UPLO, N, ALPHA, AP, X, INCX, BETA, Y, INCY)
DSPMV
Definition: dspmv.f:147
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:187
subroutine dspt21(ITYPE, UPLO, N, KBAND, AP, D, E, U, LDU, VP, TAU, WORK, RESULT)
DSPT21
Definition: dspt21.f:221
subroutine dopmtr(SIDE, UPLO, TRANS, M, N, AP, TAU, C, LDC, WORK, INFO)
DOPMTR
Definition: dopmtr.f:150