zlamtsqr.f

Go to the documentation of this file.

*> \brief \b ZLAMTSQR
*
*  Definition:
*  ===========
*
*      SUBROUTINE ZLAMTSQR( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
*     $                     LDT, C, LDC, WORK, LWORK, INFO )
*
*
*     .. Scalar Arguments ..
*      CHARACTER         SIDE, TRANS
*      INTEGER           INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
*     ..
*     .. Array Arguments ..
*      COMPLEX*16        A( LDA, * ), WORK( * ), C(LDC, * ),
*     $                  T( LDT, * )
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>      ZLAMTSQR overwrites the general complex M-by-N matrix C with
*>
*>
*>                 SIDE = 'L'     SIDE = 'R'
*> TRANS = 'N':      Q * C          C * Q
*> TRANS = 'C':      Q**H * C       C * Q**H
*>      where Q is a complex unitary matrix defined as the product
*>      of blocked elementary reflectors computed by tall skinny
*>      QR factorization (ZLATSQR)
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SIDE
*> \verbatim
*>          SIDE is CHARACTER*1
*>          = 'L': apply Q or Q**H from the Left;
*>          = 'R': apply Q or Q**H from the Right.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N':  No transpose, apply Q;
*>          = 'C':  Conjugate Transpose, apply Q**H.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >=0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix C. N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines
*>          the matrix Q. M >= K >= 0;
*>
*> \endverbatim
*>
*> \param[in] MB
*> \verbatim
*>          MB is INTEGER
*>          The block size to be used in the blocked QR.
*>          MB > N. (must be the same as ZLATSQR)
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          The column block size to be used in the blocked QR.
*>          N >= NB >= 1.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,K)
*>          The i-th column must contain the vector which defines the
*>          blockedelementary reflector H(i), for i = 1,2,...,k, as
*>          returned by ZLATSQR in the first k columns of
*>          its array argument A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*>          If SIDE = 'L', LDA >= max(1,M);
*>          if SIDE = 'R', LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] T
*> \verbatim
*>          T is COMPLEX*16 array, dimension
*>          ( N * Number of blocks(CEIL(M-K/MB-K)),
*>          The blocked upper triangular block reflectors stored in compact form
*>          as a sequence of upper triangular blocks.  See below
*>          for further details.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of the array T.  LDT >= NB.
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is COMPLEX*16 array, dimension (LDC,N)
*>          On entry, the M-by-N matrix C.
*>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C. LDC >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>         (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
*>
*> \endverbatim
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>
*>          If SIDE = 'L', LWORK >= max(1,N)*NB;
*>          if SIDE = 'R', LWORK >= max(1,MB)*NB.
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*>
*> \endverbatim
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*> Tall-Skinny QR (TSQR) performs QR by a sequence of unitary transformations,
*> representing Q as a product of other unitary matrices
*>   Q = Q(1) * Q(2) * . . . * Q(k)
*> where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
*>   Q(1) zeros out the subdiagonal entries of rows 1:MB of A
*>   Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
*>   Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
*>   . . .
*>
*> Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
*> stored under the diagonal of rows 1:MB of A, and by upper triangular
*> block reflectors, stored in array T(1:LDT,1:N).
*> For more information see Further Details in GEQRT.
*>
*> Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
*> stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
*> block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
*> The last Q(k) may use fewer rows.
*> For more information see Further Details in TPQRT.
*>
*> For more details of the overall algorithm, see the description of
*> Sequential TSQR in Section 2.2 of [1].
*>
*> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
*>     J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
*>     SIAM J. Sci. Comput, vol. 34, no. 1, 2012
*> \endverbatim
*>
*> \ingroup lamtsqr
*>
*  =====================================================================
      SUBROUTINE zlamtsqr( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
     $        LDT, C, LDC, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER         SIDE, TRANS
      INTEGER           INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
*     ..
*     .. Array Arguments ..
      COMPLEX*16        A( LDA, * ), WORK( * ), C(LDC, * ),
     $                t( ldt, * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL    LEFT, RIGHT, TRAN, NOTRAN, LQUERY
      INTEGER    I, II, KK, LW, CTR, Q
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     .. External Subroutines ..
      EXTERNAL   zgemqrt, ztpmqrt, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      lquery  = lwork.LT.0
      notran  = lsame( trans, 'N' )
      tran    = lsame( trans, 'C' )
      left    = lsame( side, 'L' )
      right   = lsame( side, 'R' )
      IF (left) THEN
        lw = n * nb
        q = m
      ELSE
        lw = m * nb
        q = n
      END IF
*
      info = 0
      IF( .NOT.left .AND. .NOT.right ) THEN
         info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
         info = -2
      ELSE IF( m.LT.k ) THEN
        info = -3
      ELSE IF( n.LT.0 ) THEN
        info = -4
      ELSE IF( k.LT.0 ) THEN
        info = -5
      ELSE IF( k.LT.nb .OR. nb.LT.1 ) THEN
        info = -7
      ELSE IF( lda.LT.max( 1, q ) ) THEN
        info = -9
      ELSE IF( ldt.LT.max( 1, nb) ) THEN
        info = -11
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -13
      ELSE IF(( lwork.LT.max(1,lw)).AND.(.NOT.lquery)) THEN
        info = -15
      END IF
*
*     Determine the block size if it is tall skinny or short and wide
*
      IF( info.EQ.0)  THEN
          work(1) = lw
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'ZLAMTSQR', -info )
        RETURN
      ELSE IF (lquery) THEN
       RETURN
      END IF
*
*     Quick return if possible
*
      IF( min(m,n,k).EQ.0 ) THEN
        RETURN
      END IF
*
      IF((mb.LE.k).OR.(mb.GE.max(m,n,k))) THEN
        CALL zgemqrt( side, trans, m, n, k, nb, a, lda,
     $        t, ldt, c, ldc, work, info)
        RETURN
       END IF
*
      IF(left.AND.notran) THEN
*
*         Multiply Q to the last block of C
*
         kk = mod((m-k),(mb-k))
         ctr = (m-k)/(mb-k)
         IF (kk.GT.0) THEN
           ii=m-kk+1
           CALL ztpmqrt('L','N',kk , n, k, 0, nb, a(ii,1), lda,
     $       t(1, ctr * k + 1),ldt , c(1,1), ldc,
     $       c(ii,1), ldc, work, info )
         ELSE
           ii=m+1
         END IF
*
         DO i=ii-(mb-k),mb+1,-(mb-k)
*
*         Multiply Q to the current block of C (I:I+MB,1:N)
*
           ctr = ctr - 1
           CALL ztpmqrt('L','N',mb-k , n, k, 0,nb, a(i,1), lda,
     $         t(1,ctr * k + 1),ldt, c(1,1), ldc,
     $         c(i,1), ldc, work, info )
 
         END DO
*
*         Multiply Q to the first block of C (1:MB,1:N)
*
         CALL zgemqrt('L','N',mb , n, k, nb, a(1,1), lda, t
     $            ,ldt ,c(1,1), ldc, work, info )
*
      ELSE IF (left.AND.tran) THEN
*
*         Multiply Q to the first block of C
*
         kk = mod((m-k),(mb-k))
         ii=m-kk+1
         ctr = 1
         CALL zgemqrt('L','C',mb , n, k, nb, a(1,1), lda, t
     $            ,ldt ,c(1,1), ldc, work, info )
*
         DO i=mb+1,ii-mb+k,(mb-k)
*
*         Multiply Q to the current block of C (I:I+MB,1:N)
*
          CALL ztpmqrt('L','C',mb-k , n, k, 0,nb, a(i,1), lda,
     $       t(1,ctr * k + 1),ldt, c(1,1), ldc,
     $       c(i,1), ldc, work, info )
          ctr = ctr + 1
*
         END DO
         IF(ii.LE.m) THEN
*
*         Multiply Q to the last block of C
*
          CALL ztpmqrt('L','C',kk , n, k, 0,nb, a(ii,1), lda,
     $      t(1, ctr * k + 1), ldt, c(1,1), ldc,
     $      c(ii,1), ldc, work, info )
*
         END IF
*
      ELSE IF(right.AND.tran) THEN
*
*         Multiply Q to the last block of C
*
          kk = mod((n-k),(mb-k))
          ctr = (n-k)/(mb-k)
          IF (kk.GT.0) THEN
            ii=n-kk+1
            CALL ztpmqrt('R','C',m , kk, k, 0, nb, a(ii,1), lda,
     $        t(1,ctr * k + 1), ldt, c(1,1), ldc,
     $        c(1,ii), ldc, work, info )
          ELSE
            ii=n+1
          END IF
*
          DO i=ii-(mb-k),mb+1,-(mb-k)
*
*         Multiply Q to the current block of C (1:M,I:I+MB)
*
            ctr = ctr - 1
            CALL ztpmqrt('R','C',m , mb-k, k, 0,nb, a(i,1), lda,
     $          t(1, ctr * k + 1), ldt, c(1,1), ldc,
     $          c(1,i), ldc, work, info )
 
          END DO
*
*         Multiply Q to the first block of C (1:M,1:MB)
*
          CALL zgemqrt('R','C',m , mb, k, nb, a(1,1), lda, t
     $              ,ldt ,c(1,1), ldc, work, info )
*
      ELSE IF (right.AND.notran) THEN
*
*         Multiply Q to the first block of C
*
         kk = mod((n-k),(mb-k))
         ii=n-kk+1
         ctr = 1
         CALL zgemqrt('R','N', m, mb , k, nb, a(1,1), lda, t
     $              ,ldt ,c(1,1), ldc, work, info )
*
         DO i=mb+1,ii-mb+k,(mb-k)
*
*         Multiply Q to the current block of C (1:M,I:I+MB)
*
          CALL ztpmqrt('R','N', m, mb-k, k, 0,nb, a(i,1), lda,
     $         t(1, ctr * k + 1),ldt, c(1,1), ldc,
     $         c(1,i), ldc, work, info )
          ctr = ctr + 1
*
         END DO
         IF(ii.LE.n) THEN
*
*         Multiply Q to the last block of C
*
          CALL ztpmqrt('R','N', m, kk , k, 0,nb, a(ii,1), lda,
     $        t(1,ctr * k + 1),ldt, c(1,1), ldc,
     $        c(1,ii), ldc, work, info )
*
         END IF
*
      END IF
*
      work(1) = lw
      RETURN
*
*     End of ZLAMTSQR
*
      END