LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zlamtsqr()

subroutine zlamtsqr ( character side,
character trans,
integer m,
integer n,
integer k,
integer mb,
integer nb,
complex*16, dimension( lda, * ) a,
integer lda,
complex*16, dimension( ldt, * ) t,
integer ldt,
complex*16, dimension( ldc, * ) c,
integer ldc,
complex*16, dimension( * ) work,
integer lwork,
integer info )

ZLAMTSQR

Purpose:
!>
!>      ZLAMTSQR overwrites the general complex M-by-N matrix C with
!>
!>
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'C':      Q**H * C       C * Q**H
!>      where Q is a complex unitary matrix defined as the product
!>      of blocked elementary reflectors computed by tall skinny
!>      QR factorization (ZLATSQR)
!>
Parameters
[in]SIDE
!>          SIDE is CHARACTER*1
!>          = 'L': apply Q or Q**H from the Left;
!>          = 'R': apply Q or Q**H from the Right.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          = 'N':  No transpose, apply Q;
!>          = 'C':  Conjugate Transpose, apply Q**H.
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix A.  M >=0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix C. N >= 0.
!>
[in]K
!>          K is INTEGER
!>          The number of elementary reflectors whose product defines
!>          the matrix Q. M >= K >= 0;
!>
!>
[in]MB
!>          MB is INTEGER
!>          The block size to be used in the blocked QR.
!>          MB > N. (must be the same as ZLATSQR)
!>
[in]NB
!>          NB is INTEGER
!>          The column block size to be used in the blocked QR.
!>          N >= NB >= 1.
!>
[in]A
!>          A is COMPLEX*16 array, dimension (LDA,K)
!>          The i-th column must contain the vector which defines the
!>          blockedelementary reflector H(i), for i = 1,2,...,k, as
!>          returned by ZLATSQR in the first k columns of
!>          its array argument A.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.
!>          If SIDE = 'L', LDA >= max(1,M);
!>          if SIDE = 'R', LDA >= max(1,N).
!>
[in]T
!>          T is COMPLEX*16 array, dimension
!>          ( N * Number of blocks(CEIL(M-K/MB-K)),
!>          The blocked upper triangular block reflectors stored in compact form
!>          as a sequence of upper triangular blocks.  See below
!>          for further details.
!>
[in]LDT
!>          LDT is INTEGER
!>          The leading dimension of the array T.  LDT >= NB.
!>
[in,out]C
!>          C is COMPLEX*16 array, dimension (LDC,N)
!>          On entry, the M-by-N matrix C.
!>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
!>
[in]LDC
!>          LDC is INTEGER
!>          The leading dimension of the array C. LDC >= max(1,M).
!>
[out]WORK
!>          (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the minimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK.
!>          If MIN(M,N,K) = 0, LWORK >= 1.
!>          If SIDE = 'L', LWORK >= max(1,N*NB).
!>          If SIDE = 'R', LWORK >= max(1,MB*NB).
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the minimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!> Tall-Skinny QR (TSQR) performs QR by a sequence of unitary transformations,
!> representing Q as a product of other unitary matrices
!>   Q = Q(1) * Q(2) * . . . * Q(k)
!> where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
!>   Q(1) zeros out the subdiagonal entries of rows 1:MB of A
!>   Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
!>   Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
!>   . . .
!>
!> Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
!> stored under the diagonal of rows 1:MB of A, and by upper triangular
!> block reflectors, stored in array T(1:LDT,1:N).
!> For more information see Further Details in GEQRT.
!>
!> Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
!> stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
!> block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
!> The last Q(k) may use fewer rows.
!> For more information see Further Details in TPQRT.
!>
!> For more details of the overall algorithm, see the description of
!> Sequential TSQR in Section 2.2 of [1].
!>
!> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
!>     J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
!>     SIAM J. Sci. Comput, vol. 34, no. 1, 2012
!>

Definition at line 199 of file zlamtsqr.f.

201*
202* -- LAPACK computational routine --
203* -- LAPACK is a software package provided by Univ. of Tennessee, --
204* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
205*
206* .. Scalar Arguments ..
207 CHARACTER SIDE, TRANS
208 INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
209* ..
210* .. Array Arguments ..
211 COMPLEX*16 A( LDA, * ), WORK( * ), C( LDC, * ),
212 $ T( LDT, * )
213* ..
214*
215* =====================================================================
216*
217* ..
218* .. Local Scalars ..
219 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
220 INTEGER I, II, KK, LW, CTR, Q, MINMNK, LWMIN
221* ..
222* .. External Functions ..
223 LOGICAL LSAME
224 EXTERNAL lsame
225* ..
226* .. External Subroutines ..
227 EXTERNAL zgemqrt, ztpmqrt, xerbla
228* ..
229* .. Executable Statements ..
230*
231* Test the input arguments
232*
233 info = 0
234 lquery = ( lwork.EQ.-1 )
235 notran = lsame( trans, 'N' )
236 tran = lsame( trans, 'C' )
237 left = lsame( side, 'L' )
238 right = lsame( side, 'R' )
239 IF( left ) THEN
240 lw = n * nb
241 q = m
242 ELSE
243 lw = m * nb
244 q = n
245 END IF
246*
247 minmnk = min( m, n, k )
248 IF( minmnk.EQ.0 ) THEN
249 lwmin = 1
250 ELSE
251 lwmin = max( 1, lw )
252 END IF
253*
254 IF( .NOT.left .AND. .NOT.right ) THEN
255 info = -1
256 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
257 info = -2
258 ELSE IF( m.LT.k ) THEN
259 info = -3
260 ELSE IF( n.LT.0 ) THEN
261 info = -4
262 ELSE IF( k.LT.0 ) THEN
263 info = -5
264 ELSE IF( k.LT.nb .OR. nb.LT.1 ) THEN
265 info = -7
266 ELSE IF( lda.LT.max( 1, q ) ) THEN
267 info = -9
268 ELSE IF( ldt.LT.max( 1, nb ) ) THEN
269 info = -11
270 ELSE IF( ldc.LT.max( 1, m ) ) THEN
271 info = -13
272 ELSE IF( lwork.LT.lwmin .AND. (.NOT.lquery) ) THEN
273 info = -15
274 END IF
275*
276 IF( info.EQ.0 ) THEN
277 work( 1 ) = lwmin
278 END IF
279*
280 IF( info.NE.0 ) THEN
281 CALL xerbla( 'ZLAMTSQR', -info )
282 RETURN
283 ELSE IF( lquery ) THEN
284 RETURN
285 END IF
286*
287* Quick return if possible
288*
289 IF( minmnk.EQ.0 ) THEN
290 RETURN
291 END IF
292*
293* Determine the block size if it is tall skinny or short and wide
294*
295 IF((mb.LE.k).OR.(mb.GE.max(m,n,k))) THEN
296 CALL zgemqrt( side, trans, m, n, k, nb, a, lda,
297 $ t, ldt, c, ldc, work, info )
298 RETURN
299 END IF
300*
301 IF(left.AND.notran) THEN
302*
303* Multiply Q to the last block of C
304*
305 kk = mod((m-k),(mb-k))
306 ctr = (m-k)/(mb-k)
307 IF (kk.GT.0) THEN
308 ii=m-kk+1
309 CALL ztpmqrt('L','N',kk , n, k, 0, nb, a(ii,1), lda,
310 $ t(1, ctr * k + 1),ldt , c(1,1), ldc,
311 $ c(ii,1), ldc, work, info )
312 ELSE
313 ii=m+1
314 END IF
315*
316 DO i=ii-(mb-k),mb+1,-(mb-k)
317*
318* Multiply Q to the current block of C (I:I+MB,1:N)
319*
320 ctr = ctr - 1
321 CALL ztpmqrt('L','N',mb-k , n, k, 0,nb, a(i,1), lda,
322 $ t(1,ctr * k + 1),ldt, c(1,1), ldc,
323 $ c(i,1), ldc, work, info )
324
325 END DO
326*
327* Multiply Q to the first block of C (1:MB,1:N)
328*
329 CALL zgemqrt('L','N',mb , n, k, nb, a(1,1), lda, t
330 $ ,ldt ,c(1,1), ldc, work, info )
331*
332 ELSE IF (left.AND.tran) THEN
333*
334* Multiply Q to the first block of C
335*
336 kk = mod((m-k),(mb-k))
337 ii=m-kk+1
338 ctr = 1
339 CALL zgemqrt('L','C',mb , n, k, nb, a(1,1), lda, t
340 $ ,ldt ,c(1,1), ldc, work, info )
341*
342 DO i=mb+1,ii-mb+k,(mb-k)
343*
344* Multiply Q to the current block of C (I:I+MB,1:N)
345*
346 CALL ztpmqrt('L','C',mb-k , n, k, 0,nb, a(i,1), lda,
347 $ t(1,ctr * k + 1),ldt, c(1,1), ldc,
348 $ c(i,1), ldc, work, info )
349 ctr = ctr + 1
350*
351 END DO
352 IF(ii.LE.m) THEN
353*
354* Multiply Q to the last block of C
355*
356 CALL ztpmqrt('L','C',kk , n, k, 0,nb, a(ii,1), lda,
357 $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
358 $ c(ii,1), ldc, work, info )
359*
360 END IF
361*
362 ELSE IF(right.AND.tran) THEN
363*
364* Multiply Q to the last block of C
365*
366 kk = mod((n-k),(mb-k))
367 ctr = (n-k)/(mb-k)
368 IF (kk.GT.0) THEN
369 ii=n-kk+1
370 CALL ztpmqrt('R','C',m , kk, k, 0, nb, a(ii,1), lda,
371 $ t(1,ctr * k + 1), ldt, c(1,1), ldc,
372 $ c(1,ii), ldc, work, info )
373 ELSE
374 ii=n+1
375 END IF
376*
377 DO i=ii-(mb-k),mb+1,-(mb-k)
378*
379* Multiply Q to the current block of C (1:M,I:I+MB)
380*
381 ctr = ctr - 1
382 CALL ztpmqrt('R','C',m , mb-k, k, 0,nb, a(i,1), lda,
383 $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
384 $ c(1,i), ldc, work, info )
385
386 END DO
387*
388* Multiply Q to the first block of C (1:M,1:MB)
389*
390 CALL zgemqrt('R','C',m , mb, k, nb, a(1,1), lda, t
391 $ ,ldt ,c(1,1), ldc, work, info )
392*
393 ELSE IF (right.AND.notran) THEN
394*
395* Multiply Q to the first block of C
396*
397 kk = mod((n-k),(mb-k))
398 ii=n-kk+1
399 ctr = 1
400 CALL zgemqrt('R','N', m, mb , k, nb, a(1,1), lda, t
401 $ ,ldt ,c(1,1), ldc, work, info )
402*
403 DO i=mb+1,ii-mb+k,(mb-k)
404*
405* Multiply Q to the current block of C (1:M,I:I+MB)
406*
407 CALL ztpmqrt('R','N', m, mb-k, k, 0,nb, a(i,1), lda,
408 $ t(1, ctr * k + 1),ldt, c(1,1), ldc,
409 $ c(1,i), ldc, work, info )
410 ctr = ctr + 1
411*
412 END DO
413 IF(ii.LE.n) THEN
414*
415* Multiply Q to the last block of C
416*
417 CALL ztpmqrt('R','N', m, kk , k, 0,nb, a(ii,1), lda,
418 $ t(1,ctr * k + 1),ldt, c(1,1), ldc,
419 $ c(1,ii), ldc, work, info )
420*
421 END IF
422*
423 END IF
424*
425 work( 1 ) = lwmin
426 RETURN
427*
428* End of ZLAMTSQR
429*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zgemqrt
subroutine zgemqrt(side, trans, m, n, k, nb, v, ldv, t, ldt, c, ldc, work, info)
ZGEMQRT
Definition zgemqrt.f:166
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
ztpmqrt
subroutine ztpmqrt(side, trans, m, n, k, l, nb, v, ldv, t, ldt, a, lda, b, ldb, work, info)
ZTPMQRT
Definition ztpmqrt.f:215
Here is the call graph for this function:
Here is the caller graph for this function: