zptt02()

subroutine zptt02	(	character	uplo,
		integer	n,
		integer	nrhs,
		double precision, dimension( * )	d,
		complex*16, dimension( * )	e,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		double precision	resid
	)

ZPTT02

Purpose:

 ZPTT02 computes the residual for the solution to a symmetric
 tridiagonal system of equations:
    RESID = norm(B - A*X) / (norm(A) * norm(X) * EPS),
 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the superdiagonal or the subdiagonal of the tridiagonal matrix A is stored. = 'U': E is the superdiagonal of A = 'L': E is the subdiagonal of A
[in]	N	N is INTEGER The order of the matrix A.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The n diagonal elements of the tridiagonal matrix A.
[in]	E	E is COMPLEX*16 array, dimension (N-1) The (n-1) subdiagonal elements of the tridiagonal matrix A.
[in]	X	X is COMPLEX*16 array, dimension (LDX,NRHS) The n by nrhs matrix of solution vectors X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,NRHS) On entry, the n by nrhs matrix of right hand side vectors B. On exit, B is overwritten with the difference B - A*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	RESID	RESID is DOUBLE PRECISION norm(B - A*X) / (norm(A) * norm(X) * EPS)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 114 of file zptt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDB, LDX, N, NRHS
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * )
      COMPLEX*16         B( LDB, * ), E( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      DOUBLE PRECISION   ANORM, BNORM, EPS, XNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DZASUM, ZLANHT
      EXTERNAL           dlamch, dzasum, zlanht
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlaptm
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Compute the 1-norm of the tridiagonal matrix A.
*
      anorm = zlanht( '1', n, d, e )
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute B - A*X.
*
      CALL zlaptm( uplo, n, nrhs, -one, d, e, x, ldx, one, b, ldb )
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - A*X) / ( norm(A) * norm(X) * EPS ).
*
      resid = zero
      DO 10 j = 1, nrhs
         bnorm = dzasum( n, b( 1, j ), 1 )
         xnorm = dzasum( n, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of ZPTT02
*

Here is the call graph for this function:

Here is the caller graph for this function: