claed7()

subroutine claed7	(	integer	n,
		integer	cutpnt,
		integer	qsiz,
		integer	tlvls,
		integer	curlvl,
		integer	curpbm,
		real, dimension( * )	d,
		complex, dimension( ldq, * )	q,
		integer	ldq,
		real	rho,
		integer, dimension( * )	indxq,
		real, dimension( * )	qstore,
		integer, dimension( * )	qptr,
		integer, dimension( * )	prmptr,
		integer, dimension( * )	perm,
		integer, dimension( * )	givptr,
		integer, dimension( 2, * )	givcol,
		real, dimension( 2, * )	givnum,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	info )

CLAED7 used by CSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is dense.

Download CLAED7 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLAED7 computes the updated eigensystem of a diagonal
!> matrix after modification by a rank-one symmetric matrix. This
!> routine is used only for the eigenproblem which requires all
!> eigenvalues and optionally eigenvectors of a dense or banded
!> Hermitian matrix that has been reduced to tridiagonal form.
!>
!>   T = Q(in) ( D(in) + RHO * Z*Z**H ) Q**H(in) = Q(out) * D(out) * Q**H(out)
!>
!>   where Z = Q**Hu, u is a vector of length N with ones in the
!>   CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.
!>
!>    The eigenvectors of the original matrix are stored in Q, and the
!>    eigenvalues are in D.  The algorithm consists of three stages:
!>
!>       The first stage consists of deflating the size of the problem
!>       when there are multiple eigenvalues or if there is a zero in
!>       the Z vector.  For each such occurrence the dimension of the
!>       secular equation problem is reduced by one.  This stage is
!>       performed by the routine SLAED2.
!>
!>       The second stage consists of calculating the updated
!>       eigenvalues. This is done by finding the roots of the secular
!>       equation via the routine SLAED4 (as called by SLAED3).
!>       This routine also calculates the eigenvectors of the current
!>       problem.
!>
!>       The final stage consists of computing the updated eigenvectors
!>       directly using the updated eigenvalues.  The eigenvectors for
!>       the current problem are multiplied with the eigenvectors from
!>       the overall problem.
!> 

Parameters

[in]	N	!> N is INTEGER !> The dimension of the symmetric tridiagonal matrix. N >= 0. !>
[in]	CUTPNT	!> CUTPNT is INTEGER !> Contains the location of the last eigenvalue in the leading !> sub-matrix. min(1,N) <= CUTPNT <= N. !>
[in]	QSIZ	!> QSIZ is INTEGER !> The dimension of the unitary matrix used to reduce !> the full matrix to tridiagonal form. QSIZ >= N. !>
[in]	TLVLS	!> TLVLS is INTEGER !> The total number of merging levels in the overall divide and !> conquer tree. !>
[in]	CURLVL	!> CURLVL is INTEGER !> The current level in the overall merge routine, !> 0 <= curlvl <= tlvls. !>
[in]	CURPBM	!> CURPBM is INTEGER !> The current problem in the current level in the overall !> merge routine (counting from upper left to lower right). !>
[in,out]	D	!> D is REAL array, dimension (N) !> On entry, the eigenvalues of the rank-1-perturbed matrix. !> On exit, the eigenvalues of the repaired matrix. !>
[in,out]	Q	!> Q is COMPLEX array, dimension (LDQ,N) !> On entry, the eigenvectors of the rank-1-perturbed matrix. !> On exit, the eigenvectors of the repaired tridiagonal matrix. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,N). !>
[in]	RHO	!> RHO is REAL !> Contains the subdiagonal element used to create the rank-1 !> modification. !>
[out]	INDXQ	!> INDXQ is INTEGER array, dimension (N) !> This contains the permutation which will reintegrate the !> subproblem just solved back into sorted order, !> ie. D( INDXQ( I = 1, N ) ) will be in ascending order. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (4*N) !>
[out]	RWORK	!> RWORK is REAL array, !> dimension (3*N+2*QSIZ*N) !>
[out]	WORK	!> WORK is COMPLEX array, dimension (QSIZ*N) !>
[in,out]	QSTORE	!> QSTORE is REAL array, dimension (N**2+1) !> Stores eigenvectors of submatrices encountered during !> divide and conquer, packed together. QPTR points to !> beginning of the submatrices. !>
[in,out]	QPTR	!> QPTR is INTEGER array, dimension (N+2) !> List of indices pointing to beginning of submatrices stored !> in QSTORE. The submatrices are numbered starting at the !> bottom left of the divide and conquer tree, from left to !> right and bottom to top. !>
[in]	PRMPTR	!> PRMPTR is INTEGER array, dimension (N lg N) !> Contains a list of pointers which indicate where in PERM a !> level's permutation is stored. PRMPTR(i+1) - PRMPTR(i) !> indicates the size of the permutation and also the size of !> the full, non-deflated problem. !>
[in]	PERM	!> PERM is INTEGER array, dimension (N lg N) !> Contains the permutations (from deflation and sorting) to be !> applied to each eigenblock. !>
[in]	GIVPTR	!> GIVPTR is INTEGER array, dimension (N lg N) !> Contains a list of pointers which indicate where in GIVCOL a !> level's Givens rotations are stored. GIVPTR(i+1) - GIVPTR(i) !> indicates the number of Givens rotations. !>
[in]	GIVCOL	!> GIVCOL is INTEGER array, dimension (2, N lg N) !> Each pair of numbers indicates a pair of columns to take place !> in a Givens rotation. !>
[in]	GIVNUM	!> GIVNUM is REAL array, dimension (2, N lg N) !> Each number indicates the S value to be used in the !> corresponding Givens rotation. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = 1, an eigenvalue did not converge !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 243 of file claed7.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            CURLVL, CURPBM, CUTPNT, INFO, LDQ, N, QSIZ,
     $                   TLVLS
      REAL               RHO
*     ..
*     .. Array Arguments ..
      INTEGER            GIVCOL( 2, * ), GIVPTR( * ), INDXQ( * ),
     $                   IWORK( * ), PERM( * ), PRMPTR( * ), QPTR( * )
      REAL               D( * ), GIVNUM( 2, * ), QSTORE( * ), RWORK( * )
      COMPLEX            Q( LDQ, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            COLTYP, CURR, I, IDLMDA, INDX,
     $                   INDXC, INDXP, IQ, IW, IZ, K, N1, N2, PTR
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacrm, claed8, slaed9, slaeda, slamrg,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
*     IF( ICOMPQ.LT.0 .OR. ICOMPQ.GT.1 ) THEN
*        INFO = -1
*     ELSE IF( N.LT.0 ) THEN
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( min( 1, n ).GT.cutpnt .OR. n.LT.cutpnt ) THEN
         info = -2
      ELSE IF( qsiz.LT.n ) THEN
         info = -3
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLAED7', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     The following values are for bookkeeping purposes only.  They are
*     integer pointers which indicate the portion of the workspace
*     used by a particular array in SLAED2 and SLAED3.
*
      iz = 1
      idlmda = iz + n
      iw = idlmda + n
      iq = iw + n
*
      indx = 1
      indxc = indx + n
      coltyp = indxc + n
      indxp = coltyp + n
*
*     Form the z-vector which consists of the last row of Q_1 and the
*     first row of Q_2.
*
      ptr = 1 + 2**tlvls
      DO 10 i = 1, curlvl - 1
         ptr = ptr + 2**( tlvls-i )
   10 CONTINUE
      curr = ptr + curpbm
      CALL slaeda( n, tlvls, curlvl, curpbm, prmptr, perm, givptr,
     $             givcol, givnum, qstore, qptr, rwork( iz ),
     $             rwork( iz+n ), info )
*
*     When solving the final problem, we no longer need the stored data,
*     so we will overwrite the data from this level onto the previously
*     used storage space.
*
      IF( curlvl.EQ.tlvls ) THEN
         qptr( curr ) = 1
         prmptr( curr ) = 1
         givptr( curr ) = 1
      END IF
*
*     Sort and Deflate eigenvalues.
*
      CALL claed8( k, n, qsiz, q, ldq, d, rho, cutpnt, rwork( iz ),
     $             rwork( idlmda ), work, qsiz, rwork( iw ),
     $             iwork( indxp ), iwork( indx ), indxq,
     $             perm( prmptr( curr ) ), givptr( curr+1 ),
     $             givcol( 1, givptr( curr ) ),
     $             givnum( 1, givptr( curr ) ), info )
      prmptr( curr+1 ) = prmptr( curr ) + n
      givptr( curr+1 ) = givptr( curr+1 ) + givptr( curr )
*
*     Solve Secular Equation.
*
      IF( k.NE.0 ) THEN
         CALL slaed9( k, 1, k, n, d, rwork( iq ), k, rho,
     $                rwork( idlmda ), rwork( iw ),
     $                qstore( qptr( curr ) ), k, info )
         CALL clacrm( qsiz, k, work, qsiz, qstore( qptr( curr ) ), k,
     $                q,
     $                ldq, rwork( iq ) )
         qptr( curr+1 ) = qptr( curr ) + k**2
         IF( info.NE.0 ) THEN
            RETURN
         END IF
*
*     Prepare the INDXQ sorting permutation.
*
         n1 = k
         n2 = n - k
         CALL slamrg( n1, n2, d, 1, -1, indxq )
      ELSE
         qptr( curr+1 ) = qptr( curr )
         DO 20 i = 1, n
            indxq( i ) = i
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of CLAED7
*

Here is the call graph for this function:

Here is the caller graph for this function: