dormr3()

subroutine dormr3	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		integer	l,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( * )	work,
		integer	info )

DORMR3 multiplies a general matrix by the orthogonal matrix from a RZ factorization determined by stzrzf (unblocked algorithm).

Download DORMR3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DORMR3 overwrites the general real m by n matrix C with
!>
!>       Q * C  if SIDE = 'L' and TRANS = 'N', or
!>
!>       Q**T* C  if SIDE = 'L' and TRANS = 'C', or
!>
!>       C * Q  if SIDE = 'R' and TRANS = 'N', or
!>
!>       C * Q**T if SIDE = 'R' and TRANS = 'C',
!>
!> where Q is a real orthogonal matrix defined as the product of k
!> elementary reflectors
!>
!>       Q = H(1) H(2) . . . H(k)
!>
!> as returned by DTZRZF. Q is of order m if SIDE = 'L' and of order n
!> if SIDE = 'R'.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**T from the Left !> = 'R': apply Q or Q**T from the Right !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': apply Q (No transpose) !> = 'T': apply Q**T (Transpose) !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines !> the matrix Q. !> If SIDE = 'L', M >= K >= 0; !> if SIDE = 'R', N >= K >= 0. !>
[in]	L	!> L is INTEGER !> The number of columns of the matrix A containing !> the meaningful part of the Householder reflectors. !> If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension !> (LDA,M) if SIDE = 'L', !> (LDA,N) if SIDE = 'R' !> The i-th row must contain the vector which defines the !> elementary reflector H(i), for i = 1,2,...,k, as returned by !> DTZRZF in the last k rows of its array argument A. !> A is modified by the routine but restored on exit. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,K). !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by DTZRZF. !>
[in,out]	C	!> C is DOUBLE PRECISION array, dimension (LDC,N) !> On entry, the m-by-n matrix C. !> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension !> (N) if SIDE = 'L', !> (M) if SIDE = 'R' !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Further Details:

!> 

Definition at line 174 of file dormr3.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, K, L, LDA, LDC, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LEFT, NOTRAN
      INTEGER            I, I1, I2, I3, IC, JA, JC, MI, NI, NQ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlarz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
*
*     NQ is the order of Q
*
      IF( left ) THEN
         nq = m
      ELSE
         nq = n
      END IF
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
         info = -5
      ELSE IF( l.LT.0 .OR. ( left .AND. ( l.GT.m ) ) .OR.
     $         ( .NOT.left .AND. ( l.GT.n ) ) ) THEN
         info = -6
      ELSE IF( lda.LT.max( 1, k ) ) THEN
         info = -8
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DORMR3', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      IF( ( left .AND. .NOT.notran .OR. .NOT.left .AND. notran ) ) THEN
         i1 = 1
         i2 = k
         i3 = 1
      ELSE
         i1 = k
         i2 = 1
         i3 = -1
      END IF
*
      IF( left ) THEN
         ni = n
         ja = m - l + 1
         jc = 1
      ELSE
         mi = m
         ja = n - l + 1
         ic = 1
      END IF
*
      DO 10 i = i1, i2, i3
         IF( left ) THEN
*
*           H(i) or H(i)**T is applied to C(i:m,1:n)
*
            mi = m - i + 1
            ic = i
         ELSE
*
*           H(i) or H(i)**T is applied to C(1:m,i:n)
*
            ni = n - i + 1
            jc = i
         END IF
*
*        Apply H(i) or H(i)**T
*
         CALL dlarz( side, mi, ni, l, a( i, ja ), lda, tau( i ),
     $               c( ic, jc ), ldc, work )
*
   10 CONTINUE
*
      RETURN
*
*     End of DORMR3
*

Here is the call graph for this function:

Here is the caller graph for this function: