zdrvac()

subroutine zdrvac	(	logical, dimension( * )	dotype,
		integer	nm,
		integer, dimension( * )	mval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	afac,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		complex, dimension(*)	swork,
		integer	nout )

ZDRVAC

Purpose:

!>
!> ZDRVAC tests ZCPOSV.
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NM	!> NM is INTEGER !> The number of values of N contained in the vector MVAL. !>
[in]	MVAL	!> MVAL is INTEGER array, dimension (NM) !> The values of the matrix dimension N. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	NMAX	!> NMAX is INTEGER !> The maximum value permitted for N, used in dimensioning the !> work arrays. !>
[out]	A	!> A is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	AFAC	!> AFAC is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	X	!> X is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension !> (max(2*NMAX,2*NSMAX+NWORK)) !>
[out]	SWORK	!> SWORK is COMPLEX array, dimension !> (NMAX*(NSMAX+NMAX)) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 142 of file zdrvac.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NMAX, NM, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            MVAL( * ), NSVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX            SWORK(*)
      COMPLEX*16         A( * ), AFAC( * ), B( * ),
     $                   WORK( * ), X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 9 )
      INTEGER            NTESTS
      parameter( ntests = 1 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IM, IMAT, INFO, IOFF, IRHS, IUPLO,
     $                   IZERO, KL, KU, LDA, MODE, N,
     $                   NERRS, NFAIL, NIMAT, NRHS, NRUN
      DOUBLE PRECISION   ANORM, CNDNUM
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. Local Variables ..
      INTEGER            ITER, KASE
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, zlacpy, zlaipd,
     $                   zlarhs, zlatb4, zlatms,
     $                   zpot06, zcposv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      kase = 0
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'PO'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
      infot = 0
*
*     Do for each value of N in MVAL
*
      DO 120 im = 1, nm
         n = mval( im )
         lda = max( n, 1 )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 110 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 110
*
*           Skip types 3, 4, or 5 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.5
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 110
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 100 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Set up parameters with ZLATB4 and generate a test matrix
*              with ZLATMS.
*
               CALL zlatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                      CNDNUM, DIST )
*
               srnamt = 'ZLATMS'
               CALL zlatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                      CNDNUM, ANORM, KL, KU, UPLO, A, LDA, WORK,
     $                      INFO )
*
*              Check error code from ZLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'ZLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
*
*              For types 3-5, zero one row and column of the matrix to
*              test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
                  ioff = ( izero-1 )*lda
*
*                 Set row and column IZERO of A to 0.
*
                  IF( iuplo.EQ.1 ) THEN
                     DO 20 i = 1, izero - 1
                        a( ioff+i ) = zero
   20                CONTINUE
                     ioff = ioff + izero
                     DO 30 i = izero, n
                        a( ioff ) = zero
                        ioff = ioff + lda
   30                CONTINUE
                  ELSE
                     ioff = izero
                     DO 40 i = 1, izero - 1
                        a( ioff ) = zero
                        ioff = ioff + lda
   40                CONTINUE
                     ioff = ioff - izero
                     DO 50 i = izero, n
                        a( ioff+i ) = zero
   50                CONTINUE
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              Set the imaginary part of the diagonals.
*
               CALL zlaipd( n, a, lda+1, 0 )
*
               DO 60 irhs = 1, nns
                  nrhs = nsval( irhs )
                  xtype = 'N'
*
*                 Form an exact solution and set the right hand side.
*
                  srnamt = 'ZLARHS'
                  CALL zlarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                         nrhs, a, lda, x, lda, b, lda,
     $                         iseed, info )
*
*                 Compute the L*L' or U'*U factorization of the
*                 matrix and solve the system.
*
                  srnamt = 'ZCPOSV '
                  kase = kase + 1
*
                  CALL zlacpy( 'All', n, n, a, lda, afac, lda)
*
                  CALL zcposv( uplo, n, nrhs, afac, lda, b, lda, x, lda,
     $                         work, swork, rwork, iter, info )
*
                  IF (iter.LT.0) THEN
                     CALL zlacpy( 'All', n, n, a, lda, afac, lda )
                  ENDIF
*
*                 Check error code from ZCPOSV .
*
                  IF( info.NE.izero ) THEN
*
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     nerrs = nerrs + 1
*
                     IF( info.NE.izero .AND. izero.NE.0 ) THEN
                        WRITE( nout, fmt = 9988 )'ZCPOSV',info,izero,n,
     $                     imat
                     ELSE
                        WRITE( nout, fmt = 9975 )'ZCPOSV',info,n,imat
                     END IF
                  END IF
*
*                 Skip the remaining test if the matrix is singular.
*
                  IF( info.NE.0 )
     $               GO TO 110
*
*                 Check the quality of the solution
*
                  CALL zlacpy( 'All', n, nrhs, b, lda, work, lda )
*
                  CALL zpot06( uplo, n, nrhs, a, lda, x, lda, work,
     $               lda, rwork, result( 1 ) )
*
*                 Check if the test passes the testing.
*                 Print information about the tests that did not
*                 pass the testing.
*
*                 If iterative refinement has been used and claimed to
*                 be successful (ITER>0), we want
*                 NORM1(B - A*X)/(NORM1(A)*NORM1(X)*EPS*SRQT(N)) < 1
*
*                 If double precision has been used (ITER<0), we want
*                 NORM1(B - A*X)/(NORM1(A)*NORM1(X)*EPS) < THRES
*                 (Cf. the linear solver testing routines)
*
                  IF ((thresh.LE.0.0e+00)
     $               .OR.((iter.GE.0).AND.(n.GT.0)
     $               .AND.(result(1).GE.sqrt(dble(n))))
     $               .OR.((iter.LT.0).AND.(result(1).GE.thresh))) THEN
*
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 ) THEN
                        WRITE( nout, fmt = 8999 )'ZPO'
                        WRITE( nout, fmt = '( '' Matrix types:'' )' )
                        WRITE( nout, fmt = 8979 )
                        WRITE( nout, fmt = '( '' Test ratios:'' )' )
                        WRITE( nout, fmt = 8960 )1
                        WRITE( nout, fmt = '( '' Messages:'' )' )
                     END IF
*
                     WRITE( nout, fmt = 9998 )uplo, n, nrhs, imat, 1,
     $                  result( 1 )
*
                     nfail = nfail + 1
*
                  END IF
*
                  nrun = nrun + 1
*
   60          CONTINUE
  100       CONTINUE
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      IF( nfail.GT.0 ) THEN
         WRITE( nout, fmt = 9996 )'ZCPOSV', nfail, nrun
      ELSE
         WRITE( nout, fmt = 9995 )'ZCPOSV', nrun
      END IF
      IF( nerrs.GT.0 ) THEN
         WRITE( nout, fmt = 9994 )nerrs
      END IF
*
 9998 FORMAT( ' UPLO=''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9996 FORMAT( 1x, a6, ': ', i6, ' out of ', i6,
     $      ' tests failed to pass the threshold' )
 9995 FORMAT( /1x, 'All tests for ', a6,
     $      ' routines passed the threshold ( ', i6, ' tests run)' )
 9994 FORMAT( 6x, i6, ' error messages recorded' )
*
*     SUBNAM, INFO, INFOE, N, IMAT
*
 9988 FORMAT( ' *** ', a6, ' returned with INFO =', i5, ' instead of ',
     $      i5, / ' ==> N =', i5, ', type ',
     $      i2 )
*
*     SUBNAM, INFO, N, IMAT
*
 9975 FORMAT( ' *** Error code from ', a6, '=', i5, ' for M=', i5,
     $      ', type ', i2 )
 8999 FORMAT( / 1x, a3, ':  positive definite dense matrices' )
 8979 FORMAT( 4x, '1. Diagonal', 24x, '7. Last n/2 columns zero', / 4x,
     $      '2. Upper triangular', 16x,
     $      '8. Random, CNDNUM = sqrt(0.1/EPS)', / 4x,
     $      '3. Lower triangular', 16x, '9. Random, CNDNUM = 0.1/EPS',
     $      / 4x, '4. Random, CNDNUM = 2', 13x,
     $      '10. Scaled near underflow', / 4x, '5. First column zero',
     $      14x, '11. Scaled near overflow', / 4x,
     $      '6. Last column zero' )
 8960 FORMAT( 3x, i2, ': norm_1( B - A * X )  / ',
     $      '( norm_1(A) * norm_1(X) * EPS * SQRT(N) ) > 1 if ITERREF',
     $      / 4x, 'or norm_1( B - A * X )  / ',
     $      '( norm_1(A) * norm_1(X) * EPS ) > THRES if ZPOTRF' )
 
      RETURN
*
*     End of ZDRVAC
*

Here is the call graph for this function:

Here is the caller graph for this function: