LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cgqrts()

subroutine cgqrts ( integer  n,
integer  m,
integer  p,
complex, dimension( lda, * )  a,
complex, dimension( lda, * )  af,
complex, dimension( lda, * )  q,
complex, dimension( lda, * )  r,
integer  lda,
complex, dimension( * )  taua,
complex, dimension( ldb, * )  b,
complex, dimension( ldb, * )  bf,
complex, dimension( ldb, * )  z,
complex, dimension( ldb, * )  t,
complex, dimension( ldb, * )  bwk,
integer  ldb,
complex, dimension( * )  taub,
complex, dimension( lwork )  work,
integer  lwork,
real, dimension( * )  rwork,
real, dimension( 4 )  result 
)

CGQRTS

Purpose:
 CGQRTS tests CGGQRF, which computes the GQR factorization of an
 N-by-M matrix A and a N-by-P matrix B: A = Q*R and B = Q*T*Z.
Parameters
[in]N
          N is INTEGER
          The number of rows of the matrices A and B.  N >= 0.
[in]M
          M is INTEGER
          The number of columns of the matrix A.  M >= 0.
[in]P
          P is INTEGER
          The number of columns of the matrix B.  P >= 0.
[in]A
          A is COMPLEX array, dimension (LDA,M)
          The N-by-M matrix A.
[out]AF
          AF is COMPLEX array, dimension (LDA,N)
          Details of the GQR factorization of A and B, as returned
          by CGGQRF, see CGGQRF for further details.
[out]Q
          Q is COMPLEX array, dimension (LDA,N)
          The M-by-M unitary matrix Q.
[out]R
          R is COMPLEX array, dimension (LDA,MAX(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, R and Q.
          LDA >= max(M,N).
[out]TAUA
          TAUA is COMPLEX array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by CGGQRF.
[in]B
          B is COMPLEX array, dimension (LDB,P)
          On entry, the N-by-P matrix A.
[out]BF
          BF is COMPLEX array, dimension (LDB,N)
          Details of the GQR factorization of A and B, as returned
          by CGGQRF, see CGGQRF for further details.
[out]Z
          Z is COMPLEX array, dimension (LDB,P)
          The P-by-P unitary matrix Z.
[out]T
          T is COMPLEX array, dimension (LDB,max(P,N))
[out]BWK
          BWK is COMPLEX array, dimension (LDB,N)
[in]LDB
          LDB is INTEGER
          The leading dimension of the arrays B, BF, Z and T.
          LDB >= max(P,N).
[out]TAUB
          TAUB is COMPLEX array, dimension (min(P,N))
          The scalar factors of the elementary reflectors, as returned
          by SGGRQF.
[out]WORK
          WORK is COMPLEX array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK, LWORK >= max(N,M,P)**2.
[out]RWORK
          RWORK is REAL array, dimension (max(N,M,P))
[out]RESULT
          RESULT is REAL array, dimension (4)
          The test ratios:
            RESULT(1) = norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP)
            RESULT(2) = norm( T*Z - Q'*B ) / (MAX(P,N)*norm(B)*ULP)
            RESULT(3) = norm( I - Q'*Q ) / ( M*ULP )
            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 174 of file cgqrts.f.

176*
177* -- LAPACK test routine --
178* -- LAPACK is a software package provided by Univ. of Tennessee, --
179* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
180*
181* .. Scalar Arguments ..
182 INTEGER LDA, LDB, LWORK, M, P, N
183* ..
184* .. Array Arguments ..
185 REAL RWORK( * ), RESULT( 4 )
186 COMPLEX A( LDA, * ), AF( LDA, * ), R( LDA, * ),
187 $ Q( LDA, * ), B( LDB, * ), BF( LDB, * ),
188 $ T( LDB, * ), Z( LDB, * ), BWK( LDB, * ),
189 $ TAUA( * ), TAUB( * ), WORK( LWORK )
190* ..
191*
192* =====================================================================
193*
194* .. Parameters ..
195 REAL ZERO, ONE
196 parameter( zero = 0.0e+0, one = 1.0e+0 )
197 COMPLEX CZERO, CONE
198 parameter( czero = ( 0.0e+0, 0.0e+0 ),
199 $ cone = ( 1.0e+0, 0.0e+0 ) )
200 COMPLEX CROGUE
201 parameter( crogue = ( -1.0e+10, 0.0e+0 ) )
202* ..
203* .. Local Scalars ..
204 INTEGER INFO
205 REAL ANORM, BNORM, ULP, UNFL, RESID
206* ..
207* .. External Functions ..
208 REAL SLAMCH, CLANGE, CLANHE
209 EXTERNAL slamch, clange, clanhe
210* ..
211* .. External Subroutines ..
212 EXTERNAL cgemm, clacpy, claset, cungqr,
213 $ cungrq, cherk
214* ..
215* .. Intrinsic Functions ..
216 INTRINSIC max, min, real
217* ..
218* .. Executable Statements ..
219*
220 ulp = slamch( 'Precision' )
221 unfl = slamch( 'Safe minimum' )
222*
223* Copy the matrix A to the array AF.
224*
225 CALL clacpy( 'Full', n, m, a, lda, af, lda )
226 CALL clacpy( 'Full', n, p, b, ldb, bf, ldb )
227*
228 anorm = max( clange( '1', n, m, a, lda, rwork ), unfl )
229 bnorm = max( clange( '1', n, p, b, ldb, rwork ), unfl )
230*
231* Factorize the matrices A and B in the arrays AF and BF.
232*
233 CALL cggqrf( n, m, p, af, lda, taua, bf, ldb, taub, work,
234 $ lwork, info )
235*
236* Generate the N-by-N matrix Q
237*
238 CALL claset( 'Full', n, n, crogue, crogue, q, lda )
239 CALL clacpy( 'Lower', n-1, m, af( 2,1 ), lda, q( 2,1 ), lda )
240 CALL cungqr( n, n, min( n, m ), q, lda, taua, work, lwork, info )
241*
242* Generate the P-by-P matrix Z
243*
244 CALL claset( 'Full', p, p, crogue, crogue, z, ldb )
245 IF( n.LE.p ) THEN
246 IF( n.GT.0 .AND. n.LT.p )
247 $ CALL clacpy( 'Full', n, p-n, bf, ldb, z( p-n+1, 1 ), ldb )
248 IF( n.GT.1 )
249 $ CALL clacpy( 'Lower', n-1, n-1, bf( 2, p-n+1 ), ldb,
250 $ z( p-n+2, p-n+1 ), ldb )
251 ELSE
252 IF( p.GT.1)
253 $ CALL clacpy( 'Lower', p-1, p-1, bf( n-p+2, 1 ), ldb,
254 $ z( 2, 1 ), ldb )
255 END IF
256 CALL cungrq( p, p, min( n, p ), z, ldb, taub, work, lwork, info )
257*
258* Copy R
259*
260 CALL claset( 'Full', n, m, czero, czero, r, lda )
261 CALL clacpy( 'Upper', n, m, af, lda, r, lda )
262*
263* Copy T
264*
265 CALL claset( 'Full', n, p, czero, czero, t, ldb )
266 IF( n.LE.p ) THEN
267 CALL clacpy( 'Upper', n, n, bf( 1, p-n+1 ), ldb, t( 1, p-n+1 ),
268 $ ldb )
269 ELSE
270 CALL clacpy( 'Full', n-p, p, bf, ldb, t, ldb )
271 CALL clacpy( 'Upper', p, p, bf( n-p+1, 1 ), ldb, t( n-p+1, 1 ),
272 $ ldb )
273 END IF
274*
275* Compute R - Q'*A
276*
277 CALL cgemm( 'Conjugate transpose', 'No transpose', n, m, n, -cone,
278 $ q, lda, a, lda, cone, r, lda )
279*
280* Compute norm( R - Q'*A ) / ( MAX(M,N)*norm(A)*ULP ) .
281*
282 resid = clange( '1', n, m, r, lda, rwork )
283 IF( anorm.GT.zero ) THEN
284 result( 1 ) = ( ( resid / real( max(1,m,n) ) ) / anorm ) / ulp
285 ELSE
286 result( 1 ) = zero
287 END IF
288*
289* Compute T*Z - Q'*B
290*
291 CALL cgemm( 'No Transpose', 'No transpose', n, p, p, cone, t, ldb,
292 $ z, ldb, czero, bwk, ldb )
293 CALL cgemm( 'Conjugate transpose', 'No transpose', n, p, n, -cone,
294 $ q, lda, b, ldb, cone, bwk, ldb )
295*
296* Compute norm( T*Z - Q'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
297*
298 resid = clange( '1', n, p, bwk, ldb, rwork )
299 IF( bnorm.GT.zero ) THEN
300 result( 2 ) = ( ( resid / real( max(1,p,n ) ) )/bnorm ) / ulp
301 ELSE
302 result( 2 ) = zero
303 END IF
304*
305* Compute I - Q'*Q
306*
307 CALL claset( 'Full', n, n, czero, cone, r, lda )
308 CALL cherk( 'Upper', 'Conjugate transpose', n, n, -one, q, lda,
309 $ one, r, lda )
310*
311* Compute norm( I - Q'*Q ) / ( N * ULP ) .
312*
313 resid = clanhe( '1', 'Upper', n, r, lda, rwork )
314 result( 3 ) = ( resid / real( max( 1, n ) ) ) / ulp
315*
316* Compute I - Z'*Z
317*
318 CALL claset( 'Full', p, p, czero, cone, t, ldb )
319 CALL cherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
320 $ one, t, ldb )
321*
322* Compute norm( I - Z'*Z ) / ( P*ULP ) .
323*
324 resid = clanhe( '1', 'Upper', p, t, ldb, rwork )
325 result( 4 ) = ( resid / real( max( 1, p ) ) ) / ulp
326*
327 RETURN
328*
329* End of CGQRTS
330*
cgemm
subroutine cgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
CGEMM
Definition cgemm.f:188
cggqrf
subroutine cggqrf(n, m, p, a, lda, taua, b, ldb, taub, work, lwork, info)
CGGQRF
Definition cggqrf.f:215
cherk
subroutine cherk(uplo, trans, n, k, alpha, a, lda, beta, c, ldc)
CHERK
Definition cherk.f:173
clacpy
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:103
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
clange
real function clange(norm, m, n, a, lda, work)
CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition clange.f:115
clanhe
real function clanhe(norm, uplo, n, a, lda, work)
CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition clanhe.f:124
claset
subroutine claset(uplo, m, n, alpha, beta, a, lda)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition claset.f:106
cungqr
subroutine cungqr(m, n, k, a, lda, tau, work, lwork, info)
CUNGQR
Definition cungqr.f:128
cungrq
subroutine cungrq(m, n, k, a, lda, tau, work, lwork, info)
CUNGRQ
Definition cungrq.f:128
Here is the call graph for this function:
Here is the caller graph for this function: