slagsy.f

Go to the documentation of this file.

*> \brief \b SLAGSY
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAGSY( N, K, D, A, LDA, ISEED, WORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, K, LDA, N
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       REAL               A( LDA, * ), D( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLAGSY generates a real symmetric matrix A, by pre- and post-
*> multiplying a real diagonal matrix D with a random orthogonal matrix:
*> A = U*D*U'. The semi-bandwidth may then be reduced to k by additional
*> orthogonal transformations.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of nonzero subdiagonals within the band of A.
*>          0 <= K <= N-1.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>          The diagonal elements of the diagonal matrix D.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          The generated n by n symmetric matrix A (the full matrix is
*>          stored).
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= N.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry, the seed of the random number generator; the array
*>          elements must be between 0 and 4095, and ISEED(4) must be
*>          odd.
*>          On exit, the seed is updated.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup real_matgen
*
*  =====================================================================
      SUBROUTINE slagsy( N, K, D, A, LDA, ISEED, WORK, INFO )
*
*  -- LAPACK auxiliary routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               A( lda, * ), D( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, HALF
      parameter                ( zero = 0.0e+0, one = 1.0e+0, half = 0.5e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               ALPHA, TAU, WA, WB, WN
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, sgemv, sger, slarnv, sscal, ssymv,
     $                   ssyr2, xerbla
*     ..
*     .. External Functions ..
      REAL               SDOT, SNRM2
      EXTERNAL           sdot, snrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sign
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( k.LT.0 .OR. k.GT.n-1 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'SLAGSY', -info )
         RETURN
      END IF
*
*     initialize lower triangle of A to diagonal matrix
*
      DO 20 j = 1, n
         DO 10 i = j + 1, n
            a( i, j ) = zero
   10    CONTINUE
   20 CONTINUE
      DO 30 i = 1, n
         a( i, i ) = d( i )
   30 CONTINUE
*
*     Generate lower triangle of symmetric matrix
*
      DO 40 i = n - 1, 1, -1
*
*        generate random reflection
*
         CALL slarnv( 3, iseed, n-i+1, work )
         wn = snrm2( n-i+1, work, 1 )
         wa = sign( wn, work( 1 ) )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = work( 1 ) + wa
            CALL sscal( n-i, one / wb, work( 2 ), 1 )
            work( 1 ) = one
            tau = wb / wa
         END IF
*
*        apply random reflection to A(i:n,i:n) from the left
*        and the right
*
*        compute  y := tau * A * u
*
         CALL ssymv( 'Lower', n-i+1, tau, a( i, i ), lda, work, 1, zero,
     $               work( n+1 ), 1 )
*
*        compute  v := y - 1/2 * tau * ( y, u ) * u
*
         alpha = -half*tau*sdot( n-i+1, work( n+1 ), 1, work, 1 )
         CALL saxpy( n-i+1, alpha, work, 1, work( n+1 ), 1 )
*
*        apply the transformation as a rank-2 update to A(i:n,i:n)
*
         CALL ssyr2( 'Lower', n-i+1, -one, work, 1, work( n+1 ), 1,
     $               a( i, i ), lda )
   40 CONTINUE
*
*     Reduce number of subdiagonals to K
*
      DO 60 i = 1, n - 1 - k
*
*        generate reflection to annihilate A(k+i+1:n,i)
*
         wn = snrm2( n-k-i+1, a( k+i, i ), 1 )
         wa = sign( wn, a( k+i, i ) )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = a( k+i, i ) + wa
            CALL sscal( n-k-i, one / wb, a( k+i+1, i ), 1 )
            a( k+i, i ) = one
            tau = wb / wa
         END IF
*
*        apply reflection to A(k+i:n,i+1:k+i-1) from the left
*
         CALL sgemv( 'Transpose', n-k-i+1, k-1, one, a( k+i, i+1 ), lda,
     $               a( k+i, i ), 1, zero, work, 1 )
         CALL sger( n-k-i+1, k-1, -tau, a( k+i, i ), 1, work, 1,
     $              a( k+i, i+1 ), lda )
*
*        apply reflection to A(k+i:n,k+i:n) from the left and the right
*
*        compute  y := tau * A * u
*
         CALL ssymv( 'Lower', n-k-i+1, tau, a( k+i, k+i ), lda,
     $               a( k+i, i ), 1, zero, work, 1 )
*
*        compute  v := y - 1/2 * tau * ( y, u ) * u
*
         alpha = -half*tau*sdot( n-k-i+1, work, 1, a( k+i, i ), 1 )
         CALL saxpy( n-k-i+1, alpha, a( k+i, i ), 1, work, 1 )
*
*        apply symmetric rank-2 update to A(k+i:n,k+i:n)
*
         CALL ssyr2( 'Lower', n-k-i+1, -one, a( k+i, i ), 1, work, 1,
     $               a( k+i, k+i ), lda )
*
         a( k+i, i ) = -wa
         DO 50 j = k + i + 1, n
            a( j, i ) = zero
   50    CONTINUE
   60 CONTINUE
*
*     Store full symmetric matrix
*
      DO 80 j = 1, n
         DO 70 i = j + 1, n
            a( j, i ) = a( i, j )
   70    CONTINUE
   80 CONTINUE
      RETURN
*
*     End of SLAGSY
*
      END