cptts2()

subroutine cptts2	(	integer	iuplo,
		integer	n,
		integer	nrhs,
		real, dimension( * )	d,
		complex, dimension( * )	e,
		complex, dimension( ldb, * )	b,
		integer	ldb )

CPTTS2 solves a tridiagonal system of the form AX=B using the L D LH factorization computed by spttrf.

Download CPTTS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPTTS2 solves a tridiagonal system of the form
!>    A * X = B
!> using the factorization A = U**H*D*U or A = L*D*L**H computed by CPTTRF.
!> D is a diagonal matrix specified in the vector D, U (or L) is a unit
!> bidiagonal matrix whose superdiagonal (subdiagonal) is specified in
!> the vector E, and X and B are N by NRHS matrices.
!> 

Parameters

[in]	IUPLO	!> IUPLO is INTEGER !> Specifies the form of the factorization and whether the !> vector E is the superdiagonal of the upper bidiagonal factor !> U or the subdiagonal of the lower bidiagonal factor L. !> = 1: A = U**H *D*U, E is the superdiagonal of U !> = 0: A = L*D*L**H, E is the subdiagonal of L !>
[in]	N	!> N is INTEGER !> The order of the tridiagonal matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	D	!> D is REAL array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> factorization A = U**H *D*U or A = L*D*L**H. !>
[in]	E	!> E is COMPLEX array, dimension (N-1) !> If IUPLO = 1, the (n-1) superdiagonal elements of the unit !> bidiagonal factor U from the factorization A = U**H*D*U. !> If IUPLO = 0, the (n-1) subdiagonal elements of the unit !> bidiagonal factor L from the factorization A = L*D*L**H. !>
[in,out]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> On entry, the right hand side vectors B for the system of !> linear equations. !> On exit, the solution vectors, X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 110 of file cptts2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IUPLO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               D( * )
      COMPLEX            B( LDB, * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. External Subroutines ..
      EXTERNAL           csscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 ) THEN
         IF( n.EQ.1 )
     $      CALL csscal( nrhs, 1. / d( 1 ), b, ldb )
         RETURN
      END IF
*
      IF( iuplo.EQ.1 ) THEN
*
*        Solve A * X = B using the factorization A = U**H *D*U,
*        overwriting each right hand side vector with its solution.
*
         IF( nrhs.LE.2 ) THEN
            j = 1
    5       CONTINUE
*
*           Solve U**H * x = b.
*
            DO 10 i = 2, n
               b( i, j ) = b( i, j ) - b( i-1, j )*conjg( e( i-1 ) )
   10       CONTINUE
*
*           Solve D * U * x = b.
*
            DO 20 i = 1, n
               b( i, j ) = b( i, j ) / d( i )
   20       CONTINUE
            DO 30 i = n - 1, 1, -1
               b( i, j ) = b( i, j ) - b( i+1, j )*e( i )
   30       CONTINUE
            IF( j.LT.nrhs ) THEN
               j = j + 1
               GO TO 5
            END IF
         ELSE
            DO 60 j = 1, nrhs
*
*              Solve U**H * x = b.
*
               DO 40 i = 2, n
                  b( i, j ) = b( i, j ) - b( i-1, j )*conjg( e( i-1 ) )
   40          CONTINUE
*
*              Solve D * U * x = b.
*
               b( n, j ) = b( n, j ) / d( n )
               DO 50 i = n - 1, 1, -1
                  b( i, j ) = b( i, j ) / d( i ) - b( i+1, j )*e( i )
   50          CONTINUE
   60       CONTINUE
         END IF
      ELSE
*
*        Solve A * X = B using the factorization A = L*D*L**H,
*        overwriting each right hand side vector with its solution.
*
         IF( nrhs.LE.2 ) THEN
            j = 1
   65       CONTINUE
*
*           Solve L * x = b.
*
            DO 70 i = 2, n
               b( i, j ) = b( i, j ) - b( i-1, j )*e( i-1 )
   70       CONTINUE
*
*           Solve D * L**H * x = b.
*
            DO 80 i = 1, n
               b( i, j ) = b( i, j ) / d( i )
   80       CONTINUE
            DO 90 i = n - 1, 1, -1
               b( i, j ) = b( i, j ) - b( i+1, j )*conjg( e( i ) )
   90       CONTINUE
            IF( j.LT.nrhs ) THEN
               j = j + 1
               GO TO 65
            END IF
         ELSE
            DO 120 j = 1, nrhs
*
*              Solve L * x = b.
*
               DO 100 i = 2, n
                  b( i, j ) = b( i, j ) - b( i-1, j )*e( i-1 )
  100          CONTINUE
*
*              Solve D * L**H * x = b.
*
               b( n, j ) = b( n, j ) / d( n )
               DO 110 i = n - 1, 1, -1
                  b( i, j ) = b( i, j ) / d( i ) -
     $                        b( i+1, j )*conjg( e( i ) )
  110          CONTINUE
  120       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of CPTTS2
*

Here is the call graph for this function:

Here is the caller graph for this function: