slals0.f

Go to the documentation of this file.

*> \brief \b SLALS0 applies back multiplying factors in solving the least squares problem using divide and conquer SVD approach. Used by sgelsd.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download SLALS0 + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slals0.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slals0.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slals0.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLALS0( ICOMPQ, NL, NR, SQRE, NRHS, B, LDB, BX, LDBX,
*                          PERM, GIVPTR, GIVCOL, LDGCOL, GIVNUM, LDGNUM,
*                          POLES, DIFL, DIFR, Z, K, C, S, WORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            GIVPTR, ICOMPQ, INFO, K, LDB, LDBX, LDGCOL,
*      $                   LDGNUM, NL, NR, NRHS, SQRE
*       REAL               C, S
*       ..
*       .. Array Arguments ..
*       INTEGER            GIVCOL( LDGCOL, * ), PERM( * )
*       REAL               B( LDB, * ), BX( LDBX, * ), DIFL( * ),
*      $                   DIFR( LDGNUM, * ), GIVNUM( LDGNUM, * ),
*      $                   POLES( LDGNUM, * ), WORK( * ), Z( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLALS0 applies back the multiplying factors of either the left or the
*> right singular vector matrix of a diagonal matrix appended by a row
*> to the right hand side matrix B in solving the least squares problem
*> using the divide-and-conquer SVD approach.
*>
*> For the left singular vector matrix, three types of orthogonal
*> matrices are involved:
*>
*> (1L) Givens rotations: the number of such rotations is GIVPTR; the
*>      pairs of columns/rows they were applied to are stored in GIVCOL;
*>      and the C- and S-values of these rotations are stored in GIVNUM.
*>
*> (2L) Permutation. The (NL+1)-st row of B is to be moved to the first
*>      row, and for J=2:N, PERM(J)-th row of B is to be moved to the
*>      J-th row.
*>
*> (3L) The left singular vector matrix of the remaining matrix.
*>
*> For the right singular vector matrix, four types of orthogonal
*> matrices are involved:
*>
*> (1R) The right singular vector matrix of the remaining matrix.
*>
*> (2R) If SQRE = 1, one extra Givens rotation to generate the right
*>      null space.
*>
*> (3R) The inverse transformation of (2L).
*>
*> (4R) The inverse transformation of (1L).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ICOMPQ
*> \verbatim
*>          ICOMPQ is INTEGER
*>         Specifies whether singular vectors are to be computed in
*>         factored form:
*>         = 0: Left singular vector matrix.
*>         = 1: Right singular vector matrix.
*> \endverbatim
*>
*> \param[in] NL
*> \verbatim
*>          NL is INTEGER
*>         The row dimension of the upper block. NL >= 1.
*> \endverbatim
*>
*> \param[in] NR
*> \verbatim
*>          NR is INTEGER
*>         The row dimension of the lower block. NR >= 1.
*> \endverbatim
*>
*> \param[in] SQRE
*> \verbatim
*>          SQRE is INTEGER
*>         = 0: the lower block is an NR-by-NR square matrix.
*>         = 1: the lower block is an NR-by-(NR+1) rectangular matrix.
*>
*>         The bidiagonal matrix has row dimension N = NL + NR + 1,
*>         and column dimension M = N + SQRE.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>         The number of columns of B and BX. NRHS must be at least 1.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension ( LDB, NRHS )
*>         On input, B contains the right hand sides of the least
*>         squares problem in rows 1 through M. On output, B contains
*>         the solution X in rows 1 through N.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>         The leading dimension of B. LDB must be at least
*>         max(1,MAX( M, N ) ).
*> \endverbatim
*>
*> \param[out] BX
*> \verbatim
*>          BX is REAL array, dimension ( LDBX, NRHS )
*> \endverbatim
*>
*> \param[in] LDBX
*> \verbatim
*>          LDBX is INTEGER
*>         The leading dimension of BX.
*> \endverbatim
*>
*> \param[in] PERM
*> \verbatim
*>          PERM is INTEGER array, dimension ( N )
*>         The permutations (from deflation and sorting) applied
*>         to the two blocks.
*> \endverbatim
*>
*> \param[in] GIVPTR
*> \verbatim
*>          GIVPTR is INTEGER
*>         The number of Givens rotations which took place in this
*>         subproblem.
*> \endverbatim
*>
*> \param[in] GIVCOL
*> \verbatim
*>          GIVCOL is INTEGER array, dimension ( LDGCOL, 2 )
*>         Each pair of numbers indicates a pair of rows/columns
*>         involved in a Givens rotation.
*> \endverbatim
*>
*> \param[in] LDGCOL
*> \verbatim
*>          LDGCOL is INTEGER
*>         The leading dimension of GIVCOL, must be at least N.
*> \endverbatim
*>
*> \param[in] GIVNUM
*> \verbatim
*>          GIVNUM is REAL array, dimension ( LDGNUM, 2 )
*>         Each number indicates the C or S value used in the
*>         corresponding Givens rotation.
*> \endverbatim
*>
*> \param[in] LDGNUM
*> \verbatim
*>          LDGNUM is INTEGER
*>         The leading dimension of arrays DIFR, POLES and
*>         GIVNUM, must be at least K.
*> \endverbatim
*>
*> \param[in] POLES
*> \verbatim
*>          POLES is REAL array, dimension ( LDGNUM, 2 )
*>         On entry, POLES(1:K, 1) contains the new singular
*>         values obtained from solving the secular equation, and
*>         POLES(1:K, 2) is an array containing the poles in the secular
*>         equation.
*> \endverbatim
*>
*> \param[in] DIFL
*> \verbatim
*>          DIFL is REAL array, dimension ( K ).
*>         On entry, DIFL(I) is the distance between I-th updated
*>         (undeflated) singular value and the I-th (undeflated) old
*>         singular value.
*> \endverbatim
*>
*> \param[in] DIFR
*> \verbatim
*>          DIFR is REAL array, dimension ( LDGNUM, 2 ).
*>         On entry, DIFR(I, 1) contains the distances between I-th
*>         updated (undeflated) singular value and the I+1-th
*>         (undeflated) old singular value. And DIFR(I, 2) is the
*>         normalizing factor for the I-th right singular vector.
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is REAL array, dimension ( K )
*>         Contain the components of the deflation-adjusted updating row
*>         vector.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>         Contains the dimension of the non-deflated matrix,
*>         This is the order of the related secular equation. 1 <= K <=N.
*> \endverbatim
*>
*> \param[in] C
*> \verbatim
*>          C is REAL
*>         C contains garbage if SQRE =0 and the C-value of a Givens
*>         rotation related to the right null space if SQRE = 1.
*> \endverbatim
*>
*> \param[in] S
*> \verbatim
*>          S is REAL
*>         S contains garbage if SQRE =0 and the S-value of a Givens
*>         rotation related to the right null space if SQRE = 1.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension ( K )
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2015
*
*> \ingroup realOTHERcomputational
*
*> \par Contributors:
*  ==================
*>
*>     Ming Gu and Ren-Cang Li, Computer Science Division, University of
*>       California at Berkeley, USA \n
*>     Osni Marques, LBNL/NERSC, USA \n
*
*  =====================================================================
      SUBROUTINE slals0( ICOMPQ, NL, NR, SQRE, NRHS, B, LDB, BX, LDBX,
     $                   perm, givptr, givcol, ldgcol, givnum, ldgnum,
     $                   poles, difl, difr, z, k, c, s, work, info )
*
*  -- LAPACK computational routine (version 3.6.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2015
*
*     .. Scalar Arguments ..
      INTEGER            GIVPTR, ICOMPQ, INFO, K, LDB, LDBX, LDGCOL,
     $                   ldgnum, nl, nr, nrhs, sqre
      REAL               C, S
*     ..
*     .. Array Arguments ..
      INTEGER            GIVCOL( ldgcol, * ), PERM( * )
      REAL               B( ldb, * ), BX( ldbx, * ), DIFL( * ),
     $                   difr( ldgnum, * ), givnum( ldgnum, * ),
     $                   poles( ldgnum, * ), work( * ), z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO, NEGONE
      parameter                ( one = 1.0e0, zero = 0.0e0, negone = -1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, M, N, NLP1
      REAL               DIFLJ, DIFRJ, DJ, DSIGJ, DSIGJP, TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           scopy, sgemv, slacpy, slascl, srot, sscal,
     $                   xerbla
*     ..
*     .. External Functions ..
      REAL               SLAMC3, SNRM2
      EXTERNAL           slamc3, snrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      n = nl + nr + 1
*
      IF( ( icompq.LT.0 ) .OR. ( icompq.GT.1 ) ) THEN
         info = -1
      ELSE IF( nl.LT.1 ) THEN
         info = -2
      ELSE IF( nr.LT.1 ) THEN
         info = -3
      ELSE IF( ( sqre.LT.0 ) .OR. ( sqre.GT.1 ) ) THEN
         info = -4
      ELSE IF( nrhs.LT.1 ) THEN
         info = -5
      ELSE IF( ldb.LT.n ) THEN
         info = -7
      ELSE IF( ldbx.LT.n ) THEN
         info = -9
      ELSE IF( givptr.LT.0 ) THEN
         info = -11
      ELSE IF( ldgcol.LT.n ) THEN
         info = -13
      ELSE IF( ldgnum.LT.n ) THEN
         info = -15
      ELSE IF( k.LT.1 ) THEN
         info = -20
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLALS0', -info )
         RETURN
      END IF
*
      m = n + sqre
      nlp1 = nl + 1
*
      IF( icompq.EQ.0 ) THEN
*
*        Apply back orthogonal transformations from the left.
*
*        Step (1L): apply back the Givens rotations performed.
*
         DO 10 i = 1, givptr
            CALL srot( nrhs, b( givcol( i, 2 ), 1 ), ldb,
     $                 b( givcol( i, 1 ), 1 ), ldb, givnum( i, 2 ),
     $                 givnum( i, 1 ) )
   10    CONTINUE
*
*        Step (2L): permute rows of B.
*
         CALL scopy( nrhs, b( nlp1, 1 ), ldb, bx( 1, 1 ), ldbx )
         DO 20 i = 2, n
            CALL scopy( nrhs, b( perm( i ), 1 ), ldb, bx( i, 1 ), ldbx )
   20    CONTINUE
*
*        Step (3L): apply the inverse of the left singular vector
*        matrix to BX.
*
         IF( k.EQ.1 ) THEN
            CALL scopy( nrhs, bx, ldbx, b, ldb )
            IF( z( 1 ).LT.zero ) THEN
               CALL sscal( nrhs, negone, b, ldb )
            END IF
         ELSE
            DO 50 j = 1, k
               diflj = difl( j )
               dj = poles( j, 1 )
               dsigj = -poles( j, 2 )
               IF( j.LT.k ) THEN
                  difrj = -difr( j, 1 )
                  dsigjp = -poles( j+1, 2 )
               END IF
               IF( ( z( j ).EQ.zero ) .OR. ( poles( j, 2 ).EQ.zero ) )
     $              THEN
                  work( j ) = zero
               ELSE
                  work( j ) = -poles( j, 2 )*z( j ) / diflj /
     $                        ( poles( j, 2 )+dj )
               END IF
               DO 30 i = 1, j - 1
                  IF( ( z( i ).EQ.zero ) .OR.
     $                ( poles( i, 2 ).EQ.zero ) ) THEN
                     work( i ) = zero
                  ELSE
                     work( i ) = poles( i, 2 )*z( i ) /
     $                           ( slamc3( poles( i, 2 ), dsigj )-
     $                           diflj ) / ( poles( i, 2 )+dj )
                  END IF
   30          CONTINUE
               DO 40 i = j + 1, k
                  IF( ( z( i ).EQ.zero ) .OR.
     $                ( poles( i, 2 ).EQ.zero ) ) THEN
                     work( i ) = zero
                  ELSE
                     work( i ) = poles( i, 2 )*z( i ) /
     $                           ( slamc3( poles( i, 2 ), dsigjp )+
     $                           difrj ) / ( poles( i, 2 )+dj )
                  END IF
   40          CONTINUE
               work( 1 ) = negone
               temp = snrm2( k, work, 1 )
               CALL sgemv( 'T', k, nrhs, one, bx, ldbx, work, 1, zero,
     $                     b( j, 1 ), ldb )
               CALL slascl( 'G', 0, 0, temp, one, 1, nrhs, b( j, 1 ),
     $                      ldb, info )
   50       CONTINUE
         END IF
*
*        Move the deflated rows of BX to B also.
*
         IF( k.LT.max( m, n ) )
     $      CALL slacpy( 'A', n-k, nrhs, bx( k+1, 1 ), ldbx,
     $                   b( k+1, 1 ), ldb )
      ELSE
*
*        Apply back the right orthogonal transformations.
*
*        Step (1R): apply back the new right singular vector matrix
*        to B.
*
         IF( k.EQ.1 ) THEN
            CALL scopy( nrhs, b, ldb, bx, ldbx )
         ELSE
            DO 80 j = 1, k
               dsigj = poles( j, 2 )
               IF( z( j ).EQ.zero ) THEN
                  work( j ) = zero
               ELSE
                  work( j ) = -z( j ) / difl( j ) /
     $                        ( dsigj+poles( j, 1 ) ) / difr( j, 2 )
               END IF
               DO 60 i = 1, j - 1
                  IF( z( j ).EQ.zero ) THEN
                     work( i ) = zero
                  ELSE
                     work( i ) = z( j ) / ( slamc3( dsigj, -poles( i+1,
     $                           2 ) )-difr( i, 1 ) ) /
     $                           ( dsigj+poles( i, 1 ) ) / difr( i, 2 )
                  END IF
   60          CONTINUE
               DO 70 i = j + 1, k
                  IF( z( j ).EQ.zero ) THEN
                     work( i ) = zero
                  ELSE
                     work( i ) = z( j ) / ( slamc3( dsigj, -poles( i,
     $                           2 ) )-difl( i ) ) /
     $                           ( dsigj+poles( i, 1 ) ) / difr( i, 2 )
                  END IF
   70          CONTINUE
               CALL sgemv( 'T', k, nrhs, one, b, ldb, work, 1, zero,
     $                     bx( j, 1 ), ldbx )
   80       CONTINUE
         END IF
*
*        Step (2R): if SQRE = 1, apply back the rotation that is
*        related to the right null space of the subproblem.
*
         IF( sqre.EQ.1 ) THEN
            CALL scopy( nrhs, b( m, 1 ), ldb, bx( m, 1 ), ldbx )
            CALL srot( nrhs, bx( 1, 1 ), ldbx, bx( m, 1 ), ldbx, c, s )
         END IF
         IF( k.LT.max( m, n ) )
     $      CALL slacpy( 'A', n-k, nrhs, b( k+1, 1 ), ldb, bx( k+1, 1 ),
     $                   ldbx )
*
*        Step (3R): permute rows of B.
*
         CALL scopy( nrhs, bx( 1, 1 ), ldbx, b( nlp1, 1 ), ldb )
         IF( sqre.EQ.1 ) THEN
            CALL scopy( nrhs, bx( m, 1 ), ldbx, b( m, 1 ), ldb )
         END IF
         DO 90 i = 2, n
            CALL scopy( nrhs, bx( i, 1 ), ldbx, b( perm( i ), 1 ), ldb )
   90    CONTINUE
*
*        Step (4R): apply back the Givens rotations performed.
*
         DO 100 i = givptr, 1, -1
            CALL srot( nrhs, b( givcol( i, 2 ), 1 ), ldb,
     $                 b( givcol( i, 1 ), 1 ), ldb, givnum( i, 2 ),
     $                 -givnum( i, 1 ) )
  100    CONTINUE
      END IF
*
      RETURN
*
*     End of SLALS0
*
      END