LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
slaswlq.f
Go to the documentation of this file.
1*> \brief \b SLASWLQ
2*
3* Definition:
4* ===========
5*
6* SUBROUTINE SLASWLQ( M, N, MB, NB, A, LDA, T, LDT, WORK,
7* LWORK, INFO)
8*
9* .. Scalar Arguments ..
10* INTEGER INFO, LDA, M, N, MB, NB, LDT, LWORK
11* ..
12* .. Array Arguments ..
13* REAL A( LDA, * ), T( LDT, * ), WORK( * )
14* ..
15*
16*
17*> \par Purpose:
18* =============
19*>
20*> \verbatim
21*>
22*> SLASWLQ computes a blocked Tall-Skinny LQ factorization of
23*> a real M-by-N matrix A for M <= N:
24*>
25*> A = ( L 0 ) * Q,
26*>
27*> where:
28*>
29*> Q is a n-by-N orthogonal matrix, stored on exit in an implicit
30*> form in the elements above the diagonal of the array A and in
31*> the elements of the array T;
32*> L is a lower-triangular M-by-M matrix stored on exit in
33*> the elements on and below the diagonal of the array A.
34*> 0 is a M-by-(N-M) zero matrix, if M < N, and is not stored.
35*>
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] M
42*> \verbatim
43*> M is INTEGER
44*> The number of rows of the matrix A. M >= 0.
45*> \endverbatim
46*>
47*> \param[in] N
48*> \verbatim
49*> N is INTEGER
50*> The number of columns of the matrix A. N >= M >= 0.
51*> \endverbatim
52*>
53*> \param[in] MB
54*> \verbatim
55*> MB is INTEGER
56*> The row block size to be used in the blocked QR.
57*> M >= MB >= 1
58*> \endverbatim
59*> \param[in] NB
60*> \verbatim
61*> NB is INTEGER
62*> The column block size to be used in the blocked QR.
63*> NB > 0.
64*> \endverbatim
65*>
66*> \param[in,out] A
67*> \verbatim
68*> A is REAL array, dimension (LDA,N)
69*> On entry, the M-by-N matrix A.
70*> On exit, the elements on and below the diagonal
71*> of the array contain the N-by-N lower triangular matrix L;
72*> the elements above the diagonal represent Q by the rows
73*> of blocked V (see Further Details).
74*>
75*> \endverbatim
76*>
77*> \param[in] LDA
78*> \verbatim
79*> LDA is INTEGER
80*> The leading dimension of the array A. LDA >= max(1,M).
81*> \endverbatim
82*>
83*> \param[out] T
84*> \verbatim
85*> T is REAL array,
86*> dimension (LDT, N * Number_of_row_blocks)
87*> where Number_of_row_blocks = CEIL((N-M)/(NB-M))
88*> The blocked upper triangular block reflectors stored in compact form
89*> as a sequence of upper triangular blocks.
90*> See Further Details below.
91*> \endverbatim
92*>
93*> \param[in] LDT
94*> \verbatim
95*> LDT is INTEGER
96*> The leading dimension of the array T. LDT >= MB.
97*> \endverbatim
98*>
99*>
100*> \param[out] WORK
101*> \verbatim
102*> (workspace) REAL array, dimension (MAX(1,LWORK))
103*>
104*> \endverbatim
105*> \param[in] LWORK
106*> \verbatim
107*> LWORK is INTEGER
108*> The dimension of the array WORK. LWORK >= MB * M.
109*> If LWORK = -1, then a workspace query is assumed; the routine
110*> only calculates the optimal size of the WORK array, returns
111*> this value as the first entry of the WORK array, and no error
112*> message related to LWORK is issued by XERBLA.
113*>
114*> \endverbatim
115*> \param[out] INFO
116*> \verbatim
117*> INFO is INTEGER
118*> = 0: successful exit
119*> < 0: if INFO = -i, the i-th argument had an illegal value
120*> \endverbatim
121*
122* Authors:
123* ========
124*
125*> \author Univ. of Tennessee
126*> \author Univ. of California Berkeley
127*> \author Univ. of Colorado Denver
128*> \author NAG Ltd.
129*
130*> \par Further Details:
131* =====================
132*>
133*> \verbatim
134*> Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations,
135*> representing Q as a product of other orthogonal matrices
136*> Q = Q(1) * Q(2) * . . . * Q(k)
137*> where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
138*> Q(1) zeros out the upper diagonal entries of rows 1:NB of A
139*> Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
140*> Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
141*> . . .
142*>
143*> Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
144*> stored under the diagonal of rows 1:MB of A, and by upper triangular
145*> block reflectors, stored in array T(1:LDT,1:N).
147*>
148*> Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
149*> stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
150*> block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
151*> The last Q(k) may use fewer rows.
153*>
154*> For more details of the overall algorithm, see the description of
155*> Sequential TSQR in Section 2.2 of [1].
156*>
157*> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
158*> J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
159*> SIAM J. Sci. Comput, vol. 34, no. 1, 2012
160*> \endverbatim
161*>
162*> \ingroup laswlq
163*>
164* =====================================================================
165 SUBROUTINE slaswlq( M, N, MB, NB, A, LDA, T, LDT, WORK, LWORK,
166 \$ INFO)
167*
168* -- LAPACK computational routine --
169* -- LAPACK is a software package provided by Univ. of Tennessee, --
170* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
171*
172* .. Scalar Arguments ..
173 INTEGER INFO, LDA, M, N, MB, NB, LWORK, LDT
174* ..
175* .. Array Arguments ..
176 REAL A( LDA, * ), WORK( * ), T( LDT, *)
177* ..
178*
179* =====================================================================
180*
181* ..
182* .. Local Scalars ..
183 LOGICAL LQUERY
184 INTEGER I, II, KK, CTR
185* ..
186* .. EXTERNAL FUNCTIONS ..
187 LOGICAL LSAME
188 REAL SROUNDUP_LWORK
189 EXTERNAL lsame, sroundup_lwork
190* .. EXTERNAL SUBROUTINES ..
191 EXTERNAL sgelqt, sgeqrt, stplqt, stpqrt, xerbla
192* .. INTRINSIC FUNCTIONS ..
193 INTRINSIC max, min, mod
194* ..
195* .. EXECUTABLE STATEMENTS ..
196*
197* TEST THE INPUT ARGUMENTS
198*
199 info = 0
200*
201 lquery = ( lwork.EQ.-1 )
202*
203 IF( m.LT.0 ) THEN
204 info = -1
205 ELSE IF( n.LT.0 .OR. n.LT.m ) THEN
206 info = -2
207 ELSE IF( mb.LT.1 .OR. ( mb.GT.m .AND. m.GT.0 )) THEN
208 info = -3
209 ELSE IF( nb.LE.0 ) THEN
210 info = -4
211 ELSE IF( lda.LT.max( 1, m ) ) THEN
212 info = -6
213 ELSE IF( ldt.LT.mb ) THEN
214 info = -8
215 ELSE IF( ( lwork.LT.m*mb) .AND. (.NOT.lquery) ) THEN
216 info = -10
217 END IF
218 IF( info.EQ.0) THEN
219 work(1) = mb*m
220 END IF
221*
222 IF( info.NE.0 ) THEN
223 CALL xerbla( 'SLASWLQ', -info )
224 RETURN
225 ELSE IF (lquery) THEN
226 RETURN
227 END IF
228*
229* Quick return if possible
230*
231 IF( min(m,n).EQ.0 ) THEN
232 RETURN
233 END IF
234*
235* The LQ Decomposition
236*
237 IF((m.GE.n).OR.(nb.LE.m).OR.(nb.GE.n)) THEN
238 CALL sgelqt( m, n, mb, a, lda, t, ldt, work, info)
239 RETURN
240 END IF
241*
242 kk = mod((n-m),(nb-m))
243 ii=n-kk+1
244*
245* Compute the LQ factorization of the first block A(1:M,1:NB)
246*
247 CALL sgelqt( m, nb, mb, a(1,1), lda, t, ldt, work, info)
248 ctr = 1
249*
250 DO i = nb+1, ii-nb+m , (nb-m)
251*
252* Compute the QR factorization of the current block A(1:M,I:I+NB-M)
253*
254 CALL stplqt( m, nb-m, 0, mb, a(1,1), lda, a( 1, i ),
255 \$ lda, t(1, ctr * m + 1),
256 \$ ldt, work, info )
257 ctr = ctr + 1
258 END DO
259*
260* Compute the QR factorization of the last block A(1:M,II:N)
261*
262 IF (ii.LE.n) THEN
263 CALL stplqt( m, kk, 0, mb, a(1,1), lda, a( 1, ii ),
264 \$ lda, t(1, ctr * m + 1), ldt,
265 \$ work, info )
266 END IF
267*
268 work( 1 ) = sroundup_lwork(m * mb)
269 RETURN
270*
271* End of SLASWLQ
272*
273 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine sgelqt(m, n, mb, a, lda, t, ldt, work, info)
SGELQT
Definition sgelqt.f:124
subroutine sgeqrt(m, n, nb, a, lda, t, ldt, work, info)
SGEQRT
Definition sgeqrt.f:141
subroutine slaswlq(m, n, mb, nb, a, lda, t, ldt, work, lwork, info)
SLASWLQ
Definition slaswlq.f:167
subroutine stplqt(m, n, l, mb, a, lda, b, ldb, t, ldt, work, info)
STPLQT
Definition stplqt.f:189
subroutine stpqrt(m, n, l, nb, a, lda, b, ldb, t, ldt, work, info)
STPQRT
Definition stpqrt.f:189