slakf2.f

Go to the documentation of this file.

*> \brief \b SLAKF2
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAKF2( M, N, A, LDA, B, D, E, Z, LDZ )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDZ, M, N
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), B( LDA, * ), D( LDA, * ),
*      $                   E( LDA, * ), Z( LDZ, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> Form the 2*M*N by 2*M*N matrix
*>
*>        Z = [ kron(In, A)  -kron(B', Im) ]
*>            [ kron(In, D)  -kron(E', Im) ],
*>
*> where In is the identity matrix of size n and X' is the transpose
*> of X. kron(X, Y) is the Kronecker product between the matrices X
*> and Y.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Size of matrix, must be >= 1.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Size of matrix, must be >= 1.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL, dimension ( LDA, M )
*>          The matrix A in the output matrix Z.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, B, D, and E. ( LDA >= M+N )
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is REAL, dimension ( LDA, N )
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL, dimension ( LDA, M )
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is REAL, dimension ( LDA, N )
*>
*>          The matrices used in forming the output matrix Z.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is REAL, dimension ( LDZ, 2*M*N )
*>          The resultant Kronecker M*N*2 by M*N*2 matrix (see above.)
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of Z. ( LDZ >= 2*M*N )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup real_matgen
*
*  =====================================================================
      SUBROUTINE slakf2( M, N, A, LDA, B, D, E, Z, LDZ )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDZ, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( lda, * ), B( lda, * ), D( lda, * ),
     $                   e( lda, * ), z( ldz, * )
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter                ( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IK, J, JK, L, MN, MN2
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset
*     ..
*     .. Executable Statements ..
*
*     Initialize Z
*
      mn = m*n
      mn2 = 2*mn
      CALL slaset( 'Full', mn2, mn2, zero, zero, z, ldz )
*
      ik = 1
      DO 50 l = 1, n
*
*        form kron(In, A)
*
         DO 20 i = 1, m
            DO 10 j = 1, m
               z( ik+i-1, ik+j-1 ) = a( i, j )
   10       CONTINUE
   20    CONTINUE
*
*        form kron(In, D)
*
         DO 40 i = 1, m
            DO 30 j = 1, m
               z( ik+mn+i-1, ik+j-1 ) = d( i, j )
   30       CONTINUE
   40    CONTINUE
*
         ik = ik + m
   50 CONTINUE
*
      ik = 1
      DO 90 l = 1, n
         jk = mn + 1
*
         DO 80 j = 1, n
*
*           form -kron(B', Im)
*
            DO 60 i = 1, m
               z( ik+i-1, jk+i-1 ) = -b( j, l )
   60       CONTINUE
*
*           form -kron(E', Im)
*
            DO 70 i = 1, m
               z( ik+mn+i-1, jk+i-1 ) = -e( j, l )
   70       CONTINUE
*
            jk = jk + m
   80    CONTINUE
*
         ik = ik + m
   90 CONTINUE
*
      RETURN
*
*     End of SLAKF2
*
      END