LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
dspevd.f
Go to the documentation of this file.
1*> \brief <b> DSPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dspevd.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dspevd.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dspevd.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE DSPEVD( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK,
22* IWORK, LIWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER JOBZ, UPLO
26* INTEGER INFO, LDZ, LIWORK, LWORK, N
27* ..
28* .. Array Arguments ..
29* INTEGER IWORK( * )
30* DOUBLE PRECISION AP( * ), W( * ), WORK( * ), Z( LDZ, * )
31* ..
32*
33*
34*> \par Purpose:
35* =============
36*>
37*> \verbatim
38*>
39*> DSPEVD computes all the eigenvalues and, optionally, eigenvectors
40*> of a real symmetric matrix A in packed storage. If eigenvectors are
41*> desired, it uses a divide and conquer algorithm.
42*>
43*> \endverbatim
44*
45* Arguments:
46* ==========
47*
48*> \param[in] JOBZ
49*> \verbatim
50*> JOBZ is CHARACTER*1
51*> = 'N': Compute eigenvalues only;
52*> = 'V': Compute eigenvalues and eigenvectors.
53*> \endverbatim
54*>
55*> \param[in] UPLO
56*> \verbatim
57*> UPLO is CHARACTER*1
58*> = 'U': Upper triangle of A is stored;
59*> = 'L': Lower triangle of A is stored.
60*> \endverbatim
61*>
62*> \param[in] N
63*> \verbatim
64*> N is INTEGER
65*> The order of the matrix A. N >= 0.
66*> \endverbatim
67*>
68*> \param[in,out] AP
69*> \verbatim
70*> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
71*> On entry, the upper or lower triangle of the symmetric matrix
72*> A, packed columnwise in a linear array. The j-th column of A
73*> is stored in the array AP as follows:
74*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
75*> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
76*>
77*> On exit, AP is overwritten by values generated during the
78*> reduction to tridiagonal form. If UPLO = 'U', the diagonal
79*> and first superdiagonal of the tridiagonal matrix T overwrite
80*> the corresponding elements of A, and if UPLO = 'L', the
81*> diagonal and first subdiagonal of T overwrite the
82*> corresponding elements of A.
83*> \endverbatim
84*>
85*> \param[out] W
86*> \verbatim
87*> W is DOUBLE PRECISION array, dimension (N)
88*> If INFO = 0, the eigenvalues in ascending order.
89*> \endverbatim
90*>
91*> \param[out] Z
92*> \verbatim
93*> Z is DOUBLE PRECISION array, dimension (LDZ, N)
94*> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
95*> eigenvectors of the matrix A, with the i-th column of Z
96*> holding the eigenvector associated with W(i).
97*> If JOBZ = 'N', then Z is not referenced.
98*> \endverbatim
99*>
100*> \param[in] LDZ
101*> \verbatim
102*> LDZ is INTEGER
103*> The leading dimension of the array Z. LDZ >= 1, and if
104*> JOBZ = 'V', LDZ >= max(1,N).
105*> \endverbatim
106*>
107*> \param[out] WORK
108*> \verbatim
109*> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
110*> On exit, if INFO = 0, WORK(1) returns the required LWORK.
111*> \endverbatim
112*>
113*> \param[in] LWORK
114*> \verbatim
115*> LWORK is INTEGER
116*> The dimension of the array WORK.
117*> If N <= 1, LWORK must be at least 1.
118*> If JOBZ = 'N' and N > 1, LWORK must be at least 2*N.
119*> If JOBZ = 'V' and N > 1, LWORK must be at least
120*> 1 + 6*N + N**2.
121*>
122*> If LWORK = -1, then a workspace query is assumed; the routine
123*> only calculates the required sizes of the WORK and IWORK
124*> arrays, returns these values as the first entries of the WORK
125*> and IWORK arrays, and no error message related to LWORK or
126*> LIWORK is issued by XERBLA.
127*> \endverbatim
128*>
129*> \param[out] IWORK
130*> \verbatim
131*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
132*> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
133*> \endverbatim
134*>
135*> \param[in] LIWORK
136*> \verbatim
137*> LIWORK is INTEGER
138*> The dimension of the array IWORK.
139*> If JOBZ = 'N' or N <= 1, LIWORK must be at least 1.
140*> If JOBZ = 'V' and N > 1, LIWORK must be at least 3 + 5*N.
141*>
142*> If LIWORK = -1, then a workspace query is assumed; the
143*> routine only calculates the required sizes of the WORK and
144*> IWORK arrays, returns these values as the first entries of
145*> the WORK and IWORK arrays, and no error message related to
146*> LWORK or LIWORK is issued by XERBLA.
147*> \endverbatim
148*>
149*> \param[out] INFO
150*> \verbatim
151*> INFO is INTEGER
152*> = 0: successful exit
153*> < 0: if INFO = -i, the i-th argument had an illegal value.
154*> > 0: if INFO = i, the algorithm failed to converge; i
155*> off-diagonal elements of an intermediate tridiagonal
156*> form did not converge to zero.
157*> \endverbatim
158*
159* Authors:
160* ========
161*
162*> \author Univ. of Tennessee
163*> \author Univ. of California Berkeley
164*> \author Univ. of Colorado Denver
165*> \author NAG Ltd.
166*
167*> \ingroup hpevd
168*
169* =====================================================================
170 SUBROUTINE dspevd( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK,
171 \$ IWORK, LIWORK, INFO )
172*
173* -- LAPACK driver routine --
174* -- LAPACK is a software package provided by Univ. of Tennessee, --
175* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
176*
177* .. Scalar Arguments ..
178 CHARACTER JOBZ, UPLO
179 INTEGER INFO, LDZ, LIWORK, LWORK, N
180* ..
181* .. Array Arguments ..
182 INTEGER IWORK( * )
183 DOUBLE PRECISION AP( * ), W( * ), WORK( * ), Z( LDZ, * )
184* ..
185*
186* =====================================================================
187*
188* .. Parameters ..
189 DOUBLE PRECISION ZERO, ONE
190 parameter( zero = 0.0d+0, one = 1.0d+0 )
191* ..
192* .. Local Scalars ..
193 LOGICAL LQUERY, WANTZ
194 INTEGER IINFO, INDE, INDTAU, INDWRK, ISCALE, LIWMIN,
195 \$ llwork, lwmin
196 DOUBLE PRECISION ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
197 \$ smlnum
198* ..
199* .. External Functions ..
200 LOGICAL LSAME
201 DOUBLE PRECISION DLAMCH, DLANSP
202 EXTERNAL lsame, dlamch, dlansp
203* ..
204* .. External Subroutines ..
205 EXTERNAL dopmtr, dscal, dsptrd, dstedc, dsterf, xerbla
206* ..
207* .. Intrinsic Functions ..
208 INTRINSIC sqrt
209* ..
210* .. Executable Statements ..
211*
212* Test the input parameters.
213*
214 wantz = lsame( jobz, 'V' )
215 lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
216*
217 info = 0
218 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
219 info = -1
220 ELSE IF( .NOT.( lsame( uplo, 'U' ) .OR. lsame( uplo, 'L' ) ) )
221 \$ THEN
222 info = -2
223 ELSE IF( n.LT.0 ) THEN
224 info = -3
225 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
226 info = -7
227 END IF
228*
229 IF( info.EQ.0 ) THEN
230 IF( n.LE.1 ) THEN
231 liwmin = 1
232 lwmin = 1
233 ELSE
234 IF( wantz ) THEN
235 liwmin = 3 + 5*n
236 lwmin = 1 + 6*n + n**2
237 ELSE
238 liwmin = 1
239 lwmin = 2*n
240 END IF
241 END IF
242 iwork( 1 ) = liwmin
243 work( 1 ) = lwmin
244*
245 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
246 info = -9
247 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
248 info = -11
249 END IF
250 END IF
251*
252 IF( info.NE.0 ) THEN
253 CALL xerbla( 'DSPEVD', -info )
254 RETURN
255 ELSE IF( lquery ) THEN
256 RETURN
257 END IF
258*
259* Quick return if possible
260*
261 IF( n.EQ.0 )
262 \$ RETURN
263*
264 IF( n.EQ.1 ) THEN
265 w( 1 ) = ap( 1 )
266 IF( wantz )
267 \$ z( 1, 1 ) = one
268 RETURN
269 END IF
270*
271* Get machine constants.
272*
273 safmin = dlamch( 'Safe minimum' )
274 eps = dlamch( 'Precision' )
275 smlnum = safmin / eps
276 bignum = one / smlnum
277 rmin = sqrt( smlnum )
278 rmax = sqrt( bignum )
279*
280* Scale matrix to allowable range, if necessary.
281*
282 anrm = dlansp( 'M', uplo, n, ap, work )
283 iscale = 0
284 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
285 iscale = 1
286 sigma = rmin / anrm
287 ELSE IF( anrm.GT.rmax ) THEN
288 iscale = 1
289 sigma = rmax / anrm
290 END IF
291 IF( iscale.EQ.1 ) THEN
292 CALL dscal( ( n*( n+1 ) ) / 2, sigma, ap, 1 )
293 END IF
294*
295* Call DSPTRD to reduce symmetric packed matrix to tridiagonal form.
296*
297 inde = 1
298 indtau = inde + n
299 CALL dsptrd( uplo, n, ap, w, work( inde ), work( indtau ), iinfo )
300*
301* For eigenvalues only, call DSTERF. For eigenvectors, first call
302* DSTEDC to generate the eigenvector matrix, WORK(INDWRK), of the
303* tridiagonal matrix, then call DOPMTR to multiply it by the
304* Householder transformations represented in AP.
305*
306 IF( .NOT.wantz ) THEN
307 CALL dsterf( n, w, work( inde ), info )
308 ELSE
309 indwrk = indtau + n
310 llwork = lwork - indwrk + 1
311 CALL dstedc( 'I', n, w, work( inde ), z, ldz, work( indwrk ),
312 \$ llwork, iwork, liwork, info )
313 CALL dopmtr( 'L', uplo, 'N', n, n, ap, work( indtau ), z, ldz,
314 \$ work( indwrk ), iinfo )
315 END IF
316*
317* If matrix was scaled, then rescale eigenvalues appropriately.
318*
319 IF( iscale.EQ.1 )
320 \$ CALL dscal( n, one / sigma, w, 1 )
321*
322 work( 1 ) = lwmin
323 iwork( 1 ) = liwmin
324 RETURN
325*
326* End of DSPEVD
327*
328 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dspevd(jobz, uplo, n, ap, w, z, ldz, work, lwork, iwork, liwork, info)
DSPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition dspevd.f:172
subroutine dsptrd(uplo, n, ap, d, e, tau, info)
DSPTRD
Definition dsptrd.f:150
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
subroutine dstedc(compz, n, d, e, z, ldz, work, lwork, iwork, liwork, info)
DSTEDC
Definition dstedc.f:182
subroutine dsterf(n, d, e, info)
DSTERF
Definition dsterf.f:86
subroutine dopmtr(side, uplo, trans, m, n, ap, tau, c, ldc, work, info)
DOPMTR
Definition dopmtr.f:150