sqlt01()

subroutine sqlt01	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		real, dimension( lda, * )	af,
		real, dimension( lda, * )	q,
		real, dimension( lda, * )	l,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result )

SQLT01

Purpose:

!>
!> SQLT01 tests SGEQLF, which computes the QL factorization of an m-by-n
!> matrix A, and partially tests SORGQL which forms the m-by-m
!> orthogonal matrix Q.
!>
!> SQLT01 compares L with Q'*A, and checks that Q is orthogonal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The m-by-n matrix A. !>
[out]	AF	!> AF is REAL array, dimension (LDA,N) !> Details of the QL factorization of A, as returned by SGEQLF. !> See SGEQLF for further details. !>
[out]	Q	!> Q is REAL array, dimension (LDA,M) !> The m-by-m orthogonal matrix Q. !>
[out]	L	!> L is REAL array, dimension (LDA,max(M,N)) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and R. !> LDA >= max(M,N). !>
[out]	TAU	!> TAU is REAL array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors, as returned !> by SGEQLF. !>
[out]	WORK	!> WORK is REAL array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is REAL array, dimension (M) !>
[out]	RESULT	!> RESULT is REAL array, dimension (2) !> The test ratios: !> RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) !> RESULT(2) = norm( I - Q'*Q ) / ( M * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file sqlt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               ROGUE
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE, SLANSY
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, sgeqlf, slacpy, slaset, sorgql, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL slacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'SGEQLF'
      CALL sgeqlf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL slaset( 'Full', m, m, rogue, rogue, q, lda )
      IF( m.GE.n ) THEN
         IF( n.LT.m .AND. n.GT.0 )
     $      CALL slacpy( 'Full', m-n, n, af, lda, q( 1, m-n+1 ), lda )
         IF( n.GT.1 )
     $      CALL slacpy( 'Upper', n-1, n-1, af( m-n+1, 2 ), lda,
     $                   q( m-n+1, m-n+2 ), lda )
      ELSE
         IF( m.GT.1 )
     $      CALL slacpy( 'Upper', m-1, m-1, af( 1, n-m+2 ), lda,
     $                   q( 1, 2 ), lda )
      END IF
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'SORGQL'
      CALL sorgql( m, m, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL slaset( 'Full', m, n, zero, zero, l, lda )
      IF( m.GE.n ) THEN
         IF( n.GT.0 )
     $      CALL slacpy( 'Lower', n, n, af( m-n+1, 1 ), lda,
     $                   l( m-n+1, 1 ), lda )
      ELSE
         IF( n.GT.m .AND. m.GT.0 )
     $      CALL slacpy( 'Full', m, n-m, af, lda, l, lda )
         IF( m.GT.0 )
     $      CALL slacpy( 'Lower', m, m, af( 1, n-m+1 ), lda,
     $                   l( 1, n-m+1 ), lda )
      END IF
*
*     Compute L - Q'*A
*
      CALL sgemm( 'Transpose', 'No transpose', m, n, m, -one, q, lda, a,
     $            lda, one, l, lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = slange( '1', m, n, a, lda, rwork )
      resid = slange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL slaset( 'Full', m, m, zero, one, l, lda )
      CALL ssyrk( 'Upper', 'Transpose', m, m, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = slansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of SQLT01
*

Here is the call graph for this function:

Here is the caller graph for this function: