LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zsytrf_rk()

subroutine zsytrf_rk ( character uplo,
integer n,
complex*16, dimension( lda, * ) a,
integer lda,
complex*16, dimension( * ) e,
integer, dimension( * ) ipiv,
complex*16, dimension( * ) work,
integer lwork,
integer info )

ZSYTRF_RK computes the factorization of a complex symmetric indefinite matrix using the bounded Bunch-Kaufman (rook) diagonal pivoting method (BLAS3 blocked algorithm).

Download ZSYTRF_RK + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!> ZSYTRF_RK computes the factorization of a complex symmetric matrix A
!> using the bounded Bunch-Kaufman (rook) diagonal pivoting method:
!>
!>    A = P*U*D*(U**T)*(P**T) or A = P*L*D*(L**T)*(P**T),
!>
!> where U (or L) is unit upper (or lower) triangular matrix,
!> U**T (or L**T) is the transpose of U (or L), P is a permutation
!> matrix, P**T is the transpose of P, and D is symmetric and block
!> diagonal with 1-by-1 and 2-by-2 diagonal blocks.
!>
!> This is the blocked version of the algorithm, calling Level 3 BLAS.
!> For more information see Further Details section.
!>
Parameters
[in]UPLO
!>          UPLO is CHARACTER*1
!>          Specifies whether the upper or lower triangular part of the
!>          symmetric matrix A is stored:
!>          = 'U':  Upper triangular
!>          = 'L':  Lower triangular
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in,out]A
!>          A is COMPLEX*16 array, dimension (LDA,N)
!>          On entry, the symmetric matrix A.
!>            If UPLO = 'U': the leading N-by-N upper triangular part
!>            of A contains the upper triangular part of the matrix A,
!>            and the strictly lower triangular part of A is not
!>            referenced.
!>
!>            If UPLO = 'L': the leading N-by-N lower triangular part
!>            of A contains the lower triangular part of the matrix A,
!>            and the strictly upper triangular part of A is not
!>            referenced.
!>
!>          On exit, contains:
!>            a) ONLY diagonal elements of the symmetric block diagonal
!>               matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
!>               (superdiagonal (or subdiagonal) elements of D
!>                are stored on exit in array E), and
!>            b) If UPLO = 'U': factor U in the superdiagonal part of A.
!>               If UPLO = 'L': factor L in the subdiagonal part of A.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[out]E
!>          E is COMPLEX*16 array, dimension (N)
!>          On exit, contains the superdiagonal (or subdiagonal)
!>          elements of the symmetric block diagonal matrix D
!>          with 1-by-1 or 2-by-2 diagonal blocks, where
!>          If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0;
!>          If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0.
!>
!>          NOTE: For 1-by-1 diagonal block D(k), where
!>          1 <= k <= N, the element E(k) is set to 0 in both
!>          UPLO = 'U' or UPLO = 'L' cases.
!>
[out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          IPIV describes the permutation matrix P in the factorization
!>          of matrix A as follows. The absolute value of IPIV(k)
!>          represents the index of row and column that were
!>          interchanged with the k-th row and column. The value of UPLO
!>          describes the order in which the interchanges were applied.
!>          Also, the sign of IPIV represents the block structure of
!>          the symmetric block diagonal matrix D with 1-by-1 or 2-by-2
!>          diagonal blocks which correspond to 1 or 2 interchanges
!>          at each factorization step. For more info see Further
!>          Details section.
!>
!>          If UPLO = 'U',
!>          ( in factorization order, k decreases from N to 1 ):
!>            a) A single positive entry IPIV(k) > 0 means:
!>               D(k,k) is a 1-by-1 diagonal block.
!>               If IPIV(k) != k, rows and columns k and IPIV(k) were
!>               interchanged in the matrix A(1:N,1:N);
!>               If IPIV(k) = k, no interchange occurred.
!>
!>            b) A pair of consecutive negative entries
!>               IPIV(k) < 0 and IPIV(k-1) < 0 means:
!>               D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
!>               (NOTE: negative entries in IPIV appear ONLY in pairs).
!>               1) If -IPIV(k) != k, rows and columns
!>                  k and -IPIV(k) were interchanged
!>                  in the matrix A(1:N,1:N).
!>                  If -IPIV(k) = k, no interchange occurred.
!>               2) If -IPIV(k-1) != k-1, rows and columns
!>                  k-1 and -IPIV(k-1) were interchanged
!>                  in the matrix A(1:N,1:N).
!>                  If -IPIV(k-1) = k-1, no interchange occurred.
!>
!>            c) In both cases a) and b), always ABS( IPIV(k) ) <= k.
!>
!>            d) NOTE: Any entry IPIV(k) is always NONZERO on output.
!>
!>          If UPLO = 'L',
!>          ( in factorization order, k increases from 1 to N ):
!>            a) A single positive entry IPIV(k) > 0 means:
!>               D(k,k) is a 1-by-1 diagonal block.
!>               If IPIV(k) != k, rows and columns k and IPIV(k) were
!>               interchanged in the matrix A(1:N,1:N).
!>               If IPIV(k) = k, no interchange occurred.
!>
!>            b) A pair of consecutive negative entries
!>               IPIV(k) < 0 and IPIV(k+1) < 0 means:
!>               D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
!>               (NOTE: negative entries in IPIV appear ONLY in pairs).
!>               1) If -IPIV(k) != k, rows and columns
!>                  k and -IPIV(k) were interchanged
!>                  in the matrix A(1:N,1:N).
!>                  If -IPIV(k) = k, no interchange occurred.
!>               2) If -IPIV(k+1) != k+1, rows and columns
!>                  k-1 and -IPIV(k-1) were interchanged
!>                  in the matrix A(1:N,1:N).
!>                  If -IPIV(k+1) = k+1, no interchange occurred.
!>
!>            c) In both cases a) and b), always ABS( IPIV(k) ) >= k.
!>
!>            d) NOTE: Any entry IPIV(k) is always NONZERO on output.
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension ( MAX(1,LWORK) ).
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of WORK.  LWORK >=1.  For best performance
!>          LWORK >= N*NB, where NB is the block size returned
!>          by ILAENV.
!>
!>          If LWORK = -1, then a workspace query is assumed;
!>          the routine only calculates the optimal size of the WORK
!>          array, returns this value as the first entry of the WORK
!>          array, and no error message related to LWORK is issued
!>          by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0: successful exit
!>
!>          < 0: If INFO = -k, the k-th argument had an illegal value
!>
!>          > 0: If INFO = k, the matrix A is singular, because:
!>                 If UPLO = 'U': column k in the upper
!>                 triangular part of A contains all zeros.
!>                 If UPLO = 'L': column k in the lower
!>                 triangular part of A contains all zeros.
!>
!>               Therefore D(k,k) is exactly zero, and superdiagonal
!>               elements of column k of U (or subdiagonal elements of
!>               column k of L ) are all zeros. The factorization has
!>               been completed, but the block diagonal matrix D is
!>               exactly singular, and division by zero will occur if
!>               it is used to solve a system of equations.
!>
!>               NOTE: INFO only stores the first occurrence of
!>               a singularity, any subsequent occurrence of singularity
!>               is not stored in INFO even though the factorization
!>               always completes.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!> TODO: put correct description
!>
Contributors:
!>
!>  December 2016,  Igor Kozachenko,
!>                  Computer Science Division,
!>                  University of California, Berkeley
!>
!>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
!>                  School of Mathematics,
!>                  University of Manchester
!>
!>

Definition at line 255 of file zsytrf_rk.f.

257*
258* -- LAPACK computational routine --
259* -- LAPACK is a software package provided by Univ. of Tennessee, --
260* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
261*
262* .. Scalar Arguments ..
263 CHARACTER UPLO
264 INTEGER INFO, LDA, LWORK, N
265* ..
266* .. Array Arguments ..
267 INTEGER IPIV( * )
268 COMPLEX*16 A( LDA, * ), E( * ), WORK( * )
269* ..
270*
271* =====================================================================
272*
273* .. Local Scalars ..
274 LOGICAL LQUERY, UPPER
275 INTEGER I, IINFO, IP, IWS, K, KB, LDWORK, LWKOPT,
276 $ NB, NBMIN
277* ..
278* .. External Functions ..
279 LOGICAL LSAME
280 INTEGER ILAENV
281 EXTERNAL lsame, ilaenv
282* ..
283* .. External Subroutines ..
284 EXTERNAL zlasyf_rk, zsytf2_rk, zswap, xerbla
285* ..
286* .. Intrinsic Functions ..
287 INTRINSIC abs, max
288* ..
289* .. Executable Statements ..
290*
291* Test the input parameters.
292*
293 info = 0
294 upper = lsame( uplo, 'U' )
295 lquery = ( lwork.EQ.-1 )
296 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
297 info = -1
298 ELSE IF( n.LT.0 ) THEN
299 info = -2
300 ELSE IF( lda.LT.max( 1, n ) ) THEN
301 info = -4
302 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
303 info = -8
304 END IF
305*
306 IF( info.EQ.0 ) THEN
307*
308* Determine the block size
309*
310 nb = ilaenv( 1, 'ZSYTRF_RK', uplo, n, -1, -1, -1 )
311 lwkopt = max( 1, n*nb )
312 work( 1 ) = lwkopt
313 END IF
314*
315 IF( info.NE.0 ) THEN
316 CALL xerbla( 'ZSYTRF_RK', -info )
317 RETURN
318 ELSE IF( lquery ) THEN
319 RETURN
320 END IF
321*
322 nbmin = 2
323 ldwork = n
324 IF( nb.GT.1 .AND. nb.LT.n ) THEN
325 iws = ldwork*nb
326 IF( lwork.LT.iws ) THEN
327 nb = max( lwork / ldwork, 1 )
328 nbmin = max( 2, ilaenv( 2, 'ZSYTRF_RK',
329 $ uplo, n, -1, -1, -1 ) )
330 END IF
331 ELSE
332 iws = 1
333 END IF
334 IF( nb.LT.nbmin )
335 $ nb = n
336*
337 IF( upper ) THEN
338*
339* Factorize A as U*D*U**T using the upper triangle of A
340*
341* K is the main loop index, decreasing from N to 1 in steps of
342* KB, where KB is the number of columns factorized by ZLASYF_RK;
343* KB is either NB or NB-1, or K for the last block
344*
345 k = n
346 10 CONTINUE
347*
348* If K < 1, exit from loop
349*
350 IF( k.LT.1 )
351 $ GO TO 15
352*
353 IF( k.GT.nb ) THEN
354*
355* Factorize columns k-kb+1:k of A and use blocked code to
356* update columns 1:k-kb
357*
358 CALL zlasyf_rk( uplo, k, nb, kb, a, lda, e,
359 $ ipiv, work, ldwork, iinfo )
360 ELSE
361*
362* Use unblocked code to factorize columns 1:k of A
363*
364 CALL zsytf2_rk( uplo, k, a, lda, e, ipiv, iinfo )
365 kb = k
366 END IF
367*
368* Set INFO on the first occurrence of a zero pivot
369*
370 IF( info.EQ.0 .AND. iinfo.GT.0 )
371 $ info = iinfo
372*
373* No need to adjust IPIV
374*
375*
376* Apply permutations to the leading panel 1:k-1
377*
378* Read IPIV from the last block factored, i.e.
379* indices k-kb+1:k and apply row permutations to the
380* last k+1 colunms k+1:N after that block
381* (We can do the simple loop over IPIV with decrement -1,
382* since the ABS value of IPIV( I ) represents the row index
383* of the interchange with row i in both 1x1 and 2x2 pivot cases)
384*
385 IF( k.LT.n ) THEN
386 DO i = k, ( k - kb + 1 ), -1
387 ip = abs( ipiv( i ) )
388 IF( ip.NE.i ) THEN
389 CALL zswap( n-k, a( i, k+1 ), lda,
390 $ a( ip, k+1 ), lda )
391 END IF
392 END DO
393 END IF
394*
395* Decrease K and return to the start of the main loop
396*
397 k = k - kb
398 GO TO 10
399*
400* This label is the exit from main loop over K decreasing
401* from N to 1 in steps of KB
402*
403 15 CONTINUE
404*
405 ELSE
406*
407* Factorize A as L*D*L**T using the lower triangle of A
408*
409* K is the main loop index, increasing from 1 to N in steps of
410* KB, where KB is the number of columns factorized by ZLASYF_RK;
411* KB is either NB or NB-1, or N-K+1 for the last block
412*
413 k = 1
414 20 CONTINUE
415*
416* If K > N, exit from loop
417*
418 IF( k.GT.n )
419 $ GO TO 35
420*
421 IF( k.LE.n-nb ) THEN
422*
423* Factorize columns k:k+kb-1 of A and use blocked code to
424* update columns k+kb:n
425*
426 CALL zlasyf_rk( uplo, n-k+1, nb, kb, a( k, k ), lda,
427 $ e( k ),
428 $ ipiv( k ), work, ldwork, iinfo )
429
430
431 ELSE
432*
433* Use unblocked code to factorize columns k:n of A
434*
435 CALL zsytf2_rk( uplo, n-k+1, a( k, k ), lda, e( k ),
436 $ ipiv( k ), iinfo )
437 kb = n - k + 1
438*
439 END IF
440*
441* Set INFO on the first occurrence of a zero pivot
442*
443 IF( info.EQ.0 .AND. iinfo.GT.0 )
444 $ info = iinfo + k - 1
445*
446* Adjust IPIV
447*
448 DO i = k, k + kb - 1
449 IF( ipiv( i ).GT.0 ) THEN
450 ipiv( i ) = ipiv( i ) + k - 1
451 ELSE
452 ipiv( i ) = ipiv( i ) - k + 1
453 END IF
454 END DO
455*
456* Apply permutations to the leading panel 1:k-1
457*
458* Read IPIV from the last block factored, i.e.
459* indices k:k+kb-1 and apply row permutations to the
460* first k-1 colunms 1:k-1 before that block
461* (We can do the simple loop over IPIV with increment 1,
462* since the ABS value of IPIV( I ) represents the row index
463* of the interchange with row i in both 1x1 and 2x2 pivot cases)
464*
465 IF( k.GT.1 ) THEN
466 DO i = k, ( k + kb - 1 ), 1
467 ip = abs( ipiv( i ) )
468 IF( ip.NE.i ) THEN
469 CALL zswap( k-1, a( i, 1 ), lda,
470 $ a( ip, 1 ), lda )
471 END IF
472 END DO
473 END IF
474*
475* Increase K and return to the start of the main loop
476*
477 k = k + kb
478 GO TO 20
479*
480* This label is the exit from main loop over K increasing
481* from 1 to N in steps of KB
482*
483 35 CONTINUE
484*
485* End Lower
486*
487 END IF
488*
489 work( 1 ) = lwkopt
490 RETURN
491*
492* End of ZSYTRF_RK
493*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zsytf2_rk
subroutine zsytf2_rk(uplo, n, a, lda, e, ipiv, info)
ZSYTF2_RK computes the factorization of a complex symmetric indefinite matrix using the bounded Bunch...
Definition zsytf2_rk.f:239
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
zlasyf_rk
subroutine zlasyf_rk(uplo, n, nb, kb, a, lda, e, ipiv, w, ldw, info)
ZLASYF_RK computes a partial factorization of a complex symmetric indefinite matrix using bounded Bun...
Definition zlasyf_rk.f:260
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
zswap
subroutine zswap(n, zx, incx, zy, incy)
ZSWAP
Definition zswap.f:81
Here is the call graph for this function:
Here is the caller graph for this function: