sdrvsx()

subroutine sdrvsx	(	integer	nsizes,
		integer, dimension( * )	nn,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer, dimension( 4 )	iseed,
		real	thresh,
		integer	niunit,
		integer	nounit,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( lda, * )	h,
		real, dimension( lda, * )	ht,
		real, dimension( * )	wr,
		real, dimension( * )	wi,
		real, dimension( * )	wrt,
		real, dimension( * )	wit,
		real, dimension( * )	wrtmp,
		real, dimension( * )	witmp,
		real, dimension( ldvs, * )	vs,
		integer	ldvs,
		real, dimension( ldvs, * )	vs1,
		real, dimension( 17 )	result,
		real, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		logical, dimension( * )	bwork,
		integer	info )

SDRVSX

Purpose:

!>
!>    SDRVSX checks the nonsymmetric eigenvalue (Schur form) problem
!>    expert driver SGEESX.
!>
!>    SDRVSX uses both test matrices generated randomly depending on
!>    data supplied in the calling sequence, as well as on data
!>    read from an input file and including precomputed condition
!>    numbers to which it compares the ones it computes.
!>
!>    When SDRVSX is called, a number of matrix  () and a
!>    number of matrix  are specified.  For each size ()
!>    and each type of matrix, one matrix will be generated and used
!>    to test the nonsymmetric eigenroutines.  For each matrix, 15
!>    tests will be performed:
!>
!>    (1)     0 if T is in Schur form, 1/ulp otherwise
!>           (no sorting of eigenvalues)
!>
!>    (2)     | A - VS T VS' | / ( n |A| ulp )
!>
!>      Here VS is the matrix of Schur eigenvectors, and T is in Schur
!>      form  (no sorting of eigenvalues).
!>
!>    (3)     | I - VS VS' | / ( n ulp ) (no sorting of eigenvalues).
!>
!>    (4)     0     if WR+sqrt(-1)*WI are eigenvalues of T
!>            1/ulp otherwise
!>            (no sorting of eigenvalues)
!>
!>    (5)     0     if T(with VS) = T(without VS),
!>            1/ulp otherwise
!>            (no sorting of eigenvalues)
!>
!>    (6)     0     if eigenvalues(with VS) = eigenvalues(without VS),
!>            1/ulp otherwise
!>            (no sorting of eigenvalues)
!>
!>    (7)     0 if T is in Schur form, 1/ulp otherwise
!>            (with sorting of eigenvalues)
!>
!>    (8)     | A - VS T VS' | / ( n |A| ulp )
!>
!>      Here VS is the matrix of Schur eigenvectors, and T is in Schur
!>      form  (with sorting of eigenvalues).
!>
!>    (9)     | I - VS VS' | / ( n ulp ) (with sorting of eigenvalues).
!>
!>    (10)    0     if WR+sqrt(-1)*WI are eigenvalues of T
!>            1/ulp otherwise
!>            If workspace sufficient, also compare WR, WI with and
!>            without reciprocal condition numbers
!>            (with sorting of eigenvalues)
!>
!>    (11)    0     if T(with VS) = T(without VS),
!>            1/ulp otherwise
!>            If workspace sufficient, also compare T with and without
!>            reciprocal condition numbers
!>            (with sorting of eigenvalues)
!>
!>    (12)    0     if eigenvalues(with VS) = eigenvalues(without VS),
!>            1/ulp otherwise
!>            If workspace sufficient, also compare VS with and without
!>            reciprocal condition numbers
!>            (with sorting of eigenvalues)
!>
!>    (13)    if sorting worked and SDIM is the number of
!>            eigenvalues which were SELECTed
!>            If workspace sufficient, also compare SDIM with and
!>            without reciprocal condition numbers
!>
!>    (14)    if RCONDE the same no matter if VS and/or RCONDV computed
!>
!>    (15)    if RCONDV the same no matter if VS and/or RCONDE computed
!>
!>    The  are specified by an array NN(1:NSIZES); the value of
!>    each element NN(j) specifies one size.
!>    The  are specified by a logical array DOTYPE( 1:NTYPES );
!>    if DOTYPE(j) is .TRUE., then matrix type  will be generated.
!>    Currently, the list of possible types is:
!>
!>    (1)  The zero matrix.
!>    (2)  The identity matrix.
!>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
!>
!>    (4)  A diagonal matrix with evenly spaced entries
!>         1, ..., ULP  and random signs.
!>         (ULP = (first number larger than 1) - 1 )
!>    (5)  A diagonal matrix with geometrically spaced entries
!>         1, ..., ULP  and random signs.
!>    (6)  A diagonal matrix with  entries 1, ULP, ..., ULP
!>         and random signs.
!>
!>    (7)  Same as (4), but multiplied by a constant near
!>         the overflow threshold
!>    (8)  Same as (4), but multiplied by a constant near
!>         the underflow threshold
!>
!>    (9)  A matrix of the form  U' T U, where U is orthogonal and
!>         T has evenly spaced entries 1, ..., ULP with random signs
!>         on the diagonal and random O(1) entries in the upper
!>         triangle.
!>
!>    (10) A matrix of the form  U' T U, where U is orthogonal and
!>         T has geometrically spaced entries 1, ..., ULP with random
!>         signs on the diagonal and random O(1) entries in the upper
!>         triangle.
!>
!>    (11) A matrix of the form  U' T U, where U is orthogonal and
!>         T has  entries 1, ULP,..., ULP with random
!>         signs on the diagonal and random O(1) entries in the upper
!>         triangle.
!>
!>    (12) A matrix of the form  U' T U, where U is orthogonal and
!>         T has real or complex conjugate paired eigenvalues randomly
!>         chosen from ( ULP, 1 ) and random O(1) entries in the upper
!>         triangle.
!>
!>    (13) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
!>         with random signs on the diagonal and random O(1) entries
!>         in the upper triangle.
!>
!>    (14) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has geometrically spaced entries
!>         1, ..., ULP with random signs on the diagonal and random
!>         O(1) entries in the upper triangle.
!>
!>    (15) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has  entries 1, ULP,..., ULP
!>         with random signs on the diagonal and random O(1) entries
!>         in the upper triangle.
!>
!>    (16) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has real or complex conjugate paired
!>         eigenvalues randomly chosen from ( ULP, 1 ) and random
!>         O(1) entries in the upper triangle.
!>
!>    (17) Same as (16), but multiplied by a constant
!>         near the overflow threshold
!>    (18) Same as (16), but multiplied by a constant
!>         near the underflow threshold
!>
!>    (19) Nonsymmetric matrix with random entries chosen from (-1,1).
!>         If N is at least 4, all entries in first two rows and last
!>         row, and first column and last two columns are zero.
!>    (20) Same as (19), but multiplied by a constant
!>         near the overflow threshold
!>    (21) Same as (19), but multiplied by a constant
!>         near the underflow threshold
!>
!>    In addition, an input file will be read from logical unit number
!>    NIUNIT. The file contains matrices along with precomputed
!>    eigenvalues and reciprocal condition numbers for the eigenvalue
!>    average and right invariant subspace. For these matrices, in
!>    addition to tests (1) to (15) we will compute the following two
!>    tests:
!>
!>   (16)  |RCONDE - RCDEIN| / cond(RCONDE)
!>
!>      RCONDE is the reciprocal average eigenvalue condition number
!>      computed by SGEESX and RCDEIN (the precomputed true value)
!>      is supplied as input.  cond(RCONDE) is the condition number
!>      of RCONDE, and takes errors in computing RCONDE into account,
!>      so that the resulting quantity should be O(ULP). cond(RCONDE)
!>      is essentially given by norm(A)/RCONDV.
!>
!>   (17)  |RCONDV - RCDVIN| / cond(RCONDV)
!>
!>      RCONDV is the reciprocal right invariant subspace condition
!>      number computed by SGEESX and RCDVIN (the precomputed true
!>      value) is supplied as input. cond(RCONDV) is the condition
!>      number of RCONDV, and takes errors in computing RCONDV into
!>      account, so that the resulting quantity should be O(ULP).
!>      cond(RCONDV) is essentially given by norm(A)/RCONDE.
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of sizes of matrices to use. NSIZES must be at !> least zero. If it is zero, no randomly generated matrices !> are tested, but any test matrices read from NIUNIT will be !> tested. !>
[in]	NN	!> NN is INTEGER array, dimension (NSIZES) !> An array containing the sizes to be used for the matrices. !> Zero values will be skipped. The values must be at least !> zero. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. NTYPES must be at least !> zero. If it is zero, no randomly generated test matrices !> are tested, but and test matrices read from NIUNIT will be !> tested. If it is MAXTYP+1 and NSIZES is 1, then an !> additional type, MAXTYP+1 is defined, which is to use !> whatever matrix is in A. This is only useful if !> DOTYPE(1:MAXTYP) is .FALSE. and DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size in NN a !> matrix of that size and of type j will be generated. !> If NTYPES is smaller than the maximum number of types !> defined (PARAMETER MAXTYP), then types NTYPES+1 through !> MAXTYP will not be generated. If NTYPES is larger !> than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES) !> will be ignored. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The random number generator uses a linear !> congruential sequence limited to small integers, and so !> should produce machine independent random numbers. The !> values of ISEED are changed on exit, and can be used in the !> next call to SDRVSX to continue the same random number !> sequence. !>
[in]	THRESH	!> THRESH is REAL !> A test will count as if the , computed as !> described above, exceeds THRESH. Note that the error !> is scaled to be O(1), so THRESH should be a reasonably !> small multiple of 1, e.g., 10 or 100. In particular, !> it should not depend on the precision (single vs. double) !> or the size of the matrix. It must be at least zero. !>
[in]	NIUNIT	!> NIUNIT is INTEGER !> The FORTRAN unit number for reading in the data file of !> problems to solve. !>
[in]	NOUNIT	!> NOUNIT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns INFO not equal to 0.) !>
[out]	A	!> A is REAL array, dimension (LDA, max(NN)) !> Used to hold the matrix whose eigenvalues are to be !> computed. On exit, A contains the last matrix actually used. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A, and H. LDA must be at !> least 1 and at least max( NN ). !>
[out]	H	!> H is REAL array, dimension (LDA, max(NN)) !> Another copy of the test matrix A, modified by SGEESX. !>
[out]	HT	!> HT is REAL array, dimension (LDA, max(NN)) !> Yet another copy of the test matrix A, modified by SGEESX. !>
[out]	WR	!> WR is REAL array, dimension (max(NN)) !>
[out]	WI	!> WI is REAL array, dimension (max(NN)) !> !> The real and imaginary parts of the eigenvalues of A. !> On exit, WR + WI*i are the eigenvalues of the matrix in A. !>
[out]	WRT	!> WRT is REAL array, dimension (max(NN)) !>
[out]	WIT	!> WIT is REAL array, dimension (max(NN)) !> !> Like WR, WI, these arrays contain the eigenvalues of A, !> but those computed when SGEESX only computes a partial !> eigendecomposition, i.e. not Schur vectors !>
[out]	WRTMP	!> WRTMP is REAL array, dimension (max(NN)) !>
[out]	WITMP	!> WITMP is REAL array, dimension (max(NN)) !> !> More temporary storage for eigenvalues. !>
[out]	VS	!> VS is REAL array, dimension (LDVS, max(NN)) !> VS holds the computed Schur vectors. !>
[in]	LDVS	!> LDVS is INTEGER !> Leading dimension of VS. Must be at least max(1,max(NN)). !>
[out]	VS1	!> VS1 is REAL array, dimension (LDVS, max(NN)) !> VS1 holds another copy of the computed Schur vectors. !>
[out]	RESULT	!> RESULT is REAL array, dimension (17) !> The values computed by the 17 tests described above. !> The values are currently limited to 1/ulp, to avoid overflow. !>
[out]	WORK	!> WORK is REAL array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The number of entries in WORK. This must be at least !> max(3*NN(j),2*NN(j)**2) for all j. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (max(NN)*max(NN)) !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (max(NN)) !>
[out]	INFO	!> INFO is INTEGER !> If 0, successful exit. !> <0, input parameter -INFO is incorrect !> >0, SLATMR, SLATMS, SLATME or SGET24 returned an error !> code and INFO is its absolute value !> !>----------------------------------------------------------------------- !> !> Some Local Variables and Parameters: !> ---- ----- --------- --- ---------- !> ZERO, ONE Real 0 and 1. !> MAXTYP The number of types defined. !> NMAX Largest value in NN. !> NERRS The number of tests which have exceeded THRESH !> COND, CONDS, !> IMODE Values to be passed to the matrix generators. !> ANORM Norm of A; passed to matrix generators. !> !> OVFL, UNFL Overflow and underflow thresholds. !> ULP, ULPINV Finest relative precision and its inverse. !> RTULP, RTULPI Square roots of the previous 4 values. !> The following four arrays decode JTYPE: !> KTYPE(j) The general type (1-10) for type . !> KMODE(j) The MODE value to be passed to the matrix !> generator for type . !> KMAGN(j) The order of magnitude ( O(1), !> O(overflow^(1/2) ), O(underflow^(1/2) ) !> KCONDS(j) Selectw whether CONDS is to be 1 or !> 1/sqrt(ulp). (0 means irrelevant.) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 450 of file sdrvsx.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDVS, LWORK, NIUNIT, NOUNIT, NSIZES,
     $                   NTYPES
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * ), DOTYPE( * )
      INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
      REAL               A( LDA, * ), H( LDA, * ), HT( LDA, * ),
     $                   RESULT( 17 ), VS( LDVS, * ), VS1( LDVS, * ),
     $                   WI( * ), WIT( * ), WITMP( * ), WORK( * ),
     $                   WR( * ), WRT( * ), WRTMP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
      INTEGER            MAXTYP
      parameter( maxtyp = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN
      CHARACTER*3        PATH
      INTEGER            I, IINFO, IMODE, ITYPE, IWK, J, JCOL, JSIZE,
     $                   JTYPE, MTYPES, N, NERRS, NFAIL, NMAX,
     $                   NNWORK, NSLCT, NTEST, NTESTF, NTESTT
      REAL               ANORM, COND, CONDS, OVFL, RCDEIN, RCDVIN,
     $                   RTULP, RTULPI, ULP, ULPINV, UNFL
*     ..
*     .. Local Arrays ..
      CHARACTER          ADUMMA( 1 )
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), ISLCT( 20 ),
     $                   KCONDS( MAXTYP ), KMAGN( MAXTYP ),
     $                   KMODE( MAXTYP ), KTYPE( MAXTYP )
*     ..
*     .. Arrays in Common ..
      LOGICAL            SELVAL( 20 )
      REAL               SELWI( 20 ), SELWR( 20 )
*     ..
*     .. Scalars in Common ..
      INTEGER            SELDIM, SELOPT
*     ..
*     .. Common blocks ..
      COMMON             / sslct / selopt, seldim, selval, selwr, selwi
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           sget24, slasum, slatme, slatmr, slatms,
     $                   slaset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'SX'
*
*     Check for errors
*
      ntestt = 0
      ntestf = 0
      info = 0
*
*     Important constants
*
      badnn = .false.
*
*     12 is the largest dimension in the input file of precomputed
*     problems
*
      nmax = 12
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( niunit.LE.0 ) THEN
         info = -7
      ELSE IF( nounit.LE.0 ) THEN
         info = -8
      ELSE IF( lda.LT.1 .OR. lda.LT.nmax ) THEN
         info = -10
      ELSE IF( ldvs.LT.1 .OR. ldvs.LT.nmax ) THEN
         info = -20
      ELSE IF( max( 3*nmax, 2*nmax**2 ).GT.lwork ) THEN
         info = -24
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SDRVSX', -info )
         RETURN
      END IF
*
*     If nothing to do check on NIUNIT
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   GO TO 150
*
*     More Important constants
*
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      ulp = slamch( 'Precision' )
      ulpinv = one / ulp
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
*
      DO 140 jsize = 1, nsizes
         n = nn( jsize )
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 130 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 130
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   symmetric, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random symmetric
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 90
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 30, 40, 50 )kmagn( jtype )
*
   30       CONTINUE
            anorm = one
            GO TO 60
*
   40       CONTINUE
            anorm = ovfl*ulp
            GO TO 60
*
   50       CONTINUE
            anorm = unfl*ulpinv
            GO TO 60
*
   60       CONTINUE
*
            CALL slaset( 'Full', lda, n, zero, zero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices -- Identity & Jordan block
*
*              Zero
*
            IF( itype.EQ.1 ) THEN
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 70 jcol = 1, n
                  a( jcol, jcol ) = anorm
   70          CONTINUE
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = anorm
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = one
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL slatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, 0, 0, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL slatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               adumma( 1 ) = ' '
               CALL slatme( n, 'S', iseed, work, imode, cond, one,
     $                      adumma, 'T', 'T', 'T', work( n+1 ), 4,
     $                      conds, n, n, anorm, a, lda, work( 2*n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
               IF( n.GE.4 ) THEN
                  CALL slaset( 'Full', 2, n, zero, zero, a, lda )
                  CALL slaset( 'Full', n-3, 1, zero, zero, a( 3, 1 ),
     $                         lda )
                  CALL slaset( 'Full', n-3, 2, zero, zero, a( 3, n-1 ),
     $                         lda )
                  CALL slaset( 'Full', 1, n, zero, zero, a( n, 1 ),
     $                         lda )
               END IF
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9991 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
   90       CONTINUE
*
*           Test for minimal and generous workspace
*
            DO 120 iwk = 1, 2
               IF( iwk.EQ.1 ) THEN
                  nnwork = 3*n
               ELSE
                  nnwork = max( 3*n, 2*n*n )
               END IF
               nnwork = max( nnwork, 1 )
*
               CALL sget24( .false., jtype, thresh, ioldsd, nounit, n,
     $                      a, lda, h, ht, wr, wi, wrt, wit, wrtmp,
     $                      witmp, vs, ldvs, vs1, rcdein, rcdvin, nslct,
     $                      islct, result, work, nnwork, iwork, bwork,
     $                      info )
*
*              Check for RESULT(j) > THRESH
*
               ntest = 0
               nfail = 0
               DO 100 j = 1, 15
                  IF( result( j ).GE.zero )
     $               ntest = ntest + 1
                  IF( result( j ).GE.thresh )
     $               nfail = nfail + 1
  100          CONTINUE
*
               IF( nfail.GT.0 )
     $            ntestf = ntestf + 1
               IF( ntestf.EQ.1 ) THEN
                  WRITE( nounit, fmt = 9999 )path
                  WRITE( nounit, fmt = 9998 )
                  WRITE( nounit, fmt = 9997 )
                  WRITE( nounit, fmt = 9996 )
                  WRITE( nounit, fmt = 9995 )thresh
                  WRITE( nounit, fmt = 9994 )
                  ntestf = 2
               END IF
*
               DO 110 j = 1, 15
                  IF( result( j ).GE.thresh ) THEN
                     WRITE( nounit, fmt = 9993 )n, iwk, ioldsd, jtype,
     $                  j, result( j )
                  END IF
  110          CONTINUE
*
               nerrs = nerrs + nfail
               ntestt = ntestt + ntest
*
  120       CONTINUE
  130    CONTINUE
  140 CONTINUE
*
  150 CONTINUE
*
*     Read in data from file to check accuracy of condition estimation
*     Read input data until N=0
*
      jtype = 0
  160 CONTINUE
      READ( niunit, fmt = *, END = 200 )N, nslct
      IF( n.EQ.0 )
     $   GO TO 200
      jtype = jtype + 1
      iseed( 1 ) = jtype
      IF( nslct.GT.0 )
     $   READ( niunit, fmt = * )( islct( i ), i = 1, nslct )
      DO 170 i = 1, n
         READ( niunit, fmt = * )( a( i, j ), j = 1, n )
  170 CONTINUE
      READ( niunit, fmt = * )rcdein, rcdvin
*
      CALL sget24( .true., 22, thresh, iseed, nounit, n, a, lda, h, ht,
     $             wr, wi, wrt, wit, wrtmp, witmp, vs, ldvs, vs1,
     $             rcdein, rcdvin, nslct, islct, result, work, lwork,
     $             iwork, bwork, info )
*
*     Check for RESULT(j) > THRESH
*
      ntest = 0
      nfail = 0
      DO 180 j = 1, 17
         IF( result( j ).GE.zero )
     $      ntest = ntest + 1
         IF( result( j ).GE.thresh )
     $      nfail = nfail + 1
  180 CONTINUE
*
      IF( nfail.GT.0 )
     $   ntestf = ntestf + 1
      IF( ntestf.EQ.1 ) THEN
         WRITE( nounit, fmt = 9999 )path
         WRITE( nounit, fmt = 9998 )
         WRITE( nounit, fmt = 9997 )
         WRITE( nounit, fmt = 9996 )
         WRITE( nounit, fmt = 9995 )thresh
         WRITE( nounit, fmt = 9994 )
         ntestf = 2
      END IF
      DO 190 j = 1, 17
         IF( result( j ).GE.thresh ) THEN
            WRITE( nounit, fmt = 9992 )n, jtype, j, result( j )
         END IF
  190 CONTINUE
*
      nerrs = nerrs + nfail
      ntestt = ntestt + ntest
      GO TO 160
  200 CONTINUE
*
*     Summary
*
      CALL slasum( path, nounit, nerrs, ntestt )
*
 9999 FORMAT( / 1x, a3, ' -- Real Schur Form Decomposition Expert ',
     $      'Driver', / ' Matrix types (see SDRVSX for details):' )
*
 9998 FORMAT( / ' Special Matrices:', / '  1=Zero matrix.             ',
     $      '           ', '  5=Diagonal: geometr. spaced entries.',
     $      / '  2=Identity matrix.                    ', '  6=Diagona',
     $      'l: clustered entries.', / '  3=Transposed Jordan block.  ',
     $      '          ', '  7=Diagonal: large, evenly spaced.', / '  ',
     $      '4=Diagonal: evenly spaced entries.    ', '  8=Diagonal: s',
     $      'mall, evenly spaced.' )
 9997 FORMAT( ' Dense, Non-Symmetric Matrices:', / '  9=Well-cond., ev',
     $      'enly spaced eigenvals.', ' 14=Ill-cond., geomet. spaced e',
     $      'igenals.', / ' 10=Well-cond., geom. spaced eigenvals. ',
     $      ' 15=Ill-conditioned, clustered e.vals.', / ' 11=Well-cond',
     $      'itioned, clustered e.vals. ', ' 16=Ill-cond., random comp',
     $      'lex ', / ' 12=Well-cond., random complex ', '         ',
     $      ' 17=Ill-cond., large rand. complx ', / ' 13=Ill-condi',
     $      'tioned, evenly spaced.     ', ' 18=Ill-cond., small rand.',
     $      ' complx ' )
 9996 FORMAT( ' 19=Matrix with random O(1) entries.    ', ' 21=Matrix ',
     $      'with small random entries.', / ' 20=Matrix with large ran',
     $      'dom entries.   ', / )
 9995 FORMAT( ' Tests performed with test threshold =', f8.2,
     $      / ' ( A denotes A on input and T denotes A on output)',
     $      / / ' 1 = 0 if T in Schur form (no sort), ',
     $      '  1/ulp otherwise', /
     $      ' 2 = | A - VS T transpose(VS) | / ( n |A| ulp ) (no sort)',
     $      / ' 3 = | I - VS transpose(VS) | / ( n ulp ) (no sort) ', /
     $      ' 4 = 0 if WR+sqrt(-1)*WI are eigenvalues of T (no sort),',
     $      '  1/ulp otherwise', /
     $      ' 5 = 0 if T same no matter if VS computed (no sort),',
     $      '  1/ulp otherwise', /
     $      ' 6 = 0 if WR, WI same no matter if VS computed (no sort)',
     $      ',  1/ulp otherwise' )
 9994 FORMAT( ' 7 = 0 if T in Schur form (sort), ', '  1/ulp otherwise',
     $      / ' 8 = | A - VS T transpose(VS) | / ( n |A| ulp ) (sort)',
     $      / ' 9 = | I - VS transpose(VS) | / ( n ulp ) (sort) ',
     $      / ' 10 = 0 if WR+sqrt(-1)*WI are eigenvalues of T (sort),',
     $      '  1/ulp otherwise', /
     $      ' 11 = 0 if T same no matter what else computed (sort),',
     $      '  1/ulp otherwise', /
     $      ' 12 = 0 if WR, WI same no matter what else computed ',
     $      '(sort), 1/ulp otherwise', /
     $      ' 13 = 0 if sorting successful, 1/ulp otherwise',
     $      / ' 14 = 0 if RCONDE same no matter what else computed,',
     $      ' 1/ulp otherwise', /
     $      ' 15 = 0 if RCONDv same no matter what else computed,',
     $      ' 1/ulp otherwise', /
     $      ' 16 = | RCONDE - RCONDE(precomputed) | / cond(RCONDE),',
     $      / ' 17 = | RCONDV - RCONDV(precomputed) | / cond(RCONDV),' )
 9993 FORMAT( ' N=', i5, ', IWK=', i2, ', seed=', 4( i4, ',' ),
     $      ' type ', i2, ', test(', i2, ')=', g10.3 )
 9992 FORMAT( ' N=', i5, ', input example =', i3, ',  test(', i2, ')=',
     $      g10.3 )
 9991 FORMAT( ' SDRVSX: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
      RETURN
*
*     End of SDRVSX
*

Here is the call graph for this function:

Here is the caller graph for this function: