LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dlarzb()

subroutine dlarzb ( character side,
character trans,
character direct,
character storev,
integer m,
integer n,
integer k,
integer l,
double precision, dimension( ldv, * ) v,
integer ldv,
double precision, dimension( ldt, * ) t,
integer ldt,
double precision, dimension( ldc, * ) c,
integer ldc,
double precision, dimension( ldwork, * ) work,
integer ldwork )

DLARZB applies a block reflector or its transpose to a general matrix.

Download DLARZB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> DLARZB applies a real block reflector H or its transpose H**T to
!> a real distributed M-by-N  C from the left or the right.
!>
!> Currently, only STOREV = 'R' and DIRECT = 'B' are supported.
!>
Parameters
[in]SIDE
!>          SIDE is CHARACTER*1
!>          = 'L': apply H or H**T from the Left
!>          = 'R': apply H or H**T from the Right
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          = 'N': apply H (No transpose)
!>          = 'C': apply H**T (Transpose)
!>
[in]DIRECT
!>          DIRECT is CHARACTER*1
!>          Indicates how H is formed from a product of elementary
!>          reflectors
!>          = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet)
!>          = 'B': H = H(k) . . . H(2) H(1) (Backward)
!>
[in]STOREV
!>          STOREV is CHARACTER*1
!>          Indicates how the vectors which define the elementary
!>          reflectors are stored:
!>          = 'C': Columnwise                        (not supported yet)
!>          = 'R': Rowwise
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix C.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix C.
!>
[in]K
!>          K is INTEGER
!>          The order of the matrix T (= the number of elementary
!>          reflectors whose product defines the block reflector).
!>
[in]L
!>          L is INTEGER
!>          The number of columns of the matrix V containing the
!>          meaningful part of the Householder reflectors.
!>          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
!>
[in]V
!>          V is DOUBLE PRECISION array, dimension (LDV,NV).
!>          If STOREV = 'C', NV = K; if STOREV = 'R', NV = L.
!>
[in]LDV
!>          LDV is INTEGER
!>          The leading dimension of the array V.
!>          If STOREV = 'C', LDV >= L; if STOREV = 'R', LDV >= K.
!>
[in]T
!>          T is DOUBLE PRECISION array, dimension (LDT,K)
!>          The triangular K-by-K matrix T in the representation of the
!>          block reflector.
!>
[in]LDT
!>          LDT is INTEGER
!>          The leading dimension of the array T. LDT >= K.
!>
[in,out]C
!>          C is DOUBLE PRECISION array, dimension (LDC,N)
!>          On entry, the M-by-N matrix C.
!>          On exit, C is overwritten by H*C or H**T*C or C*H or C*H**T.
!>
[in]LDC
!>          LDC is INTEGER
!>          The leading dimension of the array C. LDC >= max(1,M).
!>
[out]WORK
!>          WORK is DOUBLE PRECISION array, dimension (LDWORK,K)
!>
[in]LDWORK
!>          LDWORK is INTEGER
!>          The leading dimension of the array WORK.
!>          If SIDE = 'L', LDWORK >= max(1,N);
!>          if SIDE = 'R', LDWORK >= max(1,M).
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
Further Details:
!>

Definition at line 179 of file dlarzb.f.

181*
182* -- LAPACK computational routine --
183* -- LAPACK is a software package provided by Univ. of Tennessee, --
184* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
185*
186* .. Scalar Arguments ..
187 CHARACTER DIRECT, SIDE, STOREV, TRANS
188 INTEGER K, L, LDC, LDT, LDV, LDWORK, M, N
189* ..
190* .. Array Arguments ..
191 DOUBLE PRECISION C( LDC, * ), T( LDT, * ), V( LDV, * ),
192 $ WORK( LDWORK, * )
193* ..
194*
195* =====================================================================
196*
197* .. Parameters ..
198 DOUBLE PRECISION ONE
199 parameter( one = 1.0d+0 )
200* ..
201* .. Local Scalars ..
202 CHARACTER TRANST
203 INTEGER I, INFO, J
204* ..
205* .. External Functions ..
206 LOGICAL LSAME
207 EXTERNAL lsame
208* ..
209* .. External Subroutines ..
210 EXTERNAL dcopy, dgemm, dtrmm, xerbla
211* ..
212* .. Executable Statements ..
213*
214* Quick return if possible
215*
216 IF( m.LE.0 .OR. n.LE.0 )
217 $ RETURN
218*
219* Check for currently supported options
220*
221 info = 0
222 IF( .NOT.lsame( direct, 'B' ) ) THEN
223 info = -3
224 ELSE IF( .NOT.lsame( storev, 'R' ) ) THEN
225 info = -4
226 END IF
227 IF( info.NE.0 ) THEN
228 CALL xerbla( 'DLARZB', -info )
229 RETURN
230 END IF
231*
232 IF( lsame( trans, 'N' ) ) THEN
233 transt = 'T'
234 ELSE
235 transt = 'N'
236 END IF
237*
238 IF( lsame( side, 'L' ) ) THEN
239*
240* Form H * C or H**T * C
241*
242* W( 1:n, 1:k ) = C( 1:k, 1:n )**T
243*
244 DO 10 j = 1, k
245 CALL dcopy( n, c( j, 1 ), ldc, work( 1, j ), 1 )
246 10 CONTINUE
247*
248* W( 1:n, 1:k ) = W( 1:n, 1:k ) + ...
249* C( m-l+1:m, 1:n )**T * V( 1:k, 1:l )**T
250*
251 IF( l.GT.0 )
252 $ CALL dgemm( 'Transpose', 'Transpose', n, k, l, one,
253 $ c( m-l+1, 1 ), ldc, v, ldv, one, work, ldwork )
254*
255* W( 1:n, 1:k ) = W( 1:n, 1:k ) * T**T or W( 1:m, 1:k ) * T
256*
257 CALL dtrmm( 'Right', 'Lower', transt, 'Non-unit', n, k, one,
258 $ t,
259 $ ldt, work, ldwork )
260*
261* C( 1:k, 1:n ) = C( 1:k, 1:n ) - W( 1:n, 1:k )**T
262*
263 DO 30 j = 1, n
264 DO 20 i = 1, k
265 c( i, j ) = c( i, j ) - work( j, i )
266 20 CONTINUE
267 30 CONTINUE
268*
269* C( m-l+1:m, 1:n ) = C( m-l+1:m, 1:n ) - ...
270* V( 1:k, 1:l )**T * W( 1:n, 1:k )**T
271*
272 IF( l.GT.0 )
273 $ CALL dgemm( 'Transpose', 'Transpose', l, n, k, -one, v,
274 $ ldv,
275 $ work, ldwork, one, c( m-l+1, 1 ), ldc )
276*
277 ELSE IF( lsame( side, 'R' ) ) THEN
278*
279* Form C * H or C * H**T
280*
281* W( 1:m, 1:k ) = C( 1:m, 1:k )
282*
283 DO 40 j = 1, k
284 CALL dcopy( m, c( 1, j ), 1, work( 1, j ), 1 )
285 40 CONTINUE
286*
287* W( 1:m, 1:k ) = W( 1:m, 1:k ) + ...
288* C( 1:m, n-l+1:n ) * V( 1:k, 1:l )**T
289*
290 IF( l.GT.0 )
291 $ CALL dgemm( 'No transpose', 'Transpose', m, k, l, one,
292 $ c( 1, n-l+1 ), ldc, v, ldv, one, work, ldwork )
293*
294* W( 1:m, 1:k ) = W( 1:m, 1:k ) * T or W( 1:m, 1:k ) * T**T
295*
296 CALL dtrmm( 'Right', 'Lower', trans, 'Non-unit', m, k, one,
297 $ t,
298 $ ldt, work, ldwork )
299*
300* C( 1:m, 1:k ) = C( 1:m, 1:k ) - W( 1:m, 1:k )
301*
302 DO 60 j = 1, k
303 DO 50 i = 1, m
304 c( i, j ) = c( i, j ) - work( i, j )
305 50 CONTINUE
306 60 CONTINUE
307*
308* C( 1:m, n-l+1:n ) = C( 1:m, n-l+1:n ) - ...
309* W( 1:m, 1:k ) * V( 1:k, 1:l )
310*
311 IF( l.GT.0 )
312 $ CALL dgemm( 'No transpose', 'No transpose', m, l, k,
313 $ -one,
314 $ work, ldwork, v, ldv, one, c( 1, n-l+1 ), ldc )
315*
316 END IF
317*
318 RETURN
319*
320* End of DLARZB
321*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
dcopy
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
dgemm
subroutine dgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
DGEMM
Definition dgemm.f:188
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
dtrmm
subroutine dtrmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
DTRMM
Definition dtrmm.f:177
Here is the call graph for this function:
Here is the caller graph for this function: