real function sqrt11	(	integer	M,
		integer	K,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( lwork )	WORK,
		integer	LWORK
	)

SQRT11

Purpose:

 SQRT11 computes the test ratio

       || Q'*Q - I || / (eps * m)

 where the orthogonal matrix Q is represented as a product of
 elementary transformations.  Each transformation has the form

    H(k) = I - tau(k) v(k) v(k)'

 where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
 [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
 in A(k+1:m,k).

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	K	K is INTEGER The number of columns of A whose subdiagonal entries contain information about orthogonal transformations.
[in]	A	A is REAL array, dimension (LDA,K) The (possibly partial) output of a QR reduction routine.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	TAU	TAU is REAL array, dimension (K) The scaling factors tau for the elementary transformations as computed by the QR factorization routine.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*M + M.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 100 of file sqrt11.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, sorm2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Local Arrays ..
      REAL               rdummy( 1 )
*     ..
*     .. Executable Statements ..
*
      sqrt11 = zero
*
*     Test for sufficient workspace
*
      IF( lwork.LT.m*m+m ) THEN
         CALL xerbla( 'SQRT11', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      CALL slaset( 'Full', m, m, zero, one, work, m )
*
*     Form Q
*
      CALL sorm2r( 'Left', 'No transpose', m, m, k, a, lda, tau, work,
     $             m, work( m*m+1 ), info )
*
*     Form Q'*Q
*
      CALL sorm2r( 'Left', 'Transpose', m, m, k, a, lda, tau, work, m,
     $             work( m*m+1 ), info )
*
      DO 10 j = 1, m
         work( ( j-1 )*m+j ) = work( ( j-1 )*m+j ) - one
   10 CONTINUE
*
      sqrt11 = slange( 'One-norm', m, m, work, m, rdummy ) /
     $         ( REAL( m )*slamch( 'Epsilon' ) )
*
      RETURN
*
*     End of SQRT11
*

Here is the call graph for this function: