subroutine sqlt02	(	integer	M,
		integer	N,
		integer	K,
		real, dimension( lda, * )	A,
		real, dimension( lda, * )	AF,
		real, dimension( lda, * )	Q,
		real, dimension( lda, * )	L,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( * )	RWORK,
		real, dimension( * )	RESULT
	)

SQLT02

Purpose:

 SQLT02 tests SORGQL, which generates an m-by-n matrix Q with
 orthonornmal columns that is defined as the product of k elementary
 reflectors.

 Given the QL factorization of an m-by-n matrix A, SQLT02 generates
 the orthogonal matrix Q defined by the factorization of the last k
 columns of A; it compares L(m-n+1:m,n-k+1:n) with
 Q(1:m,m-n+1:m)'*A(1:m,n-k+1:n), and checks that the columns of Q are
 orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The m-by-n matrix A which was factorized by SQLT01.
[in]	AF	AF is REAL array, dimension (LDA,N) Details of the QL factorization of A, as returned by SGEQLF. See SGEQLF for further details.
[out]	Q	Q is REAL array, dimension (LDA,N)
[out]	L	L is REAL array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= M.
[in]	TAU	TAU is REAL array, dimension (N) The scalar factors of the elementary reflectors corresponding to the QL factorization in AF.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 138 of file sqlt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), result( * ), rwork( * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      REAL               rogue
      parameter                ( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               slamch, slange, slansy
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slaset, sorgql, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
*
*     Copy the last k columns of the factorization to the array Q
*
      CALL slaset( 'Full', m, n, rogue, rogue, q, lda )
      IF( k.LT.m )
     $   CALL slacpy( 'Full', m-k, k, af( 1, n-k+1 ), lda,
     $                q( 1, n-k+1 ), lda )
      IF( k.GT.1 )
     $   CALL slacpy( 'Upper', k-1, k-1, af( m-k+1, n-k+2 ), lda,
     $                q( m-k+1, n-k+2 ), lda )
*
*     Generate the last n columns of the matrix Q
*
      srnamt = 'SORGQL'
      CALL sorgql( m, n, k, q, lda, tau( n-k+1 ), work, lwork, info )
*
*     Copy L(m-n+1:m,n-k+1:n)
*
      CALL slaset( 'Full', n, k, zero, zero, l( m-n+1, n-k+1 ), lda )
      CALL slacpy( 'Lower', k, k, af( m-k+1, n-k+1 ), lda,
     $             l( m-k+1, n-k+1 ), lda )
*
*     Compute L(m-n+1:m,n-k+1:n) - Q(1:m,m-n+1:m)' * A(1:m,n-k+1:n)
*
      CALL sgemm( 'Transpose', 'No transpose', n, k, m, -one, q, lda,
     $            a( 1, n-k+1 ), lda, one, l( m-n+1, n-k+1 ), lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = slange( '1', m, k, a( 1, n-k+1 ), lda, rwork )
      resid = slange( '1', n, k, l( m-n+1, n-k+1 ), lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, M ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL slaset( 'Full', n, n, zero, one, l, lda )
      CALL ssyrk( 'Upper', 'Transpose', n, m, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = slansy( '1', 'Upper', n, l, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, M ) ) ) / eps
*
      RETURN
*
*     End of SQLT02
*

Here is the call graph for this function:

Here is the caller graph for this function: