double precision function dznrm2	(	integer	N,
		complex*16, dimension(*)	X,
		integer	INCX
	)

DZNRM2

Purpose:

 DZNRM2 returns the euclidean norm of a vector via the function
 name, so that

    DZNRM2 := sqrt( x**H*x )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Further Details:

  -- This version written on 25-October-1982.
     Modified on 14-October-1993 to inline the call to ZLASSQ.
     Sven Hammarling, Nag Ltd.

Definition at line 56 of file dznrm2.f.

*
*  -- Reference BLAS level1 routine (version 3.4.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER incx,n
*     ..
*     .. Array Arguments ..
      COMPLEX*16 x(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION one,zero
      parameter(one=1.0d+0,zero=0.0d+0)
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION norm,scale,ssq,temp
      INTEGER ix
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs,dble,dimag,sqrt
*     ..
      IF (n.LT.1 .OR. incx.LT.1) THEN
          norm = zero
      ELSE
          scale = zero
          ssq = one
*        The following loop is equivalent to this call to the LAPACK
*        auxiliary routine:
*        CALL ZLASSQ( N, X, INCX, SCALE, SSQ )
*
          DO 10 ix = 1,1 + (n-1)*incx,incx
              IF (dble(x(ix)).NE.zero) THEN
                  temp = abs(dble(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
              IF (dimag(x(ix)).NE.zero) THEN
                  temp = abs(dimag(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
   10     CONTINUE
          norm = scale*sqrt(ssq)
      END IF
*
      dznrm2 = norm
      RETURN
*
*     End of DZNRM2.
*

Here is the caller graph for this function: