LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
cgqrts.f
Go to the documentation of this file.
1*> \brief \b CGQRTS
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE CGQRTS( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
12* BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
13*
14* .. Scalar Arguments ..
15* INTEGER LDA, LDB, LWORK, M, P, N
16* ..
17* .. Array Arguments ..
18* REAL RWORK( * ), RESULT( 4 )
19* COMPLEX A( LDA, * ), AF( LDA, * ), R( LDA, * ),
20* $ Q( LDA, * ), B( LDB, * ), BF( LDB, * ),
21* $ T( LDB, * ), Z( LDB, * ), BWK( LDB, * ),
22* $ TAUA( * ), TAUB( * ), WORK( LWORK )
23* ..
24*
25*
26*> \par Purpose:
27* =============
28*>
29*> \verbatim
30*>
31*> CGQRTS tests CGGQRF, which computes the GQR factorization of an
32*> N-by-M matrix A and a N-by-P matrix B: A = Q*R and B = Q*T*Z.
33*> \endverbatim
34*
35* Arguments:
36* ==========
37*
38*> \param[in] N
39*> \verbatim
40*> N is INTEGER
41*> The number of rows of the matrices A and B. N >= 0.
42*> \endverbatim
43*>
44*> \param[in] M
45*> \verbatim
46*> M is INTEGER
47*> The number of columns of the matrix A. M >= 0.
48*> \endverbatim
49*>
50*> \param[in] P
51*> \verbatim
52*> P is INTEGER
53*> The number of columns of the matrix B. P >= 0.
54*> \endverbatim
55*>
56*> \param[in] A
57*> \verbatim
58*> A is COMPLEX array, dimension (LDA,M)
59*> The N-by-M matrix A.
60*> \endverbatim
61*>
62*> \param[out] AF
63*> \verbatim
64*> AF is COMPLEX array, dimension (LDA,N)
65*> Details of the GQR factorization of A and B, as returned
66*> by CGGQRF, see CGGQRF for further details.
67*> \endverbatim
68*>
69*> \param[out] Q
70*> \verbatim
71*> Q is COMPLEX array, dimension (LDA,N)
72*> The M-by-M unitary matrix Q.
73*> \endverbatim
74*>
75*> \param[out] R
76*> \verbatim
77*> R is COMPLEX array, dimension (LDA,MAX(M,N))
78*> \endverbatim
79*>
80*> \param[in] LDA
81*> \verbatim
82*> LDA is INTEGER
83*> The leading dimension of the arrays A, AF, R and Q.
84*> LDA >= max(M,N).
85*> \endverbatim
86*>
87*> \param[out] TAUA
88*> \verbatim
89*> TAUA is COMPLEX array, dimension (min(M,N))
90*> The scalar factors of the elementary reflectors, as returned
91*> by CGGQRF.
92*> \endverbatim
93*>
94*> \param[in] B
95*> \verbatim
96*> B is COMPLEX array, dimension (LDB,P)
97*> On entry, the N-by-P matrix A.
98*> \endverbatim
99*>
100*> \param[out] BF
101*> \verbatim
102*> BF is COMPLEX array, dimension (LDB,N)
103*> Details of the GQR factorization of A and B, as returned
104*> by CGGQRF, see CGGQRF for further details.
105*> \endverbatim
106*>
107*> \param[out] Z
108*> \verbatim
109*> Z is COMPLEX array, dimension (LDB,P)
110*> The P-by-P unitary matrix Z.
111*> \endverbatim
112*>
113*> \param[out] T
114*> \verbatim
115*> T is COMPLEX array, dimension (LDB,max(P,N))
116*> \endverbatim
117*>
118*> \param[out] BWK
119*> \verbatim
120*> BWK is COMPLEX array, dimension (LDB,N)
121*> \endverbatim
122*>
123*> \param[in] LDB
124*> \verbatim
125*> LDB is INTEGER
126*> The leading dimension of the arrays B, BF, Z and T.
127*> LDB >= max(P,N).
128*> \endverbatim
129*>
130*> \param[out] TAUB
131*> \verbatim
132*> TAUB is COMPLEX array, dimension (min(P,N))
133*> The scalar factors of the elementary reflectors, as returned
134*> by SGGRQF.
135*> \endverbatim
136*>
137*> \param[out] WORK
138*> \verbatim
139*> WORK is COMPLEX array, dimension (LWORK)
140*> \endverbatim
141*>
142*> \param[in] LWORK
143*> \verbatim
144*> LWORK is INTEGER
145*> The dimension of the array WORK, LWORK >= max(N,M,P)**2.
146*> \endverbatim
147*>
148*> \param[out] RWORK
149*> \verbatim
150*> RWORK is REAL array, dimension (max(N,M,P))
151*> \endverbatim
152*>
153*> \param[out] RESULT
154*> \verbatim
155*> RESULT is REAL array, dimension (4)
156*> The test ratios:
157*> RESULT(1) = norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP)
158*> RESULT(2) = norm( T*Z - Q'*B ) / (MAX(P,N)*norm(B)*ULP)
159*> RESULT(3) = norm( I - Q'*Q ) / ( M*ULP )
160*> RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
161*> \endverbatim
162*
163* Authors:
164* ========
165*
166*> \author Univ. of Tennessee
167*> \author Univ. of California Berkeley
168*> \author Univ. of Colorado Denver
169*> \author NAG Ltd.
170*
171*> \ingroup complex_eig
172*
173* =====================================================================
174 SUBROUTINE cgqrts( N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
175 $ BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
176*
177* -- LAPACK test routine --
178* -- LAPACK is a software package provided by Univ. of Tennessee, --
179* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
180*
181* .. Scalar Arguments ..
182 INTEGER LDA, LDB, LWORK, M, P, N
183* ..
184* .. Array Arguments ..
185 REAL RWORK( * ), RESULT( 4 )
186 COMPLEX A( LDA, * ), AF( LDA, * ), R( LDA, * ),
187 $ q( lda, * ), b( ldb, * ), bf( ldb, * ),
188 $ t( ldb, * ), z( ldb, * ), bwk( ldb, * ),
189 $ taua( * ), taub( * ), work( lwork )
190* ..
191*
192* =====================================================================
193*
194* .. Parameters ..
195 REAL ZERO, ONE
196 parameter( zero = 0.0e+0, one = 1.0e+0 )
197 COMPLEX CZERO, CONE
198 parameter( czero = ( 0.0e+0, 0.0e+0 ),
199 $ cone = ( 1.0e+0, 0.0e+0 ) )
200 COMPLEX CROGUE
201 parameter( crogue = ( -1.0e+10, 0.0e+0 ) )
202* ..
203* .. Local Scalars ..
204 INTEGER INFO
205 REAL ANORM, BNORM, ULP, UNFL, RESID
206* ..
207* .. External Functions ..
208 REAL SLAMCH, CLANGE, CLANHE
209 EXTERNAL slamch, clange, clanhe
210* ..
211* .. External Subroutines ..
212 EXTERNAL cgemm, clacpy, claset, cungqr,
213 $ cungrq, cherk
214* ..
215* .. Intrinsic Functions ..
216 INTRINSIC max, min, real
217* ..
218* .. Executable Statements ..
219*
220 ulp = slamch( 'Precision' )
221 unfl = slamch( 'Safe minimum' )
222*
223* Copy the matrix A to the array AF.
224*
225 CALL clacpy( 'Full', n, m, a, lda, af, lda )
226 CALL clacpy( 'Full', n, p, b, ldb, bf, ldb )
227*
228 anorm = max( clange( '1', n, m, a, lda, rwork ), unfl )
229 bnorm = max( clange( '1', n, p, b, ldb, rwork ), unfl )
230*
231* Factorize the matrices A and B in the arrays AF and BF.
232*
233 CALL cggqrf( n, m, p, af, lda, taua, bf, ldb, taub, work,
234 $ lwork, info )
235*
236* Generate the N-by-N matrix Q
237*
238 CALL claset( 'Full', n, n, crogue, crogue, q, lda )
239 CALL clacpy( 'Lower', n-1, m, af( 2,1 ), lda, q( 2,1 ), lda )
240 CALL cungqr( n, n, min( n, m ), q, lda, taua, work, lwork, info )
241*
242* Generate the P-by-P matrix Z
243*
244 CALL claset( 'Full', p, p, crogue, crogue, z, ldb )
245 IF( n.LE.p ) THEN
246 IF( n.GT.0 .AND. n.LT.p )
247 $ CALL clacpy( 'Full', n, p-n, bf, ldb, z( p-n+1, 1 ), ldb )
248 IF( n.GT.1 )
249 $ CALL clacpy( 'Lower', n-1, n-1, bf( 2, p-n+1 ), ldb,
250 $ z( p-n+2, p-n+1 ), ldb )
251 ELSE
252 IF( p.GT.1)
253 $ CALL clacpy( 'Lower', p-1, p-1, bf( n-p+2, 1 ), ldb,
254 $ z( 2, 1 ), ldb )
255 END IF
256 CALL cungrq( p, p, min( n, p ), z, ldb, taub, work, lwork, info )
257*
258* Copy R
259*
260 CALL claset( 'Full', n, m, czero, czero, r, lda )
261 CALL clacpy( 'Upper', n, m, af, lda, r, lda )
262*
263* Copy T
264*
265 CALL claset( 'Full', n, p, czero, czero, t, ldb )
266 IF( n.LE.p ) THEN
267 CALL clacpy( 'Upper', n, n, bf( 1, p-n+1 ), ldb, t( 1, p-n+1 ),
268 $ ldb )
269 ELSE
270 CALL clacpy( 'Full', n-p, p, bf, ldb, t, ldb )
271 CALL clacpy( 'Upper', p, p, bf( n-p+1, 1 ), ldb, t( n-p+1, 1 ),
272 $ ldb )
273 END IF
274*
275* Compute R - Q'*A
276*
277 CALL cgemm( 'Conjugate transpose', 'No transpose', n, m, n, -cone,
278 $ q, lda, a, lda, cone, r, lda )
279*
280* Compute norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP ) .
281*
282 resid = clange( '1', n, m, r, lda, rwork )
283 IF( anorm.GT.zero ) THEN
284 result( 1 ) = ( ( resid / real( max(1,m,n) ) ) / anorm ) / ulp
285 ELSE
286 result( 1 ) = zero
287 END IF
288*
289* Compute T*Z - Q'*B
290*
291 CALL cgemm( 'No Transpose', 'No transpose', n, p, p, cone, t, ldb,
292 $ z, ldb, czero, bwk, ldb )
293 CALL cgemm( 'Conjugate transpose', 'No transpose', n, p, n, -cone,
294 $ q, lda, b, ldb, cone, bwk, ldb )
295*
296* Compute norm( T*Z - Q'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
297*
298 resid = clange( '1', n, p, bwk, ldb, rwork )
299 IF( bnorm.GT.zero ) THEN
300 result( 2 ) = ( ( resid / real( max(1,p,n ) ) )/bnorm ) / ulp
301 ELSE
302 result( 2 ) = zero
303 END IF
304*
305* Compute I - Q'*Q
306*
307 CALL claset( 'Full', n, n, czero, cone, r, lda )
308 CALL cherk( 'Upper', 'Conjugate transpose', n, n, -one, q, lda,
309 $ one, r, lda )
310*
311* Compute norm( I - Q'*Q ) / ( N * ULP ) .
312*
313 resid = clanhe( '1', 'Upper', n, r, lda, rwork )
314 result( 3 ) = ( resid / real( max( 1, n ) ) ) / ulp
315*
316* Compute I - Z'*Z
317*
318 CALL claset( 'Full', p, p, czero, cone, t, ldb )
319 CALL cherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
320 $ one, t, ldb )
321*
322* Compute norm( I - Z'*Z ) / ( P*ULP ) .
323*
324 resid = clanhe( '1', 'Upper', p, t, ldb, rwork )
325 result( 4 ) = ( resid / real( max( 1, p ) ) ) / ulp
326*
327 RETURN
328*
329* End of CGQRTS
330*
331 END
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:187
subroutine cherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
CHERK
Definition: cherk.f:173
subroutine cgqrts(N, M, P, A, AF, Q, R, LDA, TAUA, B, BF, Z, T, BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT)
CGQRTS
Definition: cgqrts.f:176
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: claset.f:106
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:103
subroutine cungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGQR
Definition: cungqr.f:128
subroutine cggqrf(N, M, P, A, LDA, TAUA, B, LDB, TAUB, WORK, LWORK, INFO)
CGGQRF
Definition: cggqrf.f:215
subroutine cungrq(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGRQ
Definition: cungrq.f:128