zungl2()

subroutine zungl2	(	integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		integer	info )

ZUNGL2 generates all or part of the unitary matrix Q from an LQ factorization determined by cgelqf (unblocked algorithm).

Download ZUNGL2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZUNGL2 generates an m-by-n complex matrix Q with orthonormal rows,
!> which is defined as the first m rows of a product of k elementary
!> reflectors of order n
!>
!>       Q  =  H(k)**H . . . H(2)**H H(1)**H
!>
!> as returned by ZGELQF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q. N >= M. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. M >= K >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the i-th row must contain the vector which defines !> the elementary reflector H(i), for i = 1,2,...,k, as returned !> by ZGELQF in the first k rows of its array argument A. !> On exit, the m by n matrix Q. !>
[in]	LDA	!> LDA is INTEGER !> The first dimension of the array A. LDA >= max(1,M). !>
[in]	TAU	!> TAU is COMPLEX*16 array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by ZGELQF. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (M) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument has an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 110 of file zungl2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlacgv, zlarf1f, zscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dconjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZUNGL2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      IF( k.LT.m ) THEN
*
*        Initialise rows k+1:m to rows of the unit matrix
*
         DO 20 j = 1, n
            DO 10 l = k + 1, m
               a( l, j ) = zero
   10       CONTINUE
            IF( j.GT.k .AND. j.LE.m )
     $         a( j, j ) = one
   20    CONTINUE
      END IF
*
      DO 40 i = k, 1, -1
*
*        Apply H(i)**H to A(i:m,i:n) from the right
*
         IF( i.LT.n ) THEN
            CALL zlacgv( n-i, a( i, i+1 ), lda )
            IF( i.LT.m ) THEN
               CALL zlarf1f( 'Right', m-i, n-i+1, a( i, i ), lda,
     $                       conjg( tau( i ) ), a( i+1, i ), lda,
     $                       work )
            END IF
            CALL zscal( n-i, -tau( i ), a( i, i+1 ), lda )
            CALL zlacgv( n-i, a( i, i+1 ), lda )
         END IF
         a( i, i ) = one - dconjg( tau( i ) )
*
*        Set A(i,1:i-1) to zero
*
         DO 30 l = 1, i - 1
            a( i, l ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of ZUNGL2
*

Here is the call graph for this function:

Here is the caller graph for this function: