zgsvj1.f

Go to the documentation of this file.

*> \brief \b ZGSVJ1 pre-processor for the routine zgesvj, applies Jacobi rotations targeting only particular pivots.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZGSVJ1 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgsvj1.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgsvj1.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgsvj1.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGSVJ1( JOBV, M, N, N1, A, LDA, D, SVA, MV, V, LDV,
*                          EPS, SFMIN, TOL, NSWEEP, WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   EPS, SFMIN, TOL
*       INTEGER            INFO, LDA, LDV, LWORK, M, MV, N, N1, NSWEEP
*       CHARACTER*1        JOBV
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), D( N ), V( LDV, * ), WORK( LWORK )
*       DOUBLE PRECISION   SVA( N )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGSVJ1 is called from ZGESVJ as a pre-processor and that is its main
*> purpose. It applies Jacobi rotations in the same way as ZGESVJ does, but
*> it targets only particular pivots and it does not check convergence
*> (stopping criterion). Few tuning parameters (marked by [TP]) are
*> available for the implementer.
*>
*> Further Details
*> ~~~~~~~~~~~~~~~
*> ZGSVJ1 applies few sweeps of Jacobi rotations in the column space of
*> the input M-by-N matrix A. The pivot pairs are taken from the (1,2)
*> off-diagonal block in the corresponding N-by-N Gram matrix A^T * A. The
*> block-entries (tiles) of the (1,2) off-diagonal block are marked by the
*> [x]'s in the following scheme:
*>
*>    | *  *  * [x] [x] [x]|
*>    | *  *  * [x] [x] [x]|    Row-cycling in the nblr-by-nblc [x] blocks.
*>    | *  *  * [x] [x] [x]|    Row-cyclic pivoting inside each [x] block.
*>    |[x] [x] [x] *  *  * |
*>    |[x] [x] [x] *  *  * |
*>    |[x] [x] [x] *  *  * |
*>
*> In terms of the columns of A, the first N1 columns are rotated 'against'
*> the remaining N-N1 columns, trying to increase the angle between the
*> corresponding subspaces. The off-diagonal block is N1-by(N-N1) and it is
*> tiled using quadratic tiles of side KBL. Here, KBL is a tuning parameter.
*> The number of sweeps is given in NSWEEP and the orthogonality threshold
*> is given in TOL.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] JOBV
*> \verbatim
*>          JOBV is CHARACTER*1
*>          Specifies whether the output from this procedure is used
*>          to compute the matrix V:
*>          = 'V': the product of the Jacobi rotations is accumulated
*>                 by postmultiplying the N-by-N array V.
*>                (See the description of V.)
*>          = 'A': the product of the Jacobi rotations is accumulated
*>                 by postmultiplying the MV-by-N array V.
*>                (See the descriptions of MV and V.)
*>          = 'N': the Jacobi rotations are not accumulated.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the input matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the input matrix A.
*>          M >= N >= 0.
*> \endverbatim
*>
*> \param[in] N1
*> \verbatim
*>          N1 is INTEGER
*>          N1 specifies the 2 x 2 block partition, the first N1 columns are
*>          rotated 'against' the remaining N-N1 columns of A.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, M-by-N matrix A, such that A*diag(D) represents
*>          the input matrix.
*>          On exit,
*>          A_onexit * D_onexit represents the input matrix A*diag(D)
*>          post-multiplied by a sequence of Jacobi rotations, where the
*>          rotation threshold and the total number of sweeps are given in
*>          TOL and NSWEEP, respectively.
*>          (See the descriptions of N1, D, TOL and NSWEEP.)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is COMPLEX*16 array, dimension (N)
*>          The array D accumulates the scaling factors from the fast scaled
*>          Jacobi rotations.
*>          On entry, A*diag(D) represents the input matrix.
*>          On exit, A_onexit*diag(D_onexit) represents the input matrix
*>          post-multiplied by a sequence of Jacobi rotations, where the
*>          rotation threshold and the total number of sweeps are given in
*>          TOL and NSWEEP, respectively.
*>          (See the descriptions of N1, A, TOL and NSWEEP.)
*> \endverbatim
*>
*> \param[in,out] SVA
*> \verbatim
*>          SVA is DOUBLE PRECISION array, dimension (N)
*>          On entry, SVA contains the Euclidean norms of the columns of
*>          the matrix A*diag(D).
*>          On exit, SVA contains the Euclidean norms of the columns of
*>          the matrix onexit*diag(D_onexit).
*> \endverbatim
*>
*> \param[in] MV
*> \verbatim
*>          MV is INTEGER
*>          If JOBV = 'A', then MV rows of V are post-multiplied by a
*>                           sequence of Jacobi rotations.
*>          If JOBV = 'N',   then MV is not referenced.
*> \endverbatim
*>
*> \param[in,out] V
*> \verbatim
*>          V is COMPLEX*16 array, dimension (LDV,N)
*>          If JOBV = 'V' then N rows of V are post-multiplied by a
*>                           sequence of Jacobi rotations.
*>          If JOBV = 'A' then MV rows of V are post-multiplied by a
*>                           sequence of Jacobi rotations.
*>          If JOBV = 'N',   then V is not referenced.
*> \endverbatim
*>
*> \param[in] LDV
*> \verbatim
*>          LDV is INTEGER
*>          The leading dimension of the array V,  LDV >= 1.
*>          If JOBV = 'V', LDV >= N.
*>          If JOBV = 'A', LDV >= MV.
*> \endverbatim
*>
*> \param[in] EPS
*> \verbatim
*>          EPS is DOUBLE PRECISION
*>          EPS = DLAMCH('Epsilon')
*> \endverbatim
*>
*> \param[in] SFMIN
*> \verbatim
*>          SFMIN is DOUBLE PRECISION
*>          SFMIN = DLAMCH('Safe Minimum')
*> \endverbatim
*>
*> \param[in] TOL
*> \verbatim
*>          TOL is DOUBLE PRECISION
*>          TOL is the threshold for Jacobi rotations. For a pair
*>          A(:,p), A(:,q) of pivot columns, the Jacobi rotation is
*>          applied only if ABS(COS(angle(A(:,p),A(:,q)))) > TOL.
*> \endverbatim
*>
*> \param[in] NSWEEP
*> \verbatim
*>          NSWEEP is INTEGER
*>          NSWEEP is the number of sweeps of Jacobi rotations to be
*>          performed.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          LWORK is the dimension of WORK. LWORK >= M.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, then the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup gsvj1
*
*> \par Contributor:
*  ==================
*>
*> Zlatko Drmac (Zagreb, Croatia)
*
*  =====================================================================
      SUBROUTINE zgsvj1( JOBV, M, N, N1, A, LDA, D, SVA, MV, V, LDV,
     $                   EPS, SFMIN, TOL, NSWEEP, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*     .. Scalar Arguments ..
      DOUBLE PRECISION   EPS, SFMIN, TOL
      INTEGER            INFO, LDA, LDV, LWORK, M, MV, N, N1, NSWEEP
      CHARACTER*1        JOBV
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), D( N ), V( LDV, * ), WORK( LWORK )
      DOUBLE PRECISION   SVA( N )
*     ..
*
*  =====================================================================
*
*     .. Local Parameters ..
      DOUBLE PRECISION   ZERO, HALF, ONE
      parameter( zero = 0.0d0, half = 0.5d0, one = 1.0d0)
*     ..
*     .. Local Scalars ..
      COMPLEX*16         AAPQ, OMPQ
      DOUBLE PRECISION   AAPP, AAPP0, AAPQ1, AAQQ, APOAQ, AQOAP, BIG,
     $                   bigtheta, cs, mxaapq, mxsinj, rootbig,
     $                   rooteps, rootsfmin, roottol, small, sn, t,
     $                   temp1, theta, thsign
      INTEGER            BLSKIP, EMPTSW, i, ibr, igl, IERR, IJBLSK,
     $                   iswrot, jbc, jgl, kbl, mvl, notrot, nblc, nblr,
     $                   p, pskipped, q, rowskip, swband
      LOGICAL            APPLV, ROTOK, RSVEC
*     ..
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, conjg, max, dble, min, sign, sqrt
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DZNRM2
      COMPLEX*16         ZDOTC
      INTEGER            IDAMAX
      LOGICAL            LSAME
      EXTERNAL           idamax, lsame, zdotc, dznrm2
*     ..
*     .. External Subroutines ..
*     .. from BLAS
      EXTERNAL           zcopy, zrot, zswap, zaxpy
*     .. from LAPACK
      EXTERNAL           zlascl, zlassq, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      applv = lsame( jobv, 'A' )
      rsvec = lsame( jobv, 'V' )
      IF( .NOT.( rsvec .OR. applv .OR. lsame( jobv, 'N' ) ) ) THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( ( n.LT.0 ) .OR. ( n.GT.m ) ) THEN
         info = -3
      ELSE IF( n1.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.m ) THEN
         info = -6
      ELSE IF( ( rsvec.OR.applv ) .AND. ( mv.LT.0 ) ) THEN
         info = -9
      ELSE IF( ( rsvec.AND.( ldv.LT.n ) ).OR.
     $         ( applv.AND.( ldv.LT.mv ) )  ) THEN
         info = -11
      ELSE IF( tol.LE.eps ) THEN
         info = -14
      ELSE IF( nsweep.LT.0 ) THEN
         info = -15
      ELSE IF( lwork.LT.m ) THEN
         info = -17
      ELSE
         info = 0
      END IF
*
*     #:(
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGSVJ1', -info )
         RETURN
      END IF
*
      IF( rsvec ) THEN
         mvl = n
      ELSE IF( applv ) THEN
         mvl = mv
      END IF
      rsvec = rsvec .OR. applv
 
      rooteps = sqrt( eps )
      rootsfmin = sqrt( sfmin )
      small = sfmin / eps
      big = one / sfmin
      rootbig = one / rootsfmin
*     LARGE = BIG / SQRT( DBLE( M*N ) )
      bigtheta = one / rooteps
      roottol = sqrt( tol )
*
*     .. Initialize the right singular vector matrix ..
*
*     RSVEC = LSAME( JOBV, 'Y' )
*
      emptsw = n1*( n-n1 )
      notrot = 0
*
*     .. Row-cyclic pivot strategy with de Rijk's pivoting ..
*
      kbl = min( 8, n )
      nblr = n1 / kbl
      IF( ( nblr*kbl ).NE.n1 )nblr = nblr + 1
 
*     .. the tiling is nblr-by-nblc [tiles]
 
      nblc = ( n-n1 ) / kbl
      IF( ( nblc*kbl ).NE.( n-n1 ) )nblc = nblc + 1
      blskip = ( kbl**2 ) + 1
*[TP] BLKSKIP is a tuning parameter that depends on SWBAND and KBL.
 
      rowskip = min( 5, kbl )
*[TP] ROWSKIP is a tuning parameter.
      swband = 0
*[TP] SWBAND is a tuning parameter. It is meaningful and effective
*     if ZGESVJ is used as a computational routine in the preconditioned
*     Jacobi SVD algorithm ZGEJSV.
*
*
*     | *   *   * [x] [x] [x]|
*     | *   *   * [x] [x] [x]|    Row-cycling in the nblr-by-nblc [x] blocks.
*     | *   *   * [x] [x] [x]|    Row-cyclic pivoting inside each [x] block.
*     |[x] [x] [x] *   *   * |
*     |[x] [x] [x] *   *   * |
*     |[x] [x] [x] *   *   * |
*
*
      DO 1993 i = 1, nsweep
*
*     .. go go go ...
*
         mxaapq = zero
         mxsinj = zero
         iswrot = 0
*
         notrot = 0
         pskipped = 0
*
*     Each sweep is unrolled using KBL-by-KBL tiles over the pivot pairs
*     1 <= p < q <= N. This is the first step toward a blocked implementation
*     of the rotations. New implementation, based on block transformations,
*     is under development.
*
         DO 2000 ibr = 1, nblr
*
            igl = ( ibr-1 )*kbl + 1
*
 
*
* ... go to the off diagonal blocks
*
            igl = ( ibr-1 )*kbl + 1
*
*            DO 2010 jbc = ibr + 1, NBL
            DO 2010 jbc = 1, nblc
*
               jgl = ( jbc-1 )*kbl + n1 + 1
*
*        doing the block at ( ibr, jbc )
*
               ijblsk = 0
               DO 2100 p = igl, min( igl+kbl-1, n1 )
*
                  aapp = sva( p )
                  IF( aapp.GT.zero ) THEN
*
                     pskipped = 0
*
                     DO 2200 q = jgl, min( jgl+kbl-1, n )
*
                        aaqq = sva( q )
                        IF( aaqq.GT.zero ) THEN
                           aapp0 = aapp
*
*     .. M x 2 Jacobi SVD ..
*
*        Safe Gram matrix computation
*
                           IF( aaqq.GE.one ) THEN
                              IF( aapp.GE.aaqq ) THEN
                                 rotok = ( small*aapp ).LE.aaqq
                              ELSE
                                 rotok = ( small*aaqq ).LE.aapp
                              END IF
                              IF( aapp.LT.( big / aaqq ) ) THEN
                                 aapq = ( zdotc( m, a( 1, p ), 1,
     $                                  a( 1, q ), 1 ) / aaqq ) / aapp
                              ELSE
                                 CALL zcopy( m, a( 1, p ), 1,
     $                                       work, 1 )
                                 CALL zlascl( 'G', 0, 0, aapp,
     $                                        one, m, 1,
     $                                        work, lda, ierr )
                                 aapq = zdotc( m, work, 1,
     $                                  a( 1, q ), 1 ) / aaqq
                              END IF
                           ELSE
                              IF( aapp.GE.aaqq ) THEN
                                 rotok = aapp.LE.( aaqq / small )
                              ELSE
                                 rotok = aaqq.LE.( aapp / small )
                              END IF
                              IF( aapp.GT.( small / aaqq ) ) THEN
                                 aapq = ( zdotc( m, a( 1, p ), 1,
     $                                 a( 1, q ), 1 ) / max(aaqq,aapp) )
     $                                               / min(aaqq,aapp)
                              ELSE
                                 CALL zcopy( m, a( 1, q ), 1,
     $                                       work, 1 )
                                 CALL zlascl( 'G', 0, 0, aaqq,
     $                                        one, m, 1,
     $                                        work, lda, ierr )
                                 aapq = zdotc( m, a( 1, p ), 1,
     $                                  work, 1 ) / aapp
                              END IF
                           END IF
*
*                           AAPQ = AAPQ * CONJG(CWORK(p))*CWORK(q)
                           aapq1  = -abs(aapq)
                           mxaapq = max( mxaapq, -aapq1 )
*
*        TO rotate or NOT to rotate, THAT is the question ...
*
                           IF( abs( aapq1 ).GT.tol ) THEN
                              ompq = aapq / abs(aapq)
                              notrot = 0
*[RTD]      ROTATED  = ROTATED + 1
                              pskipped = 0
                              iswrot = iswrot + 1
*
                              IF( rotok ) THEN
*
                                 aqoap = aaqq / aapp
                                 apoaq = aapp / aaqq
                                 theta = -half*abs( aqoap-apoaq )/ aapq1
                                 IF( aaqq.GT.aapp0 )theta = -theta
*
                                 IF( abs( theta ).GT.bigtheta ) THEN
                                    t  = half / theta
                                    cs = one
                                    CALL zrot( m, a(1,p), 1, a(1,q), 1,
     $                                          cs, conjg(ompq)*t )
                                    IF( rsvec ) THEN
                                        CALL zrot( mvl, v(1,p), 1,
     $                                  v(1,q), 1, cs, conjg(ompq)*t )
                                    END IF
                                    sva( q ) = aaqq*sqrt( max( zero,
     $                                         one+t*apoaq*aapq1 ) )
                                    aapp = aapp*sqrt( max( zero,
     $                                     one-t*aqoap*aapq1 ) )
                                    mxsinj = max( mxsinj, abs( t ) )
                                 ELSE
*
*                 .. choose correct signum for THETA and rotate
*
                                    thsign = -sign( one, aapq1 )
                                    IF( aaqq.GT.aapp0 )thsign = -thsign
                                    t = one / ( theta+thsign*
     $                                  sqrt( one+theta*theta ) )
                                    cs = sqrt( one / ( one+t*t ) )
                                    sn = t*cs
                                    mxsinj = max( mxsinj, abs( sn ) )
                                    sva( q ) = aaqq*sqrt( max( zero,
     $                                         one+t*apoaq*aapq1 ) )
                                    aapp = aapp*sqrt( max( zero,
     $                                         one-t*aqoap*aapq1 ) )
*
                                    CALL zrot( m, a(1,p), 1, a(1,q), 1,
     $                                          cs, conjg(ompq)*sn )
                                    IF( rsvec ) THEN
                                        CALL zrot( mvl, v(1,p), 1,
     $                                  v(1,q), 1, cs, conjg(ompq)*sn )
                                    END IF
                                 END IF
                                 d(p) = -d(q) * ompq
*
                              ELSE
*              .. have to use modified Gram-Schmidt like transformation
                               IF( aapp.GT.aaqq ) THEN
                                    CALL zcopy( m, a( 1, p ), 1,
     $                                          work, 1 )
                                    CALL zlascl( 'G', 0, 0, aapp, one,
     $                                           m, 1, work,lda,
     $                                           ierr )
                                    CALL zlascl( 'G', 0, 0, aaqq, one,
     $                                           m, 1, a( 1, q ), lda,
     $                                           ierr )
                                    CALL zaxpy( m, -aapq, work,
     $                                          1, a( 1, q ), 1 )
                                    CALL zlascl( 'G', 0, 0, one, aaqq,
     $                                           m, 1, a( 1, q ), lda,
     $                                           ierr )
                                    sva( q ) = aaqq*sqrt( max( zero,
     $                                         one-aapq1*aapq1 ) )
                                    mxsinj = max( mxsinj, sfmin )
                               ELSE
                                   CALL zcopy( m, a( 1, q ), 1,
     $                                          work, 1 )
                                    CALL zlascl( 'G', 0, 0, aaqq, one,
     $                                           m, 1, work,lda,
     $                                           ierr )
                                    CALL zlascl( 'G', 0, 0, aapp, one,
     $                                           m, 1, a( 1, p ), lda,
     $                                           ierr )
                                    CALL zaxpy( m, -conjg(aapq),
     $                                   work, 1, a( 1, p ), 1 )
                                    CALL zlascl( 'G', 0, 0, one, aapp,
     $                                           m, 1, a( 1, p ), lda,
     $                                           ierr )
                                    sva( p ) = aapp*sqrt( max( zero,
     $                                         one-aapq1*aapq1 ) )
                                    mxsinj = max( mxsinj, sfmin )
                               END IF
                              END IF
*           END IF ROTOK THEN ... ELSE
*
*           In the case of cancellation in updating SVA(q), SVA(p)
*           .. recompute SVA(q), SVA(p)
                              IF( ( sva( q ) / aaqq )**2.LE.rooteps )
     $                            THEN
                                 IF( ( aaqq.LT.rootbig ) .AND.
     $                               ( aaqq.GT.rootsfmin ) ) THEN
                                    sva( q ) = dznrm2( m, a( 1, q ), 1)
                                  ELSE
                                    t = zero
                                    aaqq = one
                                    CALL zlassq( m, a( 1, q ), 1, t,
     $                                           aaqq )
                                    sva( q ) = t*sqrt( aaqq )
                                 END IF
                              END IF
                              IF( ( aapp / aapp0 )**2.LE.rooteps ) THEN
                                 IF( ( aapp.LT.rootbig ) .AND.
     $                               ( aapp.GT.rootsfmin ) ) THEN
                                    aapp = dznrm2( m, a( 1, p ), 1 )
                                 ELSE
                                    t = zero
                                    aapp = one
                                    CALL zlassq( m, a( 1, p ), 1, t,
     $                                           aapp )
                                    aapp = t*sqrt( aapp )
                                 END IF
                                 sva( p ) = aapp
                              END IF
*              end of OK rotation
                           ELSE
                              notrot = notrot + 1
*[RTD]      SKIPPED  = SKIPPED  + 1
                              pskipped = pskipped + 1
                              ijblsk = ijblsk + 1
                           END IF
                        ELSE
                           notrot = notrot + 1
                           pskipped = pskipped + 1
                           ijblsk = ijblsk + 1
                        END IF
*
                        IF( ( i.LE.swband ) .AND. ( ijblsk.GE.blskip ) )
     $                      THEN
                           sva( p ) = aapp
                           notrot = 0
                           GO TO 2011
                        END IF
                        IF( ( i.LE.swband ) .AND.
     $                      ( pskipped.GT.rowskip ) ) THEN
                           aapp = -aapp
                           notrot = 0
                           GO TO 2203
                        END IF
*
 2200                CONTINUE
*        end of the q-loop
 2203                CONTINUE
*
                     sva( p ) = aapp
*
                  ELSE
*
                     IF( aapp.EQ.zero )notrot = notrot +
     $                   min( jgl+kbl-1, n ) - jgl + 1
                     IF( aapp.LT.zero )notrot = 0
*
                  END IF
*
 2100          CONTINUE
*     end of the p-loop
 2010       CONTINUE
*     end of the jbc-loop
 2011       CONTINUE
*2011 bailed out of the jbc-loop
            DO 2012 p = igl, min( igl+kbl-1, n )
               sva( p ) = abs( sva( p ) )
 2012       CONTINUE
***
 2000    CONTINUE
*2000 :: end of the ibr-loop
*
*     .. update SVA(N)
         IF( ( sva( n ).LT.rootbig ) .AND. ( sva( n ).GT.rootsfmin ) )
     $       THEN
            sva( n ) = dznrm2( m, a( 1, n ), 1 )
         ELSE
            t = zero
            aapp = one
            CALL zlassq( m, a( 1, n ), 1, t, aapp )
            sva( n ) = t*sqrt( aapp )
         END IF
*
*     Additional steering devices
*
         IF( ( i.LT.swband ) .AND. ( ( mxaapq.LE.roottol ) .OR.
     $       ( iswrot.LE.n ) ) )swband = i
*
         IF( ( i.GT.swband+1 ) .AND. ( mxaapq.LT.sqrt( dble( n ) )*
     $       tol ) .AND. ( dble( n )*mxaapq*mxsinj.LT.tol ) ) THEN
            GO TO 1994
         END IF
*
         IF( notrot.GE.emptsw )GO TO 1994
*
 1993 CONTINUE
*     end i=1:NSWEEP loop
*
* #:( Reaching this point means that the procedure has not converged.
      info = nsweep - 1
      GO TO 1995
*
 1994 CONTINUE
* #:) Reaching this point means numerical convergence after the i-th
*     sweep.
*
      info = 0
* #:) INFO = 0 confirms successful iterations.
 1995 CONTINUE
*
*     Sort the vector SVA() of column norms.
      DO 5991 p = 1, n - 1
         q = idamax( n-p+1, sva( p ), 1 ) + p - 1
         IF( p.NE.q ) THEN
            temp1 = sva( p )
            sva( p ) = sva( q )
            sva( q ) = temp1
            aapq = d( p )
            d( p ) = d( q )
            d( q ) = aapq
            CALL zswap( m, a( 1, p ), 1, a( 1, q ), 1 )
            IF( rsvec )CALL zswap( mvl, v( 1, p ), 1, v( 1, q ), 1 )
         END IF
 5991 CONTINUE
*
*
      RETURN
*     ..
*     .. END OF ZGSVJ1
*     ..
      END