sorgrq()

subroutine sorgrq	(	integer	m,
		integer	n,
		integer	k,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( * )	work,
		integer	lwork,
		integer	info
	)

SORGRQ

Download SORGRQ + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SORGRQ generates an M-by-N real matrix Q with orthonormal rows,
 which is defined as the last M rows of a product of K elementary
 reflectors of order N

       Q  =  H(1) H(2) . . . H(k)

 as returned by SGERQF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q. N >= M.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the (m-k+i)-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by SGERQF in the last k rows of its array argument A. On exit, the M-by-N matrix Q.
[in]	LDA	LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).
[in]	TAU	TAU is REAL array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SGERQF.
[out]	WORK	WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,M). For optimum performance LWORK >= M*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 127 of file sorgrq.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, II, IINFO, IWS, J, KK, L, LDWORK,
     $                   LWKOPT, NB, NBMIN, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           slarfb, slarft, sorgr2, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
*
      IF( info.EQ.0 ) THEN
         IF( m.LE.0 ) THEN
            lwkopt = 1
         ELSE
            nb = ilaenv( 1, 'SORGRQ', ' ', m, n, k, -1 )
            lwkopt = m*nb
         END IF
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.max( 1, m ) .AND. .NOT.lquery ) THEN
            info = -8
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORGRQ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 ) THEN
         RETURN
      END IF
*
      nbmin = 2
      nx = 0
      iws = m
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'SORGRQ', ' ', m, n, k, -1 ) )
         IF( nx.LT.k ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = m
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'SORGRQ', ' ', m, n, k, -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
*
*        Use blocked code after the first block.
*        The last kk rows are handled by the block method.
*
         kk = min( k, ( ( k-nx+nb-1 ) / nb )*nb )
*
*        Set A(1:m-kk,n-kk+1:n) to zero.
*
         DO 20 j = n - kk + 1, n
            DO 10 i = 1, m - kk
               a( i, j ) = zero
   10       CONTINUE
   20    CONTINUE
      ELSE
         kk = 0
      END IF
*
*     Use unblocked code for the first or only block.
*
      CALL sorgr2( m-kk, n-kk, k-kk, a, lda, tau, work, iinfo )
*
      IF( kk.GT.0 ) THEN
*
*        Use blocked code
*
         DO 50 i = k - kk + 1, k, nb
            ib = min( nb, k-i+1 )
            ii = m - k + i
            IF( ii.GT.1 ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL slarft( 'Backward', 'Rowwise', n-k+i+ib-1, ib,
     $                      a( ii, 1 ), lda, tau( i ), work, ldwork )
*
*              Apply H**T to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
*
               CALL slarfb( 'Right', 'Transpose', 'Backward', 'Rowwise',
     $                      ii-1, n-k+i+ib-1, ib, a( ii, 1 ), lda, work,
     $                      ldwork, a, lda, work( ib+1 ), ldwork )
            END IF
*
*           Apply H**T to columns 1:n-k+i+ib-1 of current block
*
            CALL sorgr2( ib, n-k+i+ib-1, ib, a( ii, 1 ), lda, tau( i ),
     $                   work, iinfo )
*
*           Set columns n-k+i+ib:n of current block to zero
*
            DO 40 l = n - k + i + ib, n
               DO 30 j = ii, ii + ib - 1
                  a( j, l ) = zero
   30          CONTINUE
   40       CONTINUE
   50    CONTINUE
      END IF
*
      work( 1 ) = sroundup_lwork(iws)
      RETURN
*
*     End of SORGRQ
*

Here is the call graph for this function:

Here is the caller graph for this function: