cungr2()

subroutine cungr2	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( * )	work,
		integer	info )

CUNGR2 generates all or part of the unitary matrix Q from an RQ factorization determined by cgerqf (unblocked algorithm).

Download CUNGR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CUNGR2 generates an m by n complex matrix Q with orthonormal rows,
!> which is defined as the last m rows of a product of k elementary
!> reflectors of order n
!>
!>       Q  =  H(1)**H H(2)**H . . . H(k)**H
!>
!> as returned by CGERQF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q. N >= M. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. M >= K >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the (m-k+i)-th row must contain the vector which !> defines the elementary reflector H(i), for i = 1,2,...,k, as !> returned by CGERQF in the last k rows of its array argument !> A. !> On exit, the m-by-n matrix Q. !>
[in]	LDA	!> LDA is INTEGER !> The first dimension of the array A. LDA >= max(1,M). !>
[in]	TAU	!> TAU is COMPLEX array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by CGERQF. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (M) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument has an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 111 of file cungr2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, II, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacgv, clarf1l, cscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUNGR2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      IF( k.LT.m ) THEN
*
*        Initialise rows 1:m-k to rows of the unit matrix
*
         DO 20 j = 1, n
            DO 10 l = 1, m - k
               a( l, j ) = zero
   10       CONTINUE
            IF( j.GT.n-m .AND. j.LE.n-k )
     $         a( m-n+j, j ) = one
   20    CONTINUE
      END IF
*
      DO 40 i = 1, k
         ii = m - k + i
*
*        Apply H(i)**H to A(1:m-k+i,1:n-k+i) from the right
*
         CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
         a( ii, n-m+ii ) = one
         CALL clarf1l( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda,
     $                 conjg( tau( i ) ), a, lda, work )
         CALL cscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
         CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
         a( ii, n-m+ii ) = one - conjg( tau( i ) )
*
*        Set A(m-k+i,n-k+i+1:n) to zero
*
         DO 30 l = n - m + ii + 1, n
            a( ii, l ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of CUNGR2
*

Here is the call graph for this function:

Here is the caller graph for this function: