clqt04.f

Go to the documentation of this file.

*> \brief \b DLQT04
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLQT04(M,N,NB,RESULT)
*
*       .. Scalar Arguments ..
*       INTEGER M, N, NB
*       .. Return values ..
*       REAL RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLQT04 tests CGELQT and CGEMLQT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= Min(M,N).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - L Q |
*>          RESULT(2) = | I - Q Q^H |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q |
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE clqt04(M,N,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER M, N, NB
*     .. Return values ..
      REAL RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      COMPLEX, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  L(:,:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
      REAL, ALLOCATABLE :: RWORK(:)
*
*     .. Parameters ..
      REAL       ZERO
      COMPLEX    ONE, CZERO
      parameter( zero = 0.0)
      parameter( one = (1.0,0.0), czero=(0.0,0.0) )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, LL, LWORK, LDT
      REAL    ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      REAL     SLAMCH
      REAL     CLANGE, CLANSY
      LOGICAL  LSAME
      EXTERNAL slamch, clange, clansy, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = slamch( 'Epsilon' )
      k = min(m,n)
      ll = max(m,n)
      lwork = max(2,ll)*max(2,ll)*nb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(n,n), l(ll,n), rwork(ll),
     $           work(lwork), t(nb,n), c(m,n), cf(m,n),
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      ldt=nb
      DO j=1,n
         CALL clarnv( 2, iseed, m, a( 1, j ) )
      END DO
      CALL clacpy( 'Full', m, n, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL cgelqt( m, n, nb, af, m, t, ldt, work, info )
*
*     Generate the n-by-n matrix Q
*
      CALL claset( 'Full', n, n, czero, one, q, n )
      CALL cgemlqt( 'R', 'N', n, n, k, nb, af, m, t, ldt, q, n,
     $              work, info )
*
*     Copy L
*
      CALL claset( 'Full', ll, n, czero, czero, l, ll )
      CALL clacpy( 'Lower', m, n, af, m, l, ll )
*
*     Compute |L - A*Q'| / |A| and store in RESULT(1)
*
      CALL cgemm( 'N', 'C', m, n, n, -one, a, m, q, n, one, l, ll )
      anorm = clange( '1', m, n, a, m, rwork )
      resid = clange( '1', m, n, l, ll, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL claset( 'Full', n, n, czero, one, l, ll )
      CALL cherk( 'U', 'C', n, n, real(-one), q, n, real(one), l, ll)
      resid = clansy( '1', 'Upper', n, l, ll, rwork )
      result( 2 ) = resid / (eps*max(1,n))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,m
         CALL clarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = clange( '1', n, m, d, n, rwork)
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to C as Q*C
*
      CALL cgemlqt( 'L', 'N', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |Q*D - Q*D| / |D|
*
      CALL cgemm( 'N', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as QT*D
*
      CALL cgemlqt( 'L', 'C', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |QT*D - QT*D| / |D|
*
      CALL cgemm( 'C', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,n
         CALL clarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = clange( '1', m, n, c, m, rwork)
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as C*Q
*
      CALL cgemlqt( 'R', 'N', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |C*Q - C*Q| / |C|
*
      CALL cgemm( 'N', 'N', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = clange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to D as D*QT
*
      CALL cgemlqt( 'R', 'C', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |C*QT - C*QT| / |C|
*
      CALL cgemm( 'N', 'C', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = clange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, l, rwork, work, t, c, d, cf, df)
*
      RETURN
      END