cla_herpvgrw()

real function cla_herpvgrw	(	character*1	uplo,
		integer	n,
		integer	info,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldaf, * )	af,
		integer	ldaf,
		integer, dimension( * )	ipiv,
		real, dimension( * )	work
	)

CLA_HERPVGRW

Download CLA_HERPVGRW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLA_HERPVGRW computes the reciprocal pivot growth factor
 norm(A)/norm(U). The "max absolute element" norm is used. If this is
 much less than 1, the stability of the LU factorization of the
 (equilibrated) matrix A could be poor. This also means that the
 solution X, estimated condition numbers, and error bounds could be
 unreliable.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.
[in]	INFO	INFO is INTEGER The value of INFO returned from SSYTRF, .i.e., the pivot in column INFO is exactly 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) On entry, the N-by-N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	AF	AF is COMPLEX array, dimension (LDAF,N) The block diagonal matrix D and the multipliers used to obtain the factor U or L as computed by CHETRF.
[in]	LDAF	LDAF is INTEGER The leading dimension of the array AF. LDAF >= max(1,N).
[in]	IPIV	IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D as determined by CHETRF.
[out]	WORK	WORK is REAL array, dimension (2*N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 121 of file cla_herpvgrw.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            N, INFO, LDA, LDAF
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( LDA, * ), AF( LDAF, * )
      REAL               WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            NCOLS, I, J, K, KP
      REAL               AMAX, UMAX, RPVGRW, TMP
      LOGICAL            UPPER, LSAME
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, aimag, max, min
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
      upper = lsame( 'Upper', uplo )
      IF ( info.EQ.0 ) THEN
         IF (upper) THEN
            ncols = 1
         ELSE
            ncols = n
         END IF
      ELSE
         ncols = info
      END IF
 
      rpvgrw = 1.0
      DO i = 1, 2*n
         work( i ) = 0.0
      END DO
*
*     Find the max magnitude entry of each column of A.  Compute the max
*     for all N columns so we can apply the pivot permutation while
*     looping below.  Assume a full factorization is the common case.
*
      IF ( upper ) THEN
         DO j = 1, n
            DO i = 1, j
               work( n+i ) = max( cabs1( a( i,j ) ), work( n+i ) )
               work( n+j ) = max( cabs1( a( i,j ) ), work( n+j ) )
            END DO
         END DO
      ELSE
         DO j = 1, n
            DO i = j, n
               work( n+i ) = max( cabs1( a( i, j ) ), work( n+i ) )
               work( n+j ) = max( cabs1( a( i, j ) ), work( n+j ) )
            END DO
         END DO
      END IF
*
*     Now find the max magnitude entry of each column of U or L.  Also
*     permute the magnitudes of A above so they're in the same order as
*     the factor.
*
*     The iteration orders and permutations were copied from csytrs.
*     Calls to SSWAP would be severe overkill.
*
      IF ( upper ) THEN
         k = n
         DO WHILE ( k .LT. ncols .AND. k.GT.0 )
            IF ( ipiv( k ).GT.0 ) THEN
!              1x1 pivot
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               DO i = 1, k
                  work( k ) = max( cabs1( af( i, k ) ), work( k ) )
               END DO
               k = k - 1
            ELSE
!              2x2 pivot
               kp = -ipiv( k )
               tmp = work( n+k-1 )
               work( n+k-1 ) = work( n+kp )
               work( n+kp ) = tmp
               DO i = 1, k-1
                  work( k ) = max( cabs1( af( i, k ) ), work( k ) )
                  work( k-1 ) =
     $                 max( cabs1( af( i, k-1 ) ), work( k-1 ) )
               END DO
               work( k ) = max( cabs1( af( k, k ) ), work( k ) )
               k = k - 2
            END IF
         END DO
         k = ncols
         DO WHILE ( k .LE. n )
            IF ( ipiv( k ).GT.0 ) THEN
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               k = k + 1
            ELSE
               kp = -ipiv( k )
               tmp = work( n+k )
               work( n+k ) = work( n+kp )
               work( n+kp ) = tmp
               k = k + 2
            END IF
         END DO
      ELSE
         k = 1
         DO WHILE ( k .LE. ncols )
            IF ( ipiv( k ).GT.0 ) THEN
!              1x1 pivot
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               DO i = k, n
                  work( k ) = max( cabs1( af( i, k ) ), work( k ) )
               END DO
               k = k + 1
            ELSE
!              2x2 pivot
               kp = -ipiv( k )
               tmp = work( n+k+1 )
               work( n+k+1 ) = work( n+kp )
               work( n+kp ) = tmp
               DO i = k+1, n
                  work( k ) = max( cabs1( af( i, k ) ), work( k ) )
                  work( k+1 ) =
     $                 max( cabs1( af( i, k+1 ) ) , work( k+1 ) )
               END DO
               work(k) = max( cabs1( af( k, k ) ), work( k ) )
               k = k + 2
            END IF
         END DO
         k = ncols
         DO WHILE ( k .GE. 1 )
            IF ( ipiv( k ).GT.0 ) THEN
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               k = k - 1
            ELSE
               kp = -ipiv( k )
               tmp = work( n+k )
               work( n+k ) = work( n+kp )
               work( n+kp ) = tmp
               k = k - 2
            ENDIF
         END DO
      END IF
*
*     Compute the *inverse* of the max element growth factor.  Dividing
*     by zero would imply the largest entry of the factor's column is
*     zero.  Than can happen when either the column of A is zero or
*     massive pivots made the factor underflow to zero.  Neither counts
*     as growth in itself, so simply ignore terms with zero
*     denominators.
*
      IF ( upper ) THEN
         DO i = ncols, n
            umax = work( i )
            amax = work( n+i )
            IF ( umax /= 0.0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      ELSE
         DO i = 1, ncols
            umax = work( i )
            amax = work( n+i )
            IF ( umax /= 0.0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      END IF
 
      cla_herpvgrw = rpvgrw
*
*     End of CLA_HERPVGRW
*

Here is the call graph for this function:

Here is the caller graph for this function: