LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sgelqt3.f
Go to the documentation of this file.
1*> \brief \b SGELQT3
2*
3* Definition:
4* ===========
5*
6* RECURSIVE SUBROUTINE SGELQT3( M, N, A, LDA, T, LDT, INFO )
7*
8* .. Scalar Arguments ..
9* INTEGER INFO, LDA, M, N, LDT
10* ..
11* .. Array Arguments ..
12* REAL A( LDA, * ), T( LDT, * )
13* ..
14*
15*
16*> \par Purpose:
17* =============
18*>
19*> \verbatim
20*>
21*> SGELQT3 recursively computes a LQ factorization of a real M-by-N
22*> matrix A, using the compact WY representation of Q.
23*>
24*> Based on the algorithm of Elmroth and Gustavson,
25*> IBM J. Res. Develop. Vol 44 No. 4 July 2000.
26*> \endverbatim
27*
28* Arguments:
29* ==========
30*
31*> \param[in] M
32*> \verbatim
33*> M is INTEGER
34*> The number of rows of the matrix A. M =< N.
35*> \endverbatim
36*>
37*> \param[in] N
38*> \verbatim
39*> N is INTEGER
40*> The number of columns of the matrix A. N >= 0.
41*> \endverbatim
42*>
43*> \param[in,out] A
44*> \verbatim
45*> A is REAL array, dimension (LDA,N)
46*> On entry, the real M-by-N matrix A. On exit, the elements on and
47*> below the diagonal contain the N-by-N lower triangular matrix L; the
48*> elements above the diagonal are the rows of V. See below for
49*> further details.
50*> \endverbatim
51*>
52*> \param[in] LDA
53*> \verbatim
54*> LDA is INTEGER
55*> The leading dimension of the array A. LDA >= max(1,M).
56*> \endverbatim
57*>
58*> \param[out] T
59*> \verbatim
60*> T is REAL array, dimension (LDT,N)
61*> The N-by-N upper triangular factor of the block reflector.
62*> The elements on and above the diagonal contain the block
63*> reflector T; the elements below the diagonal are not used.
64*> See below for further details.
65*> \endverbatim
66*>
67*> \param[in] LDT
68*> \verbatim
69*> LDT is INTEGER
70*> The leading dimension of the array T. LDT >= max(1,N).
71*> \endverbatim
72*>
73*> \param[out] INFO
74*> \verbatim
75*> INFO is INTEGER
76*> = 0: successful exit
77*> < 0: if INFO = -i, the i-th argument had an illegal value
78*> \endverbatim
79*
80* Authors:
81* ========
82*
83*> \author Univ. of Tennessee
84*> \author Univ. of California Berkeley
85*> \author Univ. of Colorado Denver
86*> \author NAG Ltd.
87*
88*> \ingroup doubleGEcomputational
89*
90*> \par Further Details:
91* =====================
92*>
93*> \verbatim
94*>
95*> The matrix V stores the elementary reflectors H(i) in the i-th row
96*> above the diagonal. For example, if M=5 and N=3, the matrix V is
97*>
98*> V = ( 1 v1 v1 v1 v1 )
99*> ( 1 v2 v2 v2 )
100*> ( 1 v3 v3 v3 )
101*>
102*>
103*> where the vi's represent the vectors which define H(i), which are returned
104*> in the matrix A. The 1's along the diagonal of V are not stored in A. The
105*> block reflector H is then given by
106*>
107*> H = I - V * T * V**T
108*>
109*> where V**T is the transpose of V.
110*>
111*> For details of the algorithm, see Elmroth and Gustavson (cited above).
112*> \endverbatim
113*>
114* =====================================================================
115 RECURSIVE SUBROUTINE sgelqt3( M, N, A, LDA, T, LDT, INFO )
116*
117* -- LAPACK computational routine --
118* -- LAPACK is a software package provided by Univ. of Tennessee, --
119* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120*
121* .. Scalar Arguments ..
122 INTEGER info, lda, m, n, ldt
123* ..
124* .. Array Arguments ..
125 REAL a( lda, * ), t( ldt, * )
126* ..
127*
128* =====================================================================
129*
130* .. Parameters ..
131 REAL one
132 parameter( one = 1.0e+00 )
133* ..
134* .. Local Scalars ..
135 INTEGER i, i1, j, j1, m1, m2, iinfo
136* ..
137* .. External Subroutines ..
138 EXTERNAL slarfg, strmm, sgemm, xerbla
139* ..
140* .. Executable Statements ..
141*
142 info = 0
143 IF( m .LT. 0 ) THEN
144 info = -1
145 ELSE IF( n .LT. m ) THEN
146 info = -2
147 ELSE IF( lda .LT. max( 1, m ) ) THEN
148 info = -4
149 ELSE IF( ldt .LT. max( 1, m ) ) THEN
150 info = -6
151 END IF
152 IF( info.NE.0 ) THEN
153 CALL xerbla( 'SGELQT3', -info )
154 RETURN
155 END IF
156*
157 IF( m.EQ.1 ) THEN
158*
159* Compute Householder transform when M=1
160*
161 CALL slarfg( n, a, a( 1, min( 2, n ) ), lda, t )
162*
163 ELSE
164*
165* Otherwise, split A into blocks...
166*
167 m1 = m/2
168 m2 = m-m1
169 i1 = min( m1+1, m )
170 j1 = min( m+1, n )
171*
172* Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
173*
174 CALL sgelqt3( m1, n, a, lda, t, ldt, iinfo )
175*
176* Compute A(J1:M,1:N) = Q1^H A(J1:M,1:N) [workspace: T(1:N1,J1:N)]
177*
178 DO i=1,m2
179 DO j=1,m1
180 t( i+m1, j ) = a( i+m1, j )
181 END DO
182 END DO
183 CALL strmm( 'R', 'U', 'T', 'U', m2, m1, one,
184 & a, lda, t( i1, 1 ), ldt )
185*
186 CALL sgemm( 'N', 'T', m2, m1, n-m1, one, a( i1, i1 ), lda,
187 & a( 1, i1 ), lda, one, t( i1, 1 ), ldt)
188*
189 CALL strmm( 'R', 'U', 'N', 'N', m2, m1, one,
190 & t, ldt, t( i1, 1 ), ldt )
191*
192 CALL sgemm( 'N', 'N', m2, n-m1, m1, -one, t( i1, 1 ), ldt,
193 & a( 1, i1 ), lda, one, a( i1, i1 ), lda )
194*
195 CALL strmm( 'R', 'U', 'N', 'U', m2, m1 , one,
196 & a, lda, t( i1, 1 ), ldt )
197*
198 DO i=1,m2
199 DO j=1,m1
200 a( i+m1, j ) = a( i+m1, j ) - t( i+m1, j )
201 t( i+m1, j )=0
202 END DO
203 END DO
204*
205* Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
206*
207 CALL sgelqt3( m2, n-m1, a( i1, i1 ), lda,
208 & t( i1, i1 ), ldt, iinfo )
209*
210* Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
211*
212 DO i=1,m2
213 DO j=1,m1
214 t( j, i+m1 ) = (a( j, i+m1 ))
215 END DO
216 END DO
217*
218 CALL strmm( 'R', 'U', 'T', 'U', m1, m2, one,
219 & a( i1, i1 ), lda, t( 1, i1 ), ldt )
220*
221 CALL sgemm( 'N', 'T', m1, m2, n-m, one, a( 1, j1 ), lda,
222 & a( i1, j1 ), lda, one, t( 1, i1 ), ldt )
223*
224 CALL strmm( 'L', 'U', 'N', 'N', m1, m2, -one, t, ldt,
225 & t( 1, i1 ), ldt )
226*
227 CALL strmm( 'R', 'U', 'N', 'N', m1, m2, one,
228 & t( i1, i1 ), ldt, t( 1, i1 ), ldt )
229*
230*
231*
232* Y = (Y1,Y2); L = [ L1 0 ]; T = [T1 T3]
233* [ A(1:N1,J1:N) L2 ] [ 0 T2]
234*
235 END IF
236*
237 RETURN
238*
239* End of SGELQT3
240*
241 END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
recursive subroutine sgelqt3(M, N, A, LDA, T, LDT, INFO)
SGELQT3
Definition: sgelqt3.f:116
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:106
subroutine strmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
STRMM
Definition: strmm.f:177
subroutine sgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
SGEMM
Definition: sgemm.f:187