LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zhesv_rk()

subroutine zhesv_rk ( character uplo,
integer n,
integer nrhs,
complex*16, dimension( lda, * ) a,
integer lda,
complex*16, dimension( * ) e,
integer, dimension( * ) ipiv,
complex*16, dimension( ldb, * ) b,
integer ldb,
complex*16, dimension( * ) work,
integer lwork,
integer info )

ZHESV_RK computes the solution to system of linear equations A * X = B for SY matrices

Download ZHESV_RK + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!> ZHESV_RK computes the solution to a complex system of linear
!> equations A * X = B, where A is an N-by-N Hermitian matrix
!> and X and B are N-by-NRHS matrices.
!>
!> The bounded Bunch-Kaufman (rook) diagonal pivoting method is used
!> to factor A as
!>    A = P*U*D*(U**H)*(P**T),  if UPLO = 'U', or
!>    A = P*L*D*(L**H)*(P**T),  if UPLO = 'L',
!> where U (or L) is unit upper (or lower) triangular matrix,
!> U**H (or L**H) is the conjugate of U (or L), P is a permutation
!> matrix, P**T is the transpose of P, and D is Hermitian and block
!> diagonal with 1-by-1 and 2-by-2 diagonal blocks.
!>
!> ZHETRF_RK is called to compute the factorization of a complex
!> Hermitian matrix.  The factored form of A is then used to solve
!> the system of equations A * X = B by calling BLAS3 routine ZHETRS_3.
!>
Parameters
[in]UPLO
!>          UPLO is CHARACTER*1
!>          Specifies whether the upper or lower triangular part of the
!>          Hermitian matrix A is stored:
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The number of linear equations, i.e., the order of the
!>          matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrix B.  NRHS >= 0.
!>
[in,out]A
!>          A is COMPLEX*16 array, dimension (LDA,N)
!>          On entry, the Hermitian matrix A.
!>            If UPLO = 'U': the leading N-by-N upper triangular part
!>            of A contains the upper triangular part of the matrix A,
!>            and the strictly lower triangular part of A is not
!>            referenced.
!>
!>            If UPLO = 'L': the leading N-by-N lower triangular part
!>            of A contains the lower triangular part of the matrix A,
!>            and the strictly upper triangular part of A is not
!>            referenced.
!>
!>          On exit, if INFO = 0, diagonal of the block diagonal
!>          matrix D and factors U or L  as computed by ZHETRF_RK:
!>            a) ONLY diagonal elements of the Hermitian block diagonal
!>               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
!>               (superdiagonal (or subdiagonal) elements of D
!>                are stored on exit in array E), and
!>            b) If UPLO = 'U': factor U in the superdiagonal part of A.
!>               If UPLO = 'L': factor L in the subdiagonal part of A.
!>
!>          For more info see the description of ZHETRF_RK routine.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[out]E
!>          E is COMPLEX*16 array, dimension (N)
!>          On exit, contains the output computed by the factorization
!>          routine ZHETRF_RK, i.e. the superdiagonal (or subdiagonal)
!>          elements of the Hermitian block diagonal matrix D
!>          with 1-by-1 or 2-by-2 diagonal blocks, where
!>          If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0;
!>          If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0.
!>
!>          NOTE: For 1-by-1 diagonal block D(k), where
!>          1 <= k <= N, the element E(k) is set to 0 in both
!>          UPLO = 'U' or UPLO = 'L' cases.
!>
!>          For more info see the description of ZHETRF_RK routine.
!>
[out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          Details of the interchanges and the block structure of D,
!>          as determined by ZHETRF_RK.
!>
!>          For more info see the description of ZHETRF_RK routine.
!>
[in,out]B
!>          B is COMPLEX*16 array, dimension (LDB,NRHS)
!>          On entry, the N-by-NRHS right hand side matrix B.
!>          On exit, if INFO = 0, the N-by-NRHS solution matrix X.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension ( MAX(1,LWORK) ).
!>          Work array used in the factorization stage.
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of WORK.  LWORK >= 1. For best performance
!>          of factorization stage LWORK >= max(1,N*NB), where NB is
!>          the optimal blocksize for ZHETRF_RK.
!>
!>          If LWORK = -1, then a workspace query is assumed;
!>          the routine only calculates the optimal size of the WORK
!>          array for factorization stage, returns this value as
!>          the first entry of the WORK array, and no error message
!>          related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0: successful exit
!>
!>          < 0: If INFO = -k, the k-th argument had an illegal value
!>
!>          > 0: If INFO = k, the matrix A is singular, because:
!>                 If UPLO = 'U': column k in the upper
!>                 triangular part of A contains all zeros.
!>                 If UPLO = 'L': column k in the lower
!>                 triangular part of A contains all zeros.
!>
!>               Therefore D(k,k) is exactly zero, and superdiagonal
!>               elements of column k of U (or subdiagonal elements of
!>               column k of L ) are all zeros. The factorization has
!>               been completed, but the block diagonal matrix D is
!>               exactly singular, and division by zero will occur if
!>               it is used to solve a system of equations.
!>
!>               NOTE: INFO only stores the first occurrence of
!>               a singularity, any subsequent occurrence of singularity
!>               is not stored in INFO even though the factorization
!>               always completes.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
!>
!>  December 2016,  Igor Kozachenko,
!>                  Computer Science Division,
!>                  University of California, Berkeley
!>
!>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
!>                  School of Mathematics,
!>                  University of Manchester
!>
!>

Definition at line 224 of file zhesv_rk.f.

227*
228* -- LAPACK driver routine --
229* -- LAPACK is a software package provided by Univ. of Tennessee, --
230* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
231*
232* .. Scalar Arguments ..
233 CHARACTER UPLO
234 INTEGER INFO, LDA, LDB, LWORK, N, NRHS
235* ..
236* .. Array Arguments ..
237 INTEGER IPIV( * )
238 COMPLEX*16 A( LDA, * ), B( LDB, * ), E( * ), WORK( * )
239* ..
240*
241* =====================================================================
242*
243* .. Local Scalars ..
244 LOGICAL LQUERY
245 INTEGER LWKOPT
246* ..
247* .. External Functions ..
248 LOGICAL LSAME
249 EXTERNAL lsame
250* ..
251* .. External Subroutines ..
252 EXTERNAL xerbla, zhetrf_rk, zhetrs_3
253* ..
254* .. Intrinsic Functions ..
255 INTRINSIC max
256* ..
257* .. Executable Statements ..
258*
259* Test the input parameters.
260*
261 info = 0
262 lquery = ( lwork.EQ.-1 )
263 IF( .NOT.lsame( uplo, 'U' ) .AND.
264 $ .NOT.lsame( uplo, 'L' ) ) THEN
265 info = -1
266 ELSE IF( n.LT.0 ) THEN
267 info = -2
268 ELSE IF( nrhs.LT.0 ) THEN
269 info = -3
270 ELSE IF( lda.LT.max( 1, n ) ) THEN
271 info = -5
272 ELSE IF( ldb.LT.max( 1, n ) ) THEN
273 info = -9
274 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
275 info = -11
276 END IF
277*
278 IF( info.EQ.0 ) THEN
279 IF( n.EQ.0 ) THEN
280 lwkopt = 1
281 ELSE
282 CALL zhetrf_rk( uplo, n, a, lda, e, ipiv, work, -1,
283 $ info )
284 lwkopt = int( dble( work( 1 ) ) )
285 END IF
286 work( 1 ) = lwkopt
287 END IF
288*
289 IF( info.NE.0 ) THEN
290 CALL xerbla( 'ZHESV_RK ', -info )
291 RETURN
292 ELSE IF( lquery ) THEN
293 RETURN
294 END IF
295*
296* Compute the factorization A = P*U*D*(U**H)*(P**T) or
297* A = P*U*D*(U**H)*(P**T).
298*
299 CALL zhetrf_rk( uplo, n, a, lda, e, ipiv, work, lwork, info )
300*
301 IF( info.EQ.0 ) THEN
302*
303* Solve the system A*X = B with BLAS3 solver, overwriting B with X.
304*
305 CALL zhetrs_3( uplo, n, nrhs, a, lda, e, ipiv, b, ldb,
306 $ info )
307*
308 END IF
309*
310 work( 1 ) = lwkopt
311*
312 RETURN
313*
314* End of ZHESV_RK
315*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zhetrf_rk
subroutine zhetrf_rk(uplo, n, a, lda, e, ipiv, work, lwork, info)
ZHETRF_RK computes the factorization of a complex Hermitian indefinite matrix using the bounded Bunch...
Definition zhetrf_rk.f:257
zhetrs_3
subroutine zhetrs_3(uplo, n, nrhs, a, lda, e, ipiv, b, ldb, info)
ZHETRS_3
Definition zhetrs_3.f:163
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: