sorgtr()

subroutine sorgtr	(	character	uplo,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( * )	work,
		integer	lwork,
		integer	info
	)

SORGTR

Download SORGTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SORGTR generates a real orthogonal matrix Q which is defined as the
 product of n-1 elementary reflectors of order N, as returned by
 SSYTRD:

 if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),

 if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A contains elementary reflectors from SSYTRD; = 'L': Lower triangle of A contains elementary reflectors from SSYTRD.
[in]	N	N is INTEGER The order of the matrix Q. N >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the vectors which define the elementary reflectors, as returned by SSYTRD. On exit, the N-by-N orthogonal matrix Q.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	TAU	TAU is REAL array, dimension (N-1) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SSYTRD.
[out]	WORK	WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,N-1). For optimum performance LWORK >= (N-1)*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 122 of file sorgtr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, LWORK, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      INTEGER            I, IINFO, J, LWKOPT, NB
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, lsame, sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sorgql, sorgqr, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( lwork.LT.max( 1, n-1 ) .AND. .NOT.lquery ) THEN
         info = -7
      END IF
*
      IF( info.EQ.0 ) THEN
         IF ( upper ) THEN
           nb = ilaenv( 1, 'SORGQL', ' ', n-1, n-1, n-1, -1 )
         ELSE
           nb = ilaenv( 1, 'SORGQR', ' ', n-1, n-1, n-1, -1 )
         END IF
         lwkopt = max( 1, n-1 )*nb
         work( 1 ) = sroundup_lwork(lwkopt)
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORGTR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
      IF( upper ) THEN
*
*        Q was determined by a call to SSYTRD with UPLO = 'U'
*
*        Shift the vectors which define the elementary reflectors one
*        column to the left, and set the last row and column of Q to
*        those of the unit matrix
*
         DO 20 j = 1, n - 1
            DO 10 i = 1, j - 1
               a( i, j ) = a( i, j+1 )
   10       CONTINUE
            a( n, j ) = zero
   20    CONTINUE
         DO 30 i = 1, n - 1
            a( i, n ) = zero
   30    CONTINUE
         a( n, n ) = one
*
*        Generate Q(1:n-1,1:n-1)
*
         CALL sorgql( n-1, n-1, n-1, a, lda, tau, work, lwork, iinfo )
*
      ELSE
*
*        Q was determined by a call to SSYTRD with UPLO = 'L'.
*
*        Shift the vectors which define the elementary reflectors one
*        column to the right, and set the first row and column of Q to
*        those of the unit matrix
*
         DO 50 j = n, 2, -1
            a( 1, j ) = zero
            DO 40 i = j + 1, n
               a( i, j ) = a( i, j-1 )
   40       CONTINUE
   50    CONTINUE
         a( 1, 1 ) = one
         DO 60 i = 2, n
            a( i, 1 ) = zero
   60    CONTINUE
         IF( n.GT.1 ) THEN
*
*           Generate Q(2:n,2:n)
*
            CALL sorgqr( n-1, n-1, n-1, a( 2, 2 ), lda, tau, work,
     $                   lwork, iinfo )
         END IF
      END IF
      work( 1 ) = sroundup_lwork(lwkopt)
      RETURN
*
*     End of SORGTR
*

Here is the call graph for this function:

Here is the caller graph for this function: