slasd8()

subroutine slasd8	(	integer	icompq,
		integer	k,
		real, dimension( * )	d,
		real, dimension( * )	z,
		real, dimension( * )	vf,
		real, dimension( * )	vl,
		real, dimension( * )	difl,
		real, dimension( lddifr, * )	difr,
		integer	lddifr,
		real, dimension( * )	dsigma,
		real, dimension( * )	work,
		integer	info
	)

SLASD8 finds the square roots of the roots of the secular equation, and stores, for each element in D, the distance to its two nearest poles. Used by sbdsdc.

Download SLASD8 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLASD8 finds the square roots of the roots of the secular equation,
 as defined by the values in DSIGMA and Z. It makes the appropriate
 calls to SLASD4, and stores, for each  element in D, the distance
 to its two nearest poles (elements in DSIGMA). It also updates
 the arrays VF and VL, the first and last components of all the
 right singular vectors of the original bidiagonal matrix.

 SLASD8 is called from SLASD6.

Parameters

[in]	ICOMPQ	ICOMPQ is INTEGER Specifies whether singular vectors are to be computed in factored form in the calling routine: = 0: Compute singular values only. = 1: Compute singular vectors in factored form as well.
[in]	K	K is INTEGER The number of terms in the rational function to be solved by SLASD4. K >= 1.
[out]	D	D is REAL array, dimension ( K ) On output, D contains the updated singular values.
[in,out]	Z	Z is REAL array, dimension ( K ) On entry, the first K elements of this array contain the components of the deflation-adjusted updating row vector. On exit, Z is updated.
[in,out]	VF	VF is REAL array, dimension ( K ) On entry, VF contains information passed through DBEDE8. On exit, VF contains the first K components of the first components of all right singular vectors of the bidiagonal matrix.
[in,out]	VL	VL is REAL array, dimension ( K ) On entry, VL contains information passed through DBEDE8. On exit, VL contains the first K components of the last components of all right singular vectors of the bidiagonal matrix.
[out]	DIFL	DIFL is REAL array, dimension ( K ) On exit, DIFL(I) = D(I) - DSIGMA(I).
[out]	DIFR	DIFR is REAL array, dimension ( LDDIFR, 2 ) if ICOMPQ = 1 and dimension ( K ) if ICOMPQ = 0. On exit, DIFR(I,1) = D(I) - DSIGMA(I+1), DIFR(K,1) is not defined and will not be referenced. If ICOMPQ = 1, DIFR(1:K,2) is an array containing the normalizing factors for the right singular vector matrix.
[in]	LDDIFR	LDDIFR is INTEGER The leading dimension of DIFR, must be at least K.
[in]	DSIGMA	DSIGMA is REAL array, dimension ( K ) On entry, the first K elements of this array contain the old roots of the deflated updating problem. These are the poles of the secular equation.
[out]	WORK	WORK is REAL array, dimension (3*K)
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, a singular value did not converge

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 162 of file slasd8.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            ICOMPQ, INFO, K, LDDIFR
*     ..
*     .. Array Arguments ..
      REAL               D( * ), DIFL( * ), DIFR( LDDIFR, * ),
     $                   DSIGMA( * ), VF( * ), VL( * ), WORK( * ),
     $                   Z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IWK1, IWK2, IWK2I, IWK3, IWK3I, J
      REAL               DIFLJ, DIFRJ, DJ, DSIGJ, DSIGJP, RHO, TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           scopy, slascl, slasd4, slaset, xerbla
*     ..
*     .. External Functions ..
      REAL               SDOT, SLAMC3, SNRM2
      EXTERNAL           sdot, slamc3, snrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sign, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( ( icompq.LT.0 ) .OR. ( icompq.GT.1 ) ) THEN
         info = -1
      ELSE IF( k.LT.1 ) THEN
         info = -2
      ELSE IF( lddifr.LT.k ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLASD8', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( k.EQ.1 ) THEN
         d( 1 ) = abs( z( 1 ) )
         difl( 1 ) = d( 1 )
         IF( icompq.EQ.1 ) THEN
            difl( 2 ) = one
            difr( 1, 2 ) = one
         END IF
         RETURN
      END IF
*
*     Book keeping.
*
      iwk1 = 1
      iwk2 = iwk1 + k
      iwk3 = iwk2 + k
      iwk2i = iwk2 - 1
      iwk3i = iwk3 - 1
*
*     Normalize Z.
*
      rho = snrm2( k, z, 1 )
      CALL slascl( 'G', 0, 0, rho, one, k, 1, z, k, info )
      rho = rho*rho
*
*     Initialize WORK(IWK3).
*
      CALL slaset( 'A', k, 1, one, one, work( iwk3 ), k )
*
*     Compute the updated singular values, the arrays DIFL, DIFR,
*     and the updated Z.
*
      DO 40 j = 1, k
         CALL slasd4( k, j, dsigma, z, work( iwk1 ), rho, d( j ),
     $                work( iwk2 ), info )
*
*        If the root finder fails, report the convergence failure.
*
         IF( info.NE.0 ) THEN
            RETURN
         END IF
         work( iwk3i+j ) = work( iwk3i+j )*work( j )*work( iwk2i+j )
         difl( j ) = -work( j )
         difr( j, 1 ) = -work( j+1 )
         DO 20 i = 1, j - 1
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   20    CONTINUE
         DO 30 i = j + 1, k
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   30    CONTINUE
   40 CONTINUE
*
*     Compute updated Z.
*
      DO 50 i = 1, k
         z( i ) = sign( sqrt( abs( work( iwk3i+i ) ) ), z( i ) )
   50 CONTINUE
*
*     Update VF and VL.
*
      DO 80 j = 1, k
         diflj = difl( j )
         dj = d( j )
         dsigj = -dsigma( j )
         IF( j.LT.k ) THEN
            difrj = -difr( j, 1 )
            dsigjp = -dsigma( j+1 )
         END IF
         work( j ) = -z( j ) / diflj / ( dsigma( j )+dj )
*
*        Use calls to the subroutine SLAMC3 to enforce the parentheses
*        (x+y)+z. The goal is to prevent optimizing compilers
*        from doing x+(y+z).
*
         DO 60 i = 1, j - 1
            work( i ) = z( i ) / ( slamc3( dsigma( i ), dsigj )-diflj )
     $                   / ( dsigma( i )+dj )
   60    CONTINUE
         DO 70 i = j + 1, k
            work( i ) = z( i ) / ( slamc3( dsigma( i ), dsigjp )+difrj )
     $                   / ( dsigma( i )+dj )
   70    CONTINUE
         temp = snrm2( k, work, 1 )
         work( iwk2i+j ) = sdot( k, work, 1, vf, 1 ) / temp
         work( iwk3i+j ) = sdot( k, work, 1, vl, 1 ) / temp
         IF( icompq.EQ.1 ) THEN
            difr( j, 2 ) = temp
         END IF
   80 CONTINUE
*
      CALL scopy( k, work( iwk2 ), 1, vf, 1 )
      CALL scopy( k, work( iwk3 ), 1, vl, 1 )
*
      RETURN
*
*     End of SLASD8
*

Here is the call graph for this function:

Here is the caller graph for this function: