chetrs_3.f

Go to the documentation of this file.

*> \brief \b CHETRS_3
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download CHETRS_3 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chetrs_3.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chetrs_3.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chetrs_3.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHETRS_3( UPLO, N, NRHS, A, LDA, E, IPIV, B, LDB,
*                            INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX            A( LDA, * ), B( LDB, * ), E( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*> CHETRS_3 solves a system of linear equations A * X = B with a complex
*> Hermitian matrix A using the factorization computed
*> by CHETRF_RK or CHETRF_BK:
*>
*>    A = P*U*D*(U**H)*(P**T) or A = P*L*D*(L**H)*(P**T),
*>
*> where U (or L) is unit upper (or lower) triangular matrix,
*> U**H (or L**H) is the conjugate of U (or L), P is a permutation
*> matrix, P**T is the transpose of P, and D is Hermitian and block
*> diagonal with 1-by-1 and 2-by-2 diagonal blocks.
*>
*> This algorithm is using Level 3 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are
*>          stored as an upper or lower triangular matrix:
*>          = 'U':  Upper triangular, form is A = P*U*D*(U**H)*(P**T);
*>          = 'L':  Lower triangular, form is A = P*L*D*(L**H)*(P**T).
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          Diagonal of the block diagonal matrix D and factors U or L
*>          as computed by CHETRF_RK and CHETRF_BK:
*>            a) ONLY diagonal elements of the Hermitian block diagonal
*>               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
*>               (superdiagonal (or subdiagonal) elements of D
*>                should be provided on entry in array E), and
*>            b) If UPLO = 'U': factor U in the superdiagonal part of A.
*>               If UPLO = 'L': factor L in the subdiagonal part of A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is COMPLEX array, dimension (N)
*>          On entry, contains the superdiagonal (or subdiagonal)
*>          elements of the Hermitian block diagonal matrix D
*>          with 1-by-1 or 2-by-2 diagonal blocks, where
*>          If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not referenced;
*>          If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced.
*>
*>          NOTE: For 1-by-1 diagonal block D(k), where
*>          1 <= k <= N, the element E(k) is not referenced in both
*>          UPLO = 'U' or UPLO = 'L' cases.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D
*>          as determined by CHETRF_RK or CHETRF_BK.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hetrs_3
*
*> \par Contributors:
*  ==================
*>
*> \verbatim
*>
*>  June 2017,  Igor Kozachenko,
*>                  Computer Science Division,
*>                  University of California, Berkeley
*>
*>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
*>                  School of Mathematics,
*>                  University of Manchester
*>
*> \endverbatim
*
*  =====================================================================
      SUBROUTINE chetrs_3( UPLO, N, NRHS, A, LDA, E, IPIV, B, LDB,
     $                     INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0,0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, J, K, KP
      REAL               S
      COMPLEX            AK, AKM1, AKM1K, BK, BKM1, DENOM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           csscal, cswap, ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, conjg, max, real
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHETRS_3', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Begin Upper
*
*        Solve A*X = B, where A = U*D*U**H.
*
*        P**T * B
*
*        Interchange rows K and IPIV(K) of matrix B in the same order
*        that the formation order of IPIV(I) vector for Upper case.
*
*        (We can do the simple loop over IPIV with decrement -1,
*        since the ABS value of IPIV(I) represents the row index
*        of the interchange with row i in both 1x1 and 2x2 pivot cases)
*
         DO k = n, 1, -1
            kp = abs( ipiv( k ) )
            IF( kp.NE.k ) THEN
               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            END IF
         END DO
*
*        Compute (U \P**T * B) -> B    [ (U \P**T * B) ]
*
         CALL ctrsm( 'L', 'U', 'N', 'U', n, nrhs, one, a, lda, b,
     $               ldb )
*
*        Compute D \ B -> B   [ D \ (U \P**T * B) ]
*
         i = n
         DO WHILE ( i.GE.1 )
            IF( ipiv( i ).GT.0 ) THEN
               s = real( one ) / real( a( i, i ) )
               CALL csscal( nrhs, s, b( i, 1 ), ldb )
            ELSE IF ( i.GT.1 ) THEN
               akm1k = e( i )
               akm1 = a( i-1, i-1 ) / akm1k
               ak = a( i, i ) / conjg( akm1k )
               denom = akm1*ak - one
               DO j = 1, nrhs
                  bkm1 = b( i-1, j ) / akm1k
                  bk = b( i, j ) / conjg( akm1k )
                  b( i-1, j ) = ( ak*bkm1-bk ) / denom
                  b( i, j ) = ( akm1*bk-bkm1 ) / denom
               END DO
               i = i - 1
            END IF
            i = i - 1
         END DO
*
*        Compute (U**H \ B) -> B   [ U**H \ (D \ (U \P**T * B) ) ]
*
         CALL ctrsm( 'L', 'U', 'C', 'U', n, nrhs, one, a, lda, b,
     $               ldb )
*
*        P * B  [ P * (U**H \ (D \ (U \P**T * B) )) ]
*
*        Interchange rows K and IPIV(K) of matrix B in reverse order
*        from the formation order of IPIV(I) vector for Upper case.
*
*        (We can do the simple loop over IPIV with increment 1,
*        since the ABS value of IPIV(I) represents the row index
*        of the interchange with row i in both 1x1 and 2x2 pivot cases)
*
         DO k = 1, n, 1
            kp = abs( ipiv( k ) )
            IF( kp.NE.k ) THEN
               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            END IF
         END DO
*
      ELSE
*
*        Begin Lower
*
*        Solve A*X = B, where A = L*D*L**H.
*
*        P**T * B
*        Interchange rows K and IPIV(K) of matrix B in the same order
*        that the formation order of IPIV(I) vector for Lower case.
*
*        (We can do the simple loop over IPIV with increment 1,
*        since the ABS value of IPIV(I) represents the row index
*        of the interchange with row i in both 1x1 and 2x2 pivot cases)
*
         DO k = 1, n, 1
            kp = abs( ipiv( k ) )
            IF( kp.NE.k ) THEN
               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            END IF
         END DO
*
*        Compute (L \P**T * B) -> B    [ (L \P**T * B) ]
*
         CALL ctrsm( 'L', 'L', 'N', 'U', n, nrhs, one, a, lda, b,
     $               ldb )
*
*        Compute D \ B -> B   [ D \ (L \P**T * B) ]
*
         i = 1
         DO WHILE ( i.LE.n )
            IF( ipiv( i ).GT.0 ) THEN
               s = real( one ) / real( a( i, i ) )
               CALL csscal( nrhs, s, b( i, 1 ), ldb )
            ELSE IF( i.LT.n ) THEN
               akm1k = e( i )
               akm1 = a( i, i ) / conjg( akm1k )
               ak = a( i+1, i+1 ) / akm1k
               denom = akm1*ak - one
               DO  j = 1, nrhs
                  bkm1 = b( i, j ) / conjg( akm1k )
                  bk = b( i+1, j ) / akm1k
                  b( i, j ) = ( ak*bkm1-bk ) / denom
                  b( i+1, j ) = ( akm1*bk-bkm1 ) / denom
               END DO
               i = i + 1
            END IF
            i = i + 1
         END DO
*
*        Compute (L**H \ B) -> B   [ L**H \ (D \ (L \P**T * B) ) ]
*
         CALL ctrsm('L', 'L', 'C', 'U', n, nrhs, one, a, lda, b,
     $               ldb )
*
*        P * B  [ P * (L**H \ (D \ (L \P**T * B) )) ]
*
*        Interchange rows K and IPIV(K) of matrix B in reverse order
*        from the formation order of IPIV(I) vector for Lower case.
*
*        (We can do the simple loop over IPIV with decrement -1,
*        since the ABS value of IPIV(I) represents the row index
*        of the interchange with row i in both 1x1 and 2x2 pivot cases)
*
         DO k = n, 1, -1
            kp = abs( ipiv( k ) )
            IF( kp.NE.k ) THEN
               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            END IF
         END DO
*
*        END Lower
*
      END IF
*
      RETURN
*
*     End of CHETRS_3
*
      END