zstt21()

subroutine zstt21	(	integer	n,
		integer	kband,
		double precision, dimension( * )	ad,
		double precision, dimension( * )	ae,
		double precision, dimension( * )	sd,
		double precision, dimension( * )	se,
		complex*16, dimension( ldu, * )	u,
		integer	ldu,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		double precision, dimension( 2 )	result )

ZSTT21

Purpose:

!>
!> ZSTT21  checks a decomposition of the form
!>
!>    A = U S U**H
!>
!> where **H means conjugate transpose, A is real symmetric tridiagonal,
!> U is unitary, and S is real and diagonal (if KBAND=0) or symmetric
!> tridiagonal (if KBAND=1).  Two tests are performed:
!>
!>    RESULT(1) = | A - U S U**H | / ( |A| n ulp )
!>
!>    RESULT(2) = | I - U U**H | / ( n ulp )
!> 

Parameters

[in]	N	!> N is INTEGER !> The size of the matrix. If it is zero, ZSTT21 does nothing. !> It must be at least zero. !>
[in]	KBAND	!> KBAND is INTEGER !> The bandwidth of the matrix S. It may only be zero or one. !> If zero, then S is diagonal, and SE is not referenced. If !> one, then S is symmetric tri-diagonal. !>
[in]	AD	!> AD is DOUBLE PRECISION array, dimension (N) !> The diagonal of the original (unfactored) matrix A. A is !> assumed to be real symmetric tridiagonal. !>
[in]	AE	!> AE is DOUBLE PRECISION array, dimension (N-1) !> The off-diagonal of the original (unfactored) matrix A. A !> is assumed to be symmetric tridiagonal. AE(1) is the (1,2) !> and (2,1) element, AE(2) is the (2,3) and (3,2) element, etc. !>
[in]	SD	!> SD is DOUBLE PRECISION array, dimension (N) !> The diagonal of the real (symmetric tri-) diagonal matrix S. !>
[in]	SE	!> SE is DOUBLE PRECISION array, dimension (N-1) !> The off-diagonal of the (symmetric tri-) diagonal matrix S. !> Not referenced if KBSND=0. If KBAND=1, then AE(1) is the !> (1,2) and (2,1) element, SE(2) is the (2,3) and (3,2) !> element, etc. !>
[in]	U	!> U is COMPLEX*16 array, dimension (LDU, N) !> The unitary matrix in the decomposition. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of U. LDU must be at least N. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (N**2) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (2) !> The values computed by the two tests described above. The !> values are currently limited to 1/ulp, to avoid overflow. !> RESULT(1) is always modified. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 131 of file zstt21.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KBAND, LDU, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AD( * ), AE( * ), RESULT( 2 ), RWORK( * ),
     $                   SD( * ), SE( * )
      COMPLEX*16         U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      DOUBLE PRECISION   ANORM, TEMP1, TEMP2, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANHE
      EXTERNAL           dlamch, zlange, zlanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zher, zher2, zlaset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     1)      Constants
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Precision' )
*
*     Do Test 1
*
*     Copy A & Compute its 1-Norm:
*
      CALL zlaset( 'Full', n, n, czero, czero, work, n )
*
      anorm = zero
      temp1 = zero
*
      DO 10 j = 1, n - 1
         work( ( n+1 )*( j-1 )+1 ) = ad( j )
         work( ( n+1 )*( j-1 )+2 ) = ae( j )
         temp2 = abs( ae( j ) )
         anorm = max( anorm, abs( ad( j ) )+temp1+temp2 )
         temp1 = temp2
   10 CONTINUE
*
      work( n**2 ) = ad( n )
      anorm = max( anorm, abs( ad( n ) )+temp1, unfl )
*
*     Norm of A - USU*
*
      DO 20 j = 1, n
         CALL zher( 'L', n, -sd( j ), u( 1, j ), 1, work, n )
   20 CONTINUE
*
      IF( n.GT.1 .AND. kband.EQ.1 ) THEN
         DO 30 j = 1, n - 1
            CALL zher2( 'L', n, -dcmplx( se( j ) ), u( 1, j ), 1,
     $                  u( 1, j+1 ), 1, work, n )
   30    CONTINUE
      END IF
*
      wnorm = zlanhe( '1', 'L', n, work, n, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U U**H - I
*
      CALL zgemm( 'N', 'C', n, n, n, cone, u, ldu, u, ldu, czero, work,
     $            n )
*
      DO 40 j = 1, n
         work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - cone
   40 CONTINUE
*
      result( 2 ) = min( dble( n ), zlange( '1', n, n, work, n,
     $              rwork ) ) / ( n*ulp )
*
      RETURN
*
*     End of ZSTT21
*

Here is the call graph for this function:

Here is the caller graph for this function: