clagge.f

Go to the documentation of this file.

*> \brief \b CLAGGE
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLAGGE( M, N, KL, KU, D, A, LDA, ISEED, WORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, KL, KU, LDA, M, N
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       REAL               D( * )
*       COMPLEX            A( LDA, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLAGGE generates a complex general m by n matrix A, by pre- and post-
*> multiplying a real diagonal matrix D with random unitary matrices:
*> A = U*D*V. The lower and upper bandwidths may then be reduced to
*> kl and ku by additional unitary transformations.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] KL
*> \verbatim
*>          KL is INTEGER
*>          The number of nonzero subdiagonals within the band of A.
*>          0 <= KL <= M-1.
*> \endverbatim
*>
*> \param[in] KU
*> \verbatim
*>          KU is INTEGER
*>          The number of nonzero superdiagonals within the band of A.
*>          0 <= KU <= N-1.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (min(M,N))
*>          The diagonal elements of the diagonal matrix D.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The generated m by n matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= M.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry, the seed of the random number generator; the array
*>          elements must be between 0 and 4095, and ISEED(4) must be
*>          odd.
*>          On exit, the seed is updated.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (M+N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_matgen
*
*  =====================================================================
      SUBROUTINE clagge( M, N, KL, KU, D, A, LDA, ISEED, WORK, INFO )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, KL, KU, LDA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               D( * )
      COMPLEX            A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO, ONE
      parameter( zero = ( 0.0e+0, 0.0e+0 ),
     $                   one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               WN
      COMPLEX            TAU, WA, WB
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cgerc, clacgv, clarnv, cscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real
*     ..
*     .. External Functions ..
      REAL               SCNRM2
      EXTERNAL           scnrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 .OR. kl.GT.m-1 ) THEN
         info = -3
      ELSE IF( ku.LT.0 .OR. ku.GT.n-1 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -7
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'CLAGGE', -info )
         RETURN
      END IF
*
*     initialize A to diagonal matrix
*
      DO 20 j = 1, n
         DO 10 i = 1, m
            a( i, j ) = zero
   10    CONTINUE
   20 CONTINUE
      DO 30 i = 1, min( m, n )
         a( i, i ) = d( i )
   30 CONTINUE
*
*     Quick exit if the user wants a diagonal matrix
*
      IF(( kl .EQ. 0 ).AND.( ku .EQ. 0)) RETURN
*
*     pre- and post-multiply A by random unitary matrices
*
      DO 40 i = min( m, n ), 1, -1
         IF( i.LT.m ) THEN
*
*           generate random reflection
*
            CALL clarnv( 3, iseed, m-i+1, work )
            wn = scnrm2( m-i+1, work, 1 )
            wa = ( wn / abs( work( 1 ) ) )*work( 1 )
            IF( wn.EQ.zero ) THEN
               tau = zero
            ELSE
               wb = work( 1 ) + wa
               CALL cscal( m-i, one / wb, work( 2 ), 1 )
               work( 1 ) = one
               tau = real( wb / wa )
            END IF
*
*           multiply A(i:m,i:n) by random reflection from the left
*
            CALL cgemv( 'Conjugate transpose', m-i+1, n-i+1, one,
     $                  a( i, i ), lda, work, 1, zero, work( m+1 ), 1 )
            CALL cgerc( m-i+1, n-i+1, -tau, work, 1, work( m+1 ), 1,
     $                  a( i, i ), lda )
         END IF
         IF( i.LT.n ) THEN
*
*           generate random reflection
*
            CALL clarnv( 3, iseed, n-i+1, work )
            wn = scnrm2( n-i+1, work, 1 )
            wa = ( wn / abs( work( 1 ) ) )*work( 1 )
            IF( wn.EQ.zero ) THEN
               tau = zero
            ELSE
               wb = work( 1 ) + wa
               CALL cscal( n-i, one / wb, work( 2 ), 1 )
               work( 1 ) = one
               tau = real( wb / wa )
            END IF
*
*           multiply A(i:m,i:n) by random reflection from the right
*
            CALL cgemv( 'No transpose', m-i+1, n-i+1, one, a( i, i ),
     $                  lda, work, 1, zero, work( n+1 ), 1 )
            CALL cgerc( m-i+1, n-i+1, -tau, work( n+1 ), 1, work, 1,
     $                  a( i, i ), lda )
         END IF
   40 CONTINUE
*
*     Reduce number of subdiagonals to KL and number of superdiagonals
*     to KU
*
      DO 70 i = 1, max( m-1-kl, n-1-ku )
         IF( kl.LE.ku ) THEN
*
*           annihilate subdiagonal elements first (necessary if KL = 0)
*
            IF( i.LE.min( m-1-kl, n ) ) THEN
*
*              generate reflection to annihilate A(kl+i+1:m,i)
*
               wn = scnrm2( m-kl-i+1, a( kl+i, i ), 1 )
               wa = ( wn / abs( a( kl+i, i ) ) )*a( kl+i, i )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( kl+i, i ) + wa
                  CALL cscal( m-kl-i, one / wb, a( kl+i+1, i ), 1 )
                  a( kl+i, i ) = one
                  tau = real( wb / wa )
               END IF
*
*              apply reflection to A(kl+i:m,i+1:n) from the left
*
               CALL cgemv( 'Conjugate transpose', m-kl-i+1, n-i, one,
     $                     a( kl+i, i+1 ), lda, a( kl+i, i ), 1, zero,
     $                     work, 1 )
               CALL cgerc( m-kl-i+1, n-i, -tau, a( kl+i, i ), 1, work,
     $                     1, a( kl+i, i+1 ), lda )
               a( kl+i, i ) = -wa
            END IF
*
            IF( i.LE.min( n-1-ku, m ) ) THEN
*
*              generate reflection to annihilate A(i,ku+i+1:n)
*
               wn = scnrm2( n-ku-i+1, a( i, ku+i ), lda )
               wa = ( wn / abs( a( i, ku+i ) ) )*a( i, ku+i )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( i, ku+i ) + wa
                  CALL cscal( n-ku-i, one / wb, a( i, ku+i+1 ), lda )
                  a( i, ku+i ) = one
                  tau = real( wb / wa )
               END IF
*
*              apply reflection to A(i+1:m,ku+i:n) from the right
*
               CALL clacgv( n-ku-i+1, a( i, ku+i ), lda )
               CALL cgemv( 'No transpose', m-i, n-ku-i+1, one,
     $                     a( i+1, ku+i ), lda, a( i, ku+i ), lda, zero,
     $                     work, 1 )
               CALL cgerc( m-i, n-ku-i+1, -tau, work, 1, a( i, ku+i ),
     $                     lda, a( i+1, ku+i ), lda )
               a( i, ku+i ) = -wa
            END IF
         ELSE
*
*           annihilate superdiagonal elements first (necessary if
*           KU = 0)
*
            IF( i.LE.min( n-1-ku, m ) ) THEN
*
*              generate reflection to annihilate A(i,ku+i+1:n)
*
               wn = scnrm2( n-ku-i+1, a( i, ku+i ), lda )
               wa = ( wn / abs( a( i, ku+i ) ) )*a( i, ku+i )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( i, ku+i ) + wa
                  CALL cscal( n-ku-i, one / wb, a( i, ku+i+1 ), lda )
                  a( i, ku+i ) = one
                  tau = real( wb / wa )
               END IF
*
*              apply reflection to A(i+1:m,ku+i:n) from the right
*
               CALL clacgv( n-ku-i+1, a( i, ku+i ), lda )
               CALL cgemv( 'No transpose', m-i, n-ku-i+1, one,
     $                     a( i+1, ku+i ), lda, a( i, ku+i ), lda, zero,
     $                     work, 1 )
               CALL cgerc( m-i, n-ku-i+1, -tau, work, 1, a( i, ku+i ),
     $                     lda, a( i+1, ku+i ), lda )
               a( i, ku+i ) = -wa
            END IF
*
            IF( i.LE.min( m-1-kl, n ) ) THEN
*
*              generate reflection to annihilate A(kl+i+1:m,i)
*
               wn = scnrm2( m-kl-i+1, a( kl+i, i ), 1 )
               wa = ( wn / abs( a( kl+i, i ) ) )*a( kl+i, i )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( kl+i, i ) + wa
                  CALL cscal( m-kl-i, one / wb, a( kl+i+1, i ), 1 )
                  a( kl+i, i ) = one
                  tau = real( wb / wa )
               END IF
*
*              apply reflection to A(kl+i:m,i+1:n) from the left
*
               CALL cgemv( 'Conjugate transpose', m-kl-i+1, n-i, one,
     $                     a( kl+i, i+1 ), lda, a( kl+i, i ), 1, zero,
     $                     work, 1 )
               CALL cgerc( m-kl-i+1, n-i, -tau, a( kl+i, i ), 1, work,
     $                     1, a( kl+i, i+1 ), lda )
               a( kl+i, i ) = -wa
            END IF
         END IF
*
         IF (i .LE. n) THEN
            DO 50 j = kl + i + 1, m
               a( j, i ) = zero
   50       CONTINUE
         END IF
*
         IF (i .LE. m) THEN
            DO 60 j = ku + i + 1, n
               a( i, j ) = zero
   60       CONTINUE
         END IF
   70 CONTINUE
      RETURN
*
*     End of CLAGGE
*
      END