dgecon()

subroutine dgecon	(	character	norm,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision	anorm,
		double precision	rcond,
		double precision, dimension( * )	work,
		integer, dimension( * )	iwork,
		integer	info )

DGECON

Download DGECON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DGECON estimates the reciprocal of the condition number of a general
!> real matrix A, in either the 1-norm or the infinity-norm, using
!> the LU factorization computed by DGETRF.
!>
!> An estimate is obtained for norm(inv(A)), and the reciprocal of the
!> condition number is computed as
!>    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
!> 

Parameters

[in]	NORM	!> NORM is CHARACTER*1 !> Specifies whether the 1-norm condition number or the !> infinity-norm condition number is required: !> = '1' or 'O': 1-norm; !> = 'I': Infinity-norm. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The factors L and U from the factorization A = P*L*U !> as computed by DGETRF. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	ANORM	!> ANORM is DOUBLE PRECISION !> If NORM = '1' or 'O', the 1-norm of the original matrix A. !> If NORM = 'I', the infinity-norm of the original matrix A. !>
[out]	RCOND	!> RCOND is DOUBLE PRECISION !> The reciprocal of the condition number of the matrix A, !> computed as RCOND = 1/(norm(A) * norm(inv(A))). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (4*N) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> NaNs are illegal values for ANORM, and they propagate to !> the output parameter RCOND. !> Infinity is illegal for ANORM, and it propagates to the output !> parameter RCOND as 0. !> = 1: if RCOND = NaN, or !> RCOND = Inf, or !> the computed norm of the inverse of A is 0. !> In the latter, RCOND = 0 is returned. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 128 of file dgecon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            INFO, LDA, N
      DOUBLE PRECISION   ANORM, RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      DOUBLE PRECISION   A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ONENRM
      CHARACTER          NORMIN
      INTEGER            IX, KASE, KASE1
      DOUBLE PRECISION   AINVNM, SCALE, SL, SMLNUM, SU, HUGEVAL
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, DISNAN
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           lsame, idamax, dlamch, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlacn2, dlatrs, drscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      hugeval = dlamch( 'Overflow' )
*
*     Test the input parameters.
*
      info = 0
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( anorm.LT.zero ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGECON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      ELSE IF( disnan( anorm ) ) THEN
         rcond = anorm
         info = -5
         RETURN
      ELSE IF( anorm.GT.hugeval ) THEN
         info = -5
         RETURN
      END IF
*
      smlnum = dlamch( 'Safe minimum' )
*
*     Estimate the norm of inv(A).
*
      ainvnm = zero
      normin = 'N'
      IF( onenrm ) THEN
         kase1 = 1
      ELSE
         kase1 = 2
      END IF
      kase = 0
   10 CONTINUE
      CALL dlacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.kase1 ) THEN
*
*           Multiply by inv(L).
*
            CALL dlatrs( 'Lower', 'No transpose', 'Unit', normin, n,
     $                   a,
     $                   lda, work, sl, work( 2*n+1 ), info )
*
*           Multiply by inv(U).
*
            CALL dlatrs( 'Upper', 'No transpose', 'Non-unit', normin,
     $                   n,
     $                   a, lda, work, su, work( 3*n+1 ), info )
         ELSE
*
*           Multiply by inv(U**T).
*
            CALL dlatrs( 'Upper', 'Transpose', 'Non-unit', normin, n,
     $                   a,
     $                   lda, work, su, work( 3*n+1 ), info )
*
*           Multiply by inv(L**T).
*
            CALL dlatrs( 'Lower', 'Transpose', 'Unit', normin, n, a,
     $                   lda, work, sl, work( 2*n+1 ), info )
         END IF
*
*        Divide X by 1/(SL*SU) if doing so will not cause overflow.
*
         scale = sl*su
         normin = 'Y'
         IF( scale.NE.one ) THEN
            ix = idamax( n, work, 1 )
            IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
     $         GO TO 20
            CALL drscl( n, scale, work, 1 )
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm.NE.zero ) THEN
         rcond = ( one / ainvnm ) / anorm
      ELSE
         info = 1
         RETURN
      END IF
*
*     Check for NaNs and Infs
*
      IF( disnan( rcond ) .OR. rcond.GT.hugeval )
     $   info = 1
*
   20 CONTINUE
      RETURN
*
*     End of DGECON
*

Here is the call graph for this function:

Here is the caller graph for this function: