slapll()

subroutine slapll	(	integer	n,
		real, dimension( * )	x,
		integer	incx,
		real, dimension( * )	y,
		integer	incy,
		real	ssmin
	)

SLAPLL measures the linear dependence of two vectors.

Download SLAPLL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 Given two column vectors X and Y, let

                      A = ( X Y ).

 The subroutine first computes the QR factorization of A = Q*R,
 and then computes the SVD of the 2-by-2 upper triangular matrix R.
 The smaller singular value of R is returned in SSMIN, which is used
 as the measurement of the linear dependency of the vectors X and Y.

Parameters

[in]	N	N is INTEGER The length of the vectors X and Y.
[in,out]	X	X is REAL array, dimension (1+(N-1)*INCX) On entry, X contains the N-vector X. On exit, X is overwritten.
[in]	INCX	INCX is INTEGER The increment between successive elements of X. INCX > 0.
[in,out]	Y	Y is REAL array, dimension (1+(N-1)*INCY) On entry, Y contains the N-vector Y. On exit, Y is overwritten.
[in]	INCY	INCY is INTEGER The increment between successive elements of Y. INCY > 0.
[out]	SSMIN	SSMIN is REAL The smallest singular value of the N-by-2 matrix A = ( X Y ).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file slapll.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      REAL               SSMIN
*     ..
*     .. Array Arguments ..
      REAL               X( * ), Y( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               A11, A12, A22, C, SSMAX, TAU
*     ..
*     .. External Functions ..
      REAL               SDOT
      EXTERNAL           sdot
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, slarfg, slas2
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 ) THEN
         ssmin = zero
         RETURN
      END IF
*
*     Compute the QR factorization of the N-by-2 matrix ( X Y )
*
      CALL slarfg( n, x( 1 ), x( 1+incx ), incx, tau )
      a11 = x( 1 )
      x( 1 ) = one
*
      c = -tau*sdot( n, x, incx, y, incy )
      CALL saxpy( n, c, x, incx, y, incy )
*
      CALL slarfg( n-1, y( 1+incy ), y( 1+2*incy ), incy, tau )
*
      a12 = y( 1 )
      a22 = y( 1+incy )
*
*     Compute the SVD of 2-by-2 Upper triangular matrix.
*
      CALL slas2( a11, a12, a22, ssmin, ssmax )
*
      RETURN
*
*     End of SLAPLL
*

Here is the call graph for this function:

Here is the caller graph for this function: