sla_gercond.f

Go to the documentation of this file.

*> \brief \b SLA_GERCOND estimates the Skeel condition number for a general matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download SLA_GERCOND + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sla_gercond.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sla_gercond.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sla_gercond.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       REAL FUNCTION SLA_GERCOND( TRANS, N, A, LDA, AF, LDAF, IPIV,
*                                  CMODE, C, INFO, WORK, IWORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            N, LDA, LDAF, INFO, CMODE
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * ), IWORK( * )
*       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ),
*      $                   C( * )
*      ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    SLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
*>    where op2 is determined by CMODE as follows
*>    CMODE =  1    op2(C) = C
*>    CMODE =  0    op2(C) = I
*>    CMODE = -1    op2(C) = inv(C)
*>    The Skeel condition number cond(A) = norminf( |inv(A)||A| )
*>    is computed by computing scaling factors R such that
*>    diag(R)*A*op2(C) is row equilibrated and computing the standard
*>    infinity-norm condition number.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>     Specifies the form of the system of equations:
*>       = 'N':  A * X = B     (No transpose)
*>       = 'T':  A**T * X = B  (Transpose)
*>       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>     The number of linear equations, i.e., the order of the
*>     matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>     On entry, the N-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>     The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is REAL array, dimension (LDAF,N)
*>     The factors L and U from the factorization
*>     A = P*L*U as computed by SGETRF.
*> \endverbatim
*>
*> \param[in] LDAF
*> \verbatim
*>          LDAF is INTEGER
*>     The leading dimension of the array AF.  LDAF >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>     The pivot indices from the factorization A = P*L*U
*>     as computed by SGETRF; row i of the matrix was interchanged
*>     with row IPIV(i).
*> \endverbatim
*>
*> \param[in] CMODE
*> \verbatim
*>          CMODE is INTEGER
*>     Determines op2(C) in the formula op(A) * op2(C) as follows:
*>     CMODE =  1    op2(C) = C
*>     CMODE =  0    op2(C) = I
*>     CMODE = -1    op2(C) = inv(C)
*> \endverbatim
*>
*> \param[in] C
*> \verbatim
*>          C is REAL array, dimension (N)
*>     The vector C in the formula op(A) * op2(C).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>       = 0:  Successful exit.
*>     i > 0:  The ith argument is invalid.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (3*N).
*>     Workspace.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (N).
*>     Workspace.2
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup la_gercond
*
*  =====================================================================
      REAL function sla_gercond( trans, n, a, lda, af, ldaf, ipiv,
     $                           cmode, c, info, work, iwork )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            n, lda, ldaf, info, cmode
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * ), iwork( * )
      REAL               a( lda, * ), af( ldaf, * ), work( * ),
     $                   c( * )
*    ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            notrans
      INTEGER            kase, i, j
      REAL               ainvnm, tmp
*     ..
*     .. Local Arrays ..
      INTEGER            isave( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           slacn2, sgetrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      sla_gercond = 0.0
*
      info = 0
      notrans = lsame( trans, 'N' )
      IF ( .NOT. notrans .AND. .NOT. lsame(trans, 'T')
     $     .AND. .NOT. lsame(trans, 'C') ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( ldaf.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLA_GERCOND', -info )
         RETURN
      END IF
      IF( n.EQ.0 ) THEN
         sla_gercond = 1.0
         RETURN
      END IF
*
*     Compute the equilibration matrix R such that
*     inv(R)*A*C has unit 1-norm.
*
      IF (notrans) THEN
         DO i = 1, n
            tmp = 0.0
            IF ( cmode .EQ. 1 ) THEN
               DO j = 1, n
                  tmp = tmp + abs( a( i, j ) * c( j ) )
               END DO
            ELSE IF ( cmode .EQ. 0 ) THEN
               DO j = 1, n
                  tmp = tmp + abs( a( i, j ) )
               END DO
            ELSE
               DO j = 1, n
                  tmp = tmp + abs( a( i, j ) / c( j ) )
               END DO
            END IF
            work( 2*n+i ) = tmp
         END DO
      ELSE
         DO i = 1, n
            tmp = 0.0
            IF ( cmode .EQ. 1 ) THEN
               DO j = 1, n
                  tmp = tmp + abs( a( j, i ) * c( j ) )
               END DO
            ELSE IF ( cmode .EQ. 0 ) THEN
               DO j = 1, n
                  tmp = tmp + abs( a( j, i ) )
               END DO
            ELSE
               DO j = 1, n
                  tmp = tmp + abs( a( j, i ) / c( j ) )
               END DO
            END IF
            work( 2*n+i ) = tmp
         END DO
      END IF
*
*     Estimate the norm of inv(op(A)).
*
      ainvnm = 0.0
 
      kase = 0
   10 CONTINUE
      CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.2 ) THEN
*
*           Multiply by R.
*
            DO i = 1, n
               work(i) = work(i) * work(2*n+i)
            END DO
 
            IF (notrans) THEN
               CALL sgetrs( 'No transpose', n, 1, af, ldaf, ipiv,
     $            work, n, info )
            ELSE
               CALL sgetrs( 'Transpose', n, 1, af, ldaf, ipiv,
     $            work, n, info )
            END IF
*
*           Multiply by inv(C).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
         ELSE
*
*           Multiply by inv(C**T).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
 
            IF (notrans) THEN
               CALL sgetrs( 'Transpose', n, 1, af, ldaf, ipiv,
     $            work, n, info )
            ELSE
               CALL sgetrs( 'No transpose', n, 1, af, ldaf, ipiv,
     $            work, n, info )
            END IF
*
*           Multiply by R.
*
            DO i = 1, n
               work( i ) = work( i ) * work( 2*n+i )
            END DO
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm .NE. 0.0 )
     $   sla_gercond = ( 1.0 / ainvnm )
*
      RETURN
*
*     End of SLA_GERCOND
*
      END