dgeqrs()

subroutine dgeqrs	(	integer	m,
		integer	n,
		integer	nrhs,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( lwork )	work,
		integer	lwork,
		integer	info )

DGEQRS

Purpose:

!>
!> Solve the least squares problem
!>     min || A*X - B ||
!> using the QR factorization
!>     A = Q*R
!> computed by DGEQRF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. M >= N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B. NRHS >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> Details of the QR factorization of the original matrix A as !> returned by DGEQRF. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= M. !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (N) !> Details of the orthogonal matrix Q. !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> On entry, the m-by-nrhs right hand side matrix B. !> On exit, the n-by-nrhs solution matrix X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= M. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK must be at least NRHS, !> and should be at least NRHS*NB, where NB is the block size !> for this environment. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 119 of file dgeqrs.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dormqr, dtrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -8
      ELSE IF( lwork.LT.1 .OR. lwork.LT.nrhs .AND. m.GT.0 .AND. n.GT.0 )
     $          THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEQRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 .OR. m.EQ.0 )
     $   RETURN
*
*     B := Q' * B
*
      CALL dormqr( 'Left', 'Transpose', m, nrhs, n, a, lda, tau, b, ldb,
     $             work, lwork, info )
*
*     Solve R*X = B(1:n,:)
*
      CALL dtrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', n, nrhs,
     $            one, a, lda, b, ldb )
*
      RETURN
*
*     End of DGEQRS
*

Here is the call graph for this function: