sla_gbrcond()

real function sla_gbrcond	(	character	trans,
		integer	n,
		integer	kl,
		integer	ku,
		real, dimension( ldab, * )	ab,
		integer	ldab,
		real, dimension( ldafb, * )	afb,
		integer	ldafb,
		integer, dimension( * )	ipiv,
		integer	cmode,
		real, dimension( * )	c,
		integer	info,
		real, dimension( * )	work,
		integer, dimension( * )	iwork )

SLA_GBRCOND estimates the Skeel condition number for a general banded matrix.

Download SLA_GBRCOND + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!>    SLA_GBRCOND Estimates the Skeel condition number of  op(A) * op2(C)
!>    where op2 is determined by CMODE as follows
!>    CMODE =  1    op2(C) = C
!>    CMODE =  0    op2(C) = I
!>    CMODE = -1    op2(C) = inv(C)
!>    The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
!>    is computed by computing scaling factors R such that
!>    diag(R)*A*op2(C) is row equilibrated and computing the standard
!>    infinity-norm condition number.
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations: !> = 'N': A * X = B (No transpose) !> = 'T': A**T * X = B (Transpose) !> = 'C': A**H * X = B (Conjugate Transpose = Transpose) !>
[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in]	AB	!> AB is REAL array, dimension (LDAB,N) !> On entry, the matrix A in band storage, in rows 1 to KL+KU+1. !> The j-th column of A is stored in the j-th column of the !> array AB as follows: !> AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl) !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KL+KU+1. !>
[in]	AFB	!> AFB is REAL array, dimension (LDAFB,N) !> Details of the LU factorization of the band matrix A, as !> computed by SGBTRF. U is stored as an upper triangular !> band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, !> and the multipliers used during the factorization are stored !> in rows KL+KU+2 to 2*KL+KU+1. !>
[in]	LDAFB	!> LDAFB is INTEGER !> The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> The pivot indices from the factorization A = P*L*U !> as computed by SGBTRF; row i of the matrix was interchanged !> with row IPIV(i). !>
[in]	CMODE	!> CMODE is INTEGER !> Determines op2(C) in the formula op(A) * op2(C) as follows: !> CMODE = 1 op2(C) = C !> CMODE = 0 op2(C) = I !> CMODE = -1 op2(C) = inv(C) !>
[in]	C	!> C is REAL array, dimension (N) !> The vector C in the formula op(A) * op2(C). !>
[out]	INFO	!> INFO is INTEGER !> = 0: Successful exit. !> i > 0: The ith argument is invalid. !>
[out]	WORK	!> WORK is REAL array, dimension (5*N). !> Workspace. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N). !> Workspace. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 164 of file sla_gbrcond.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            N, LDAB, LDAFB, INFO, KL, KU, CMODE
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * ), IPIV( * )
      REAL               AB( LDAB, * ), AFB( LDAFB, * ), WORK( * ),
     $                   C( * )
*    ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            NOTRANS
      INTEGER            KASE, I, J, KD, KE
      REAL               AINVNM, TMP
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           slacn2, sgbtrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      sla_gbrcond = 0.0
*
      info = 0
      notrans = lsame( trans, 'N' )
      IF ( .NOT. notrans .AND. .NOT. lsame(trans, 'T')
     $     .AND. .NOT. lsame(trans, 'C') ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 .OR. kl.GT.n-1 ) THEN
         info = -3
      ELSE IF( ku.LT.0 .OR. ku.GT.n-1 ) THEN
         info = -4
      ELSE IF( ldab.LT.kl+ku+1 ) THEN
         info = -6
      ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLA_GBRCOND', -info )
         RETURN
      END IF
      IF( n.EQ.0 ) THEN
         sla_gbrcond = 1.0
         RETURN
      END IF
*
*     Compute the equilibration matrix R such that
*     inv(R)*A*C has unit 1-norm.
*
      kd = ku + 1
      ke = kl + 1
      IF ( notrans ) THEN
         DO i = 1, n
            tmp = 0.0
               IF ( cmode .EQ. 1 ) THEN
               DO j = max( i-kl, 1 ), min( i+ku, n )
                  tmp = tmp + abs( ab( kd+i-j, j ) * c( j ) )
               END DO
               ELSE IF ( cmode .EQ. 0 ) THEN
                  DO j = max( i-kl, 1 ), min( i+ku, n )
                     tmp = tmp + abs( ab( kd+i-j, j ) )
                  END DO
               ELSE
                  DO j = max( i-kl, 1 ), min( i+ku, n )
                     tmp = tmp + abs( ab( kd+i-j, j ) / c( j ) )
                  END DO
               END IF
            work( 2*n+i ) = tmp
         END DO
      ELSE
         DO i = 1, n
            tmp = 0.0
            IF ( cmode .EQ. 1 ) THEN
               DO j = max( i-kl, 1 ), min( i+ku, n )
                  tmp = tmp + abs( ab( ke-i+j, i ) * c( j ) )
               END DO
            ELSE IF ( cmode .EQ. 0 ) THEN
               DO j = max( i-kl, 1 ), min( i+ku, n )
                  tmp = tmp + abs( ab( ke-i+j, i ) )
               END DO
            ELSE
               DO j = max( i-kl, 1 ), min( i+ku, n )
                  tmp = tmp + abs( ab( ke-i+j, i ) / c( j ) )
               END DO
            END IF
            work( 2*n+i ) = tmp
         END DO
      END IF
*
*     Estimate the norm of inv(op(A)).
*
      ainvnm = 0.0
 
      kase = 0
   10 CONTINUE
      CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.2 ) THEN
*
*           Multiply by R.
*
            DO i = 1, n
               work( i ) = work( i ) * work( 2*n+i )
            END DO
 
            IF ( notrans ) THEN
               CALL sgbtrs( 'No transpose', n, kl, ku, 1, afb, ldafb,
     $              ipiv, work, n, info )
            ELSE
               CALL sgbtrs( 'Transpose', n, kl, ku, 1, afb, ldafb,
     $                      ipiv,
     $              work, n, info )
            END IF
*
*           Multiply by inv(C).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
         ELSE
*
*           Multiply by inv(C**T).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
 
            IF ( notrans ) THEN
               CALL sgbtrs( 'Transpose', n, kl, ku, 1, afb, ldafb,
     $                      ipiv,
     $              work, n, info )
            ELSE
               CALL sgbtrs( 'No transpose', n, kl, ku, 1, afb, ldafb,
     $              ipiv, work, n, info )
            END IF
*
*           Multiply by R.
*
            DO i = 1, n
               work( i ) = work( i ) * work( 2*n+i )
            END DO
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm .NE. 0.0 )
     $   sla_gbrcond = ( 1.0 / ainvnm )
*
      RETURN
*
*     End of SLA_GBRCOND
*

Here is the call graph for this function:

Here is the caller graph for this function: