subroutine zlaqr2	(	logical	WANTT,
		logical	WANTZ,
		integer	N,
		integer	KTOP,
		integer	KBOT,
		integer	NW,
		complex*16, dimension( ldh, * )	H,
		integer	LDH,
		integer	ILOZ,
		integer	IHIZ,
		complex*16, dimension( ldz, * )	Z,
		integer	LDZ,
		integer	NS,
		integer	ND,
		complex*16, dimension( * )	SH,
		complex*16, dimension( ldv, * )	V,
		integer	LDV,
		integer	NH,
		complex*16, dimension( ldt, * )	T,
		integer	LDT,
		integer	NV,
		complex*16, dimension( ldwv, * )	WV,
		integer	LDWV,
		complex*16, dimension( * )	WORK,
		integer	LWORK
	)

ZLAQR2 performs the unitary similarity transformation of a Hessenberg matrix to detect and deflate fully converged eigenvalues from a trailing principal submatrix (aggressive early deflation).

Download ZLAQR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

    ZLAQR2 is identical to ZLAQR3 except that it avoids
    recursion by calling ZLAHQR instead of ZLAQR4.

    Aggressive early deflation:

    ZLAQR2 accepts as input an upper Hessenberg matrix
    H and performs an unitary similarity transformation
    designed to detect and deflate fully converged eigenvalues from
    a trailing principal submatrix.  On output H has been over-
    written by a new Hessenberg matrix that is a perturbation of
    an unitary similarity transformation of H.  It is to be
    hoped that the final version of H has many zero subdiagonal
    entries.

Parameters

[in]	WANTT	WANTT is LOGICAL If .TRUE., then the Hessenberg matrix H is fully updated so that the triangular Schur factor may be computed (in cooperation with the calling subroutine). If .FALSE., then only enough of H is updated to preserve the eigenvalues.
[in]	WANTZ	WANTZ is LOGICAL If .TRUE., then the unitary matrix Z is updated so so that the unitary Schur factor may be computed (in cooperation with the calling subroutine). If .FALSE., then Z is not referenced.
[in]	N	N is INTEGER The order of the matrix H and (if WANTZ is .TRUE.) the order of the unitary matrix Z.
[in]	KTOP	KTOP is INTEGER It is assumed that either KTOP = 1 or H(KTOP,KTOP-1)=0. KBOT and KTOP together determine an isolated block along the diagonal of the Hessenberg matrix.
[in]	KBOT	KBOT is INTEGER It is assumed without a check that either KBOT = N or H(KBOT+1,KBOT)=0. KBOT and KTOP together determine an isolated block along the diagonal of the Hessenberg matrix.
[in]	NW	NW is INTEGER Deflation window size. 1 .LE. NW .LE. (KBOT-KTOP+1).
[in,out]	H	H is COMPLEX*16 array, dimension (LDH,N) On input the initial N-by-N section of H stores the Hessenberg matrix undergoing aggressive early deflation. On output H has been transformed by a unitary similarity transformation, perturbed, and the returned to Hessenberg form that (it is to be hoped) has some zero subdiagonal entries.
[in]	LDH	LDH is integer Leading dimension of H just as declared in the calling subroutine. N .LE. LDH
[in]	ILOZ	ILOZ is INTEGER
[in]	IHIZ	IHIZ is INTEGER Specify the rows of Z to which transformations must be applied if WANTZ is .TRUE.. 1 .LE. ILOZ .LE. IHIZ .LE. N.
[in,out]	Z	Z is COMPLEX*16 array, dimension (LDZ,N) IF WANTZ is .TRUE., then on output, the unitary similarity transformation mentioned above has been accumulated into Z(ILOZ:IHIZ,ILO:IHI) from the right. If WANTZ is .FALSE., then Z is unreferenced.
[in]	LDZ	LDZ is integer The leading dimension of Z just as declared in the calling subroutine. 1 .LE. LDZ.
[out]	NS	NS is integer The number of unconverged (ie approximate) eigenvalues returned in SR and SI that may be used as shifts by the calling subroutine.
[out]	ND	ND is integer The number of converged eigenvalues uncovered by this subroutine.
[out]	SH	SH is COMPLEX*16 array, dimension KBOT On output, approximate eigenvalues that may be used for shifts are stored in SH(KBOT-ND-NS+1) through SR(KBOT-ND). Converged eigenvalues are stored in SH(KBOT-ND+1) through SH(KBOT).
[out]	V	V is COMPLEX*16 array, dimension (LDV,NW) An NW-by-NW work array.
[in]	LDV	LDV is integer scalar The leading dimension of V just as declared in the calling subroutine. NW .LE. LDV
[in]	NH	NH is integer scalar The number of columns of T. NH.GE.NW.
[out]	T	T is COMPLEX*16 array, dimension (LDT,NW)
[in]	LDT	LDT is integer The leading dimension of T just as declared in the calling subroutine. NW .LE. LDT
[in]	NV	NV is integer The number of rows of work array WV available for workspace. NV.GE.NW.
[out]	WV	WV is COMPLEX*16 array, dimension (LDWV,NW)
[in]	LDWV	LDWV is integer The leading dimension of W just as declared in the calling subroutine. NW .LE. LDV
[out]	WORK	WORK is COMPLEX*16 array, dimension LWORK. On exit, WORK(1) is set to an estimate of the optimal value of LWORK for the given values of N, NW, KTOP and KBOT.
[in]	LWORK	LWORK is integer The dimension of the work array WORK. LWORK = 2*NW suffices, but greater efficiency may result from larger values of LWORK. If LWORK = -1, then a workspace query is assumed; ZLAQR2 only estimates the optimal workspace size for the given values of N, NW, KTOP and KBOT. The estimate is returned in WORK(1). No error message related to LWORK is issued by XERBLA. Neither H nor Z are accessed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Contributors:

Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA

Definition at line 272 of file zlaqr2.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            ihiz, iloz, kbot, ktop, ldh, ldt, ldv, ldwv,
     $                   ldz, lwork, n, nd, nh, ns, nv, nw
      LOGICAL            wantt, wantz
*     ..
*     .. Array Arguments ..
      COMPLEX*16         h( ldh, * ), sh( * ), t( ldt, * ), v( ldv, * ),
     $                   work( * ), wv( ldwv, * ), z( ldz, * )
*     ..
*
*  ================================================================
*
*     .. Parameters ..
      COMPLEX*16         zero, one
      parameter                ( zero = ( 0.0d0, 0.0d0 ),
     $                   one = ( 1.0d0, 0.0d0 ) )
      DOUBLE PRECISION   rzero, rone
      parameter                ( rzero = 0.0d0, rone = 1.0d0 )
*     ..
*     .. Local Scalars ..
      COMPLEX*16         beta, cdum, s, tau
      DOUBLE PRECISION   foo, safmax, safmin, smlnum, ulp
      INTEGER            i, ifst, ilst, info, infqr, j, jw, kcol, kln,
     $                   knt, krow, kwtop, ltop, lwk1, lwk2, lwkopt
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad, zcopy, zgehrd, zgemm, zlacpy, zlahqr,
     $                   zlarf, zlarfg, zlaset, ztrexc, zunmhr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dconjg, dimag, int, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
*     ==== Estimate optimal workspace. ====
*
      jw = min( nw, kbot-ktop+1 )
      IF( jw.LE.2 ) THEN
         lwkopt = 1
      ELSE
*
*        ==== Workspace query call to ZGEHRD ====
*
         CALL zgehrd( jw, 1, jw-1, t, ldt, work, work, -1, info )
         lwk1 = int( work( 1 ) )
*
*        ==== Workspace query call to ZUNMHR ====
*
         CALL zunmhr( 'R', 'N', jw, jw, 1, jw-1, t, ldt, work, v, ldv,
     $                work, -1, info )
         lwk2 = int( work( 1 ) )
*
*        ==== Optimal workspace ====
*
         lwkopt = jw + max( lwk1, lwk2 )
      END IF
*
*     ==== Quick return in case of workspace query. ====
*
      IF( lwork.EQ.-1 ) THEN
         work( 1 ) = dcmplx( lwkopt, 0 )
         RETURN
      END IF
*
*     ==== Nothing to do ...
*     ... for an empty active block ... ====
      ns = 0
      nd = 0
      work( 1 ) = one
      IF( ktop.GT.kbot )
     $   RETURN
*     ... nor for an empty deflation window. ====
      IF( nw.LT.1 )
     $   RETURN
*
*     ==== Machine constants ====
*
      safmin = dlamch( 'SAFE MINIMUM' )
      safmax = rone / safmin
      CALL dlabad( safmin, safmax )
      ulp = dlamch( 'PRECISION' )
      smlnum = safmin*( dble( n ) / ulp )
*
*     ==== Setup deflation window ====
*
      jw = min( nw, kbot-ktop+1 )
      kwtop = kbot - jw + 1
      IF( kwtop.EQ.ktop ) THEN
         s = zero
      ELSE
         s = h( kwtop, kwtop-1 )
      END IF
*
      IF( kbot.EQ.kwtop ) THEN
*
*        ==== 1-by-1 deflation window: not much to do ====
*
         sh( kwtop ) = h( kwtop, kwtop )
         ns = 1
         nd = 0
         IF( cabs1( s ).LE.max( smlnum, ulp*cabs1( h( kwtop,
     $       kwtop ) ) ) ) THEN
            ns = 0
            nd = 1
            IF( kwtop.GT.ktop )
     $         h( kwtop, kwtop-1 ) = zero
         END IF
         work( 1 ) = one
         RETURN
      END IF
*
*     ==== Convert to spike-triangular form.  (In case of a
*     .    rare QR failure, this routine continues to do
*     .    aggressive early deflation using that part of
*     .    the deflation window that converged using INFQR
*     .    here and there to keep track.) ====
*
      CALL zlacpy( 'U', jw, jw, h( kwtop, kwtop ), ldh, t, ldt )
      CALL zcopy( jw-1, h( kwtop+1, kwtop ), ldh+1, t( 2, 1 ), ldt+1 )
*
      CALL zlaset( 'A', jw, jw, zero, one, v, ldv )
      CALL zlahqr( .true., .true., jw, 1, jw, t, ldt, sh( kwtop ), 1,
     $             jw, v, ldv, infqr )
*
*     ==== Deflation detection loop ====
*
      ns = jw
      ilst = infqr + 1
      DO 10 knt = infqr + 1, jw
*
*        ==== Small spike tip deflation test ====
*
         foo = cabs1( t( ns, ns ) )
         IF( foo.EQ.rzero )
     $      foo = cabs1( s )
         IF( cabs1( s )*cabs1( v( 1, ns ) ).LE.max( smlnum, ulp*foo ) )
     $        THEN
*
*           ==== One more converged eigenvalue ====
*
            ns = ns - 1
         ELSE
*
*           ==== One undeflatable eigenvalue.  Move it up out of the
*           .    way.   (ZTREXC can not fail in this case.) ====
*
            ifst = ns
            CALL ztrexc( 'V', jw, t, ldt, v, ldv, ifst, ilst, info )
            ilst = ilst + 1
         END IF
   10 CONTINUE
*
*        ==== Return to Hessenberg form ====
*
      IF( ns.EQ.0 )
     $   s = zero
*
      IF( ns.LT.jw ) THEN
*
*        ==== sorting the diagonal of T improves accuracy for
*        .    graded matrices.  ====
*
         DO 30 i = infqr + 1, ns
            ifst = i
            DO 20 j = i + 1, ns
               IF( cabs1( t( j, j ) ).GT.cabs1( t( ifst, ifst ) ) )
     $            ifst = j
   20       CONTINUE
            ilst = i
            IF( ifst.NE.ilst )
     $         CALL ztrexc( 'V', jw, t, ldt, v, ldv, ifst, ilst, info )
   30    CONTINUE
      END IF
*
*     ==== Restore shift/eigenvalue array from T ====
*
      DO 40 i = infqr + 1, jw
         sh( kwtop+i-1 ) = t( i, i )
   40 CONTINUE
*
*
      IF( ns.LT.jw .OR. s.EQ.zero ) THEN
         IF( ns.GT.1 .AND. s.NE.zero ) THEN
*
*           ==== Reflect spike back into lower triangle ====
*
            CALL zcopy( ns, v, ldv, work, 1 )
            DO 50 i = 1, ns
               work( i ) = dconjg( work( i ) )
   50       CONTINUE
            beta = work( 1 )
            CALL zlarfg( ns, beta, work( 2 ), 1, tau )
            work( 1 ) = one
*
            CALL zlaset( 'L', jw-2, jw-2, zero, zero, t( 3, 1 ), ldt )
*
            CALL zlarf( 'L', ns, jw, work, 1, dconjg( tau ), t, ldt,
     $                  work( jw+1 ) )
            CALL zlarf( 'R', ns, ns, work, 1, tau, t, ldt,
     $                  work( jw+1 ) )
            CALL zlarf( 'R', jw, ns, work, 1, tau, v, ldv,
     $                  work( jw+1 ) )
*
            CALL zgehrd( jw, 1, ns, t, ldt, work, work( jw+1 ),
     $                   lwork-jw, info )
         END IF
*
*        ==== Copy updated reduced window into place ====
*
         IF( kwtop.GT.1 )
     $      h( kwtop, kwtop-1 ) = s*dconjg( v( 1, 1 ) )
         CALL zlacpy( 'U', jw, jw, t, ldt, h( kwtop, kwtop ), ldh )
         CALL zcopy( jw-1, t( 2, 1 ), ldt+1, h( kwtop+1, kwtop ),
     $               ldh+1 )
*
*        ==== Accumulate orthogonal matrix in order update
*        .    H and Z, if requested.  ====
*
         IF( ns.GT.1 .AND. s.NE.zero )
     $      CALL zunmhr( 'R', 'N', jw, ns, 1, ns, t, ldt, work, v, ldv,
     $                   work( jw+1 ), lwork-jw, info )
*
*        ==== Update vertical slab in H ====
*
         IF( wantt ) THEN
            ltop = 1
         ELSE
            ltop = ktop
         END IF
         DO 60 krow = ltop, kwtop - 1, nv
            kln = min( nv, kwtop-krow )
            CALL zgemm( 'N', 'N', kln, jw, jw, one, h( krow, kwtop ),
     $                  ldh, v, ldv, zero, wv, ldwv )
            CALL zlacpy( 'A', kln, jw, wv, ldwv, h( krow, kwtop ), ldh )
   60    CONTINUE
*
*        ==== Update horizontal slab in H ====
*
         IF( wantt ) THEN
            DO 70 kcol = kbot + 1, n, nh
               kln = min( nh, n-kcol+1 )
               CALL zgemm( 'C', 'N', jw, kln, jw, one, v, ldv,
     $                     h( kwtop, kcol ), ldh, zero, t, ldt )
               CALL zlacpy( 'A', jw, kln, t, ldt, h( kwtop, kcol ),
     $                      ldh )
   70       CONTINUE
         END IF
*
*        ==== Update vertical slab in Z ====
*
         IF( wantz ) THEN
            DO 80 krow = iloz, ihiz, nv
               kln = min( nv, ihiz-krow+1 )
               CALL zgemm( 'N', 'N', kln, jw, jw, one, z( krow, kwtop ),
     $                     ldz, v, ldv, zero, wv, ldwv )
               CALL zlacpy( 'A', kln, jw, wv, ldwv, z( krow, kwtop ),
     $                      ldz )
   80       CONTINUE
         END IF
      END IF
*
*     ==== Return the number of deflations ... ====
*
      nd = jw - ns
*
*     ==== ... and the number of shifts. (Subtracting
*     .    INFQR from the spike length takes care
*     .    of the case of a rare QR failure while
*     .    calculating eigenvalues of the deflation
*     .    window.)  ====
*
      ns = ns - infqr
*
*      ==== Return optimal workspace. ====
*
      work( 1 ) = dcmplx( lwkopt, 0 )
*
*     ==== End of ZLAQR2 ====
*

Here is the call graph for this function:

Here is the caller graph for this function: