slarfy()

subroutine slarfy	(	character	uplo,
		integer	n,
		real, dimension( * )	v,
		integer	incv,
		real	tau,
		real, dimension( ldc, * )	c,
		integer	ldc,
		real, dimension( * )	work
	)

SLARFY

Purpose:

 SLARFY applies an elementary reflector, or Householder matrix, H,
 to an n x n symmetric matrix C, from both the left and the right.

 H is represented in the form

    H = I - tau * v * v'

 where  tau  is a scalar and  v  is a vector.

 If  tau  is  zero, then  H  is taken to be the unit matrix.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix C is stored. = 'U': Upper triangle = 'L': Lower triangle
[in]	N	N is INTEGER The number of rows and columns of the matrix C. N >= 0.
[in]	V	V is REAL array, dimension (1 + (N-1)*abs(INCV)) The vector v as described above.
[in]	INCV	INCV is INTEGER The increment between successive elements of v. INCV must not be zero.
[in]	TAU	TAU is REAL The value tau as described above.
[in,out]	C	C is REAL array, dimension (LDC, N) On entry, the matrix C. On exit, C is overwritten by H * C * H'.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max( 1, N ).
[out]	WORK	WORK is REAL array, dimension (N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 107 of file slarfy.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INCV, LDC, N
      REAL               TAU
*     ..
*     .. Array Arguments ..
      REAL               C( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO, HALF
      parameter( one = 1.0e+0, zero = 0.0e+0, half = 0.5e+0 )
*     ..
*     .. Local Scalars ..
      REAL               ALPHA
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, ssymv, ssyr2
*     ..
*     .. External Functions ..
      REAL               SDOT
      EXTERNAL           sdot
*     ..
*     .. Executable Statements ..
*
      IF( tau.EQ.zero )
     $   RETURN
*
*     Form  w:= C * v
*
      CALL ssymv( uplo, n, one, c, ldc, v, incv, zero, work, 1 )
*
      alpha = -half*tau*sdot( n, work, 1, v, incv )
      CALL saxpy( n, alpha, v, incv, work, 1 )
*
*     C := C - v * w' - w * v'
*
      CALL ssyr2( uplo, n, -tau, v, incv, work, 1, c, ldc )
*
      RETURN
*
*     End of SLARFY
*

Here is the call graph for this function:

Here is the caller graph for this function: